Câu lệnh 'Tạo cơ sở dữ liệu' của SQL Server. Làm thế nào để kế thừa cài đặt tự động phát triển?

Tôi đang sử dụng SQL Server 2008 R2 và tạo cơ sở dữ liệu thông qua triển khai liên tục.

Trong hệ thống của chúng tôi, cài đặt tự động 1Mb / 10% mặc định trong SQL Server hoạt động không tốt với dữ liệu của chúng tôi. Đặc biệt là khi chúng tôi có một ứng dụng kế thừa ngăn chúng tôi thay đổi lược đồ nhiều. Chúng tôi muốn các cài đặt cơ sở dữ liệu được cấu hình ở cấp thể hiện để chúng tôi có thể thay đổi nó để triển khai theo giai đoạn.

Tôi đã đọc ở một số nơi rằng các cài đặt mặc định cho db mới dựa trên các cài đặt cho 'model', nhưng có vẻ như nó chỉ hoạt động bằng cách nhấp vào cơ sở dữ liệu mới trong UI Studio của SQL Management chứ không phải từ tập lệnh, ví dụ CREATE DATABASE [MyDb].

msdn.microsoft.com/en-us/l Library / ms186388 (v = sql.105) .aspx

sqlservercentral.com/Forums/Topic1065073-391-1.aspx

/programming/8828557/possible-to-configure-database-autogrowth-sinstall-at-the-instance-level/8828604#comment15586568_8828604

Có ai thực sự có được điều này để làm việc với một kịch bản tạo? Có cách nào khác để tôi có thể thiết lập chế độ tự động cho mỗi phiên bản máy chủ không?

Đối với SQL Server 2005+ Bạn có thể sử dụng như sau:

SELECT FILE_ID, type, type_desc, 
CAST( CAST( (CASE WHEN size < 128 THEN 128 ELSE size END) * 8. / 1024. AS INT ) AS VARCHAR(20) ) + 'MB' AS SIZE, 
CASE max_size WHEN -1 THEN 'UNLIMITED' ELSE CAST( CAST( max_size * 8. / 1024. AS INT ) AS VARCHAR(20) ) + 'MB' END  AS MAXSIZE,
CASE is_percent_growth
    WHEN 0 THEN CAST( CAST( growth * 8. / 1024. AS INT ) AS VARCHAR(20) ) + 'MB'
    WHEN 1 THEN CAST( growth AS VARCHAR(30) ) + '%'
END AS FILEGROWTH
FROM sys.master_files
WHERE database_id = DB_ID('model')
GO

Điều này sẽ lấy định nghĩa tệp cho cơ sở dữ liệu mô hình.
Sau này, bạn có thể sử dụng nó trong CREATE DATABASE hoặc ALTER DATABASE.

SSMS thực sự sử dụng SMO để lấy các tham số này và sau đó tạo ra một Script giống như:

CREATE DATABASE [aaa] ON  PRIMARY 
( NAME = N'aaa', FILENAME = N'D:\Data\aaa.mdf' , SIZE = 3072KB , MAXSIZE = UNLIMITED , FILEGROWTH = 1024KB )
 LOG ON 
( NAME = N'aaa_log', FILENAME = N'D:\Logs\aaa_log.ldf' , SIZE = 1024KB , FILEGROWTH = 10%)
GO

Nếu Ứng dụng của bạn đang tạo Cơ sở dữ liệu và Bạn không thể sửa đổi ứng dụng -
thì Bạn phải sử dụng ALTER DATABASE sau khi tạo xong:

ALTER DATABASE [aaa] MODIFY FILE ( NAME = N'aaa', MAXSIZE = 102400KB )
GO
ALTER DATABASE [aaa] MODIFY FILE ( NAME = N'aaa_log', FILEGROWTH = 10240KB )
GO

Điều này đòi hỏi ít nhất Quyền ALTER DATABASE
(ngụ ý bởi ALTER ANY DATABASE
Perm Perm Server) Rõ ràng, Bạn có thể tạo tập lệnh đó bằng cách sử dụng mẫu mã đầu tiên (TỪ sys.master_files).

Tôi sẽ không sử dụng sysaltfiles cho SQL Server 2008R2 vì nó không dùng nữa.

Chúc may mắn,
Roi

Làm thế nào về:

use master
go

declare @newDbName sysname
, @fn nvarchar(1024)
, @growthAmount integer
, @growth nvarchar(128)
, @growthAmount_log integer
, @growth_log nvarchar(128)

set @newDbName = 'myNewDB'

--see what's available to us
--select * 
--from sys.sysaltfiles saf
--inner join sys.databases db
--  on saf.dbid = db.database_id
--where db.name = 'model'

select @growthAmount = saf.growth 
, @growth = case saf.status & 0x100000 when 0 then 'MB' else '%' end
, @fn = replace(saf.filename,'model.mdf','')
from sys.sysaltfiles saf
inner join sys.databases db
    on saf.dbid = db.database_id
where db.name = 'model'
and saf.name = 'modeldev'

select @growthAmount_log = saf.growth 
, @growth_log = case saf.status & 0x100000 when 0 then 'MB' else '%' end
from sys.sysaltfiles saf
inner join sys.databases db
    on saf.dbid = db.database_id
where db.name = 'model'
and saf.name = 'modellog'

if @growth = 'MB' set @growthAmount = @growthAmount / 128
if @growth_log = 'MB' set @growthAmount_log = @growthAmount_log / 128

set @growth = cast(@growthAmount as nvarchar(10)) + @growth
set @growth_log = cast(@growthAmount_log as nvarchar(10)) + @growth_log

print '
    CREATE DATABASE ' + @newDbName + '
    ON 
    (   
        NAME = ' + @newDbName + '_data
        ,FILENAME = ''' + @fn + @newDbName + '.mdf''
        ,FILEGROWTH = ' + @growth + '
    )
    LOG ON
    ( 
        NAME = ' + @newDbName + '_log
        ,FILENAME = ''' + @fn + @newDbName + '.ldf''
        ,FILEGROWTH = ' + @growth_log + '
    ) 
'
exec('
    CREATE DATABASE ' + @newDbName + '
    ON 
    (   
        NAME = ' + @newDbName + '_data
        ,FILENAME = ''' + @fn + @newDbName + '.mdf''
        ,FILEGROWTH = ' + @growth + '
    )
    LOG ON
    ( 
        NAME = ' + @newDbName + '_log
        ,FILENAME = ''' + @fn + @newDbName + '.ldf''
        ,FILEGROWTH = ' + @growth_log + '
    ) 
')