Sử dụng các cột nguồn trong mệnh đề OUTPUT INTO của câu lệnh INSERT (SQL Server)

Tôi đang viết một câu lệnh chèn xử lý hàng loạt và muốn sử dụng bảng tạm thời để theo dõi ID được chèn thay vì tự lặp qua các mục và gọi SCOPE_IDENTITY () cho mỗi hàng được chèn.

Dữ liệu cần được chèn có ID (tạm thời) liên kết nó với dữ liệu khác cũng nên được chèn vào một bảng khác, vì vậy tôi cần một tham chiếu chéo của Id thực tế và Id tạm thời.

Đây là một ví dụ về những gì tôi có cho đến nay:

-- The existing table 
DECLARE @MyTable TABLE (ID INT IDENTITY(1,1), [Name] NVARCHAR(MAX));

-- My data I want to insert
DECLARE @MyInsertData TABLE (ID INT, [Name] NVARCHAR(MAX));
INSERT INTO @MyInsertData ( ID,Name)
VALUES ( -1 , 'bla'),(-2,'test'),(-3,'last');

DECLARE @MyCrossRef TABLE ([NewId] INT, OldId INT);

INSERT INTO @MyTable ( [Name] )
   OUTPUT Inserted.ID, INS.ID INTO @MyCrossRef
   SELECT [NAME] FROM @MyInsertData INS

-- Check the result
SELECT * FROM @MyCrossRef

Vấn đề là tôi không thể nhận được mệnh đề OUTPUT INTO để chấp nhận ID, tôi đã thử @MyInsertData.IDvà các thủ thuật khác tham gia vào bảng, nhưng dường như không có gì hoạt động.

Trên thực tế, bạn có thể đạt được điều tương tự bằng cách thay đổi INSERTthành a MERGE. Mặc dù MERGEcâu lệnh thực sự là một cách khá gọn gàng để thực hiện "uperts" trong SQL Server, nhưng không có gì ngăn bạn sử dụng nó chỉ với mục đích chèn:

-- The existing table 
DECLARE @MyTable TABLE (ID INT IDENTITY(1,1), [Name] NVARCHAR(MAX));

-- My data I want to insert
DECLARE @MyInsertData TABLE (ID INT, [Name] NVARCHAR(MAX));
INSERT INTO @MyInsertData ( ID,Name)
VALUES ( -1 , 'bla'),(-2,'test'),(-3,'last');

DECLARE @MyCrossRef TABLE ([NewId] INT, OldId INT);

MERGE INTO @MyTable AS dest
USING @MyInsertData AS ins ON 1=0   -- always false

WHEN NOT MATCHED BY TARGET          -- happens for every row, because 1 is never 0
    THEN INSERT ([Name])
         VALUES (ins.[NAME])

OUTPUT inserted.ID, ins.ID
INTO @MyCrossRef (NewId, OldId);

-- Check the result
SELECT * FROM @MyCrossRef

Một trong những điều thú vị MERGElà nó cho phép bạn truy cập các cột nguồn cũng như các bảng dựng sẵn insertedvà deletedcác bảng trong OUTPUTmệnh đề.

Mã của tôi có thể chứa lỗi, vì tôi chưa thực sự kiểm tra nó. Bài đăng trên blog của tôi từ một vài năm trước đi vào chi tiết hơn một chút, bao gồm cả về hiệu suất truy vấn.

Mệnh đề đầu ra chỉ có thể truy cập dữ liệu trong các hàng đích và hằng / biến, chứ không phải dữ liệu từ nơi khác trong nguồn SELECT, giống như khi bạn đang vận hành trong trình kích hoạt.

https://docs.microsoft.com/en-us/sql/t-sql/queries/output-clause-transact-sql trạng thái:

Bất kỳ tham chiếu nào đến các cột trong bảng đang được sửa đổi phải đủ tiêu chuẩn với tiền tố XÁC NHẬN hoặc XÓA.

Vì vậy, để có được ID gốc, bạn cần đưa nó vào bảng đích để mệnh đề đầu ra có thể lặp lại, như vậy:

-- The existing table 
DECLARE @MyTable TABLE (ID INT IDENTITY(1,1), [Name] NVARCHAR(MAX), SourceID INT);

-- My data I want to insert
DECLARE @MyInsertData TABLE (ID INT, [Name] NVARCHAR(MAX));
INSERT INTO @MyInsertData ( ID,Name)
VALUES ( -1 , 'bla'),(-2,'test'),(-3,'last');

DECLARE @MyCrossRef TABLE ([NewId] INT, OldId INT);

INSERT INTO @MyTable ( [Name], SourceID )
   OUTPUT Inserted.ID, Inserted.SourceID INTO @MyCrossRef
   SELECT [NAME], ID FROM @MyInsertData INS

-- Check the result
SELECT * FROM @MyCrossRef

mặc dù việc thay đổi lược đồ của đối tượng đích có thể không thực tế trong tình huống của bạn nên điều này có thể không được áp dụng.