Làm thế nào để bắt và xử lý chỉ các ngoại lệ cụ thể của Oracle?

Từ điều này và điều này tôi đoán, rằng không có Ngoại lệ hệ thống được đặt tên trước cho ORA-00955.

Làm cách nào tôi có thể viết lại phần sau để chỉ bắt lỗi ORA-00955?

begin
      EXECUTE IMMEDIATE 'CREATE SEQUENCE S_TEST START WITH 1 INCREMENT BY 1';
exception when OTHERS then
    Null;
end;

BTW Có cú pháp nào để bắt lỗi chỉ bằng cách cung cấp mã lỗi không?

Bạn có hai lựa chọn:

Tham khảo ngoại lệ trực tiếp theo số:

BEGIN
    EXECUTE IMMEDIATE 'CREATE SEQUENCE S_TEST START WITH 1 INCREMENT BY 1';
EXCEPTION
    WHEN OTHERS THEN
      IF SQLCODE = -955 THEN
        NULL; -- suppresses ORA-00955 exception
      ELSE
         RAISE;
      END IF;
END; 

Tùy chọn khác là sử dụng EXCEPTION_INITchỉ thị thực dụng để liên kết một số lỗi Oracle đã biết với ngoại lệ do người dùng xác định;

DECLARE
   name_in_use exception; --declare a user defined exception
   pragma exception_init( name_in_use, -955 ); --bind the error code to the above 
BEGIN
    EXECUTE IMMEDIATE 'CREATE SEQUENCE S_TEST START WITH 1 INCREMENT BY 1';
EXCEPTION
    when name_in_use then
       null; --suppress ORA-00955 exception
END; 

BTW Có cú pháp nào để bắt lỗi chỉ bằng cách cung cấp mã lỗi không?

Vâng, tôi đã chứng minh điều đó trong ví dụ đầu tiên

Đọc thêm cho các biến thể về điều này:

• Tài liệu tham khảo của Oracle về xử lý các ngoại lệ PL / SQL

Tương tự như những gì Sathya đã đề xuất, nhưng tôi muốn tránh when othershoàn toàn nếu có thể - một ngoại lệ chưa được xử lý thường là kết quả chính xác cho các trường hợp ngoại lệ mà bạn không xử lý cụ thể:

create sequence foo;
/*
sequence FOO created.
*/
declare
  name_is_already_used_955 exception;
  pragma exception_init(name_is_already_used_955,-955);
begin
  execute immediate 'create sequence foo';
exception when name_is_already_used_955 then null;
end;
/
/*
anonymous block completed
*/