Tôi đang làm việc để tối ưu hóa cấu hình emacs của mình , nơi tôi có thể tự động tạo các chức năng tương tác cho tất cả các chủ đề tôi có trong danh sách.

Dưới đây là phiên bản đơn giản hóa của cấu trúc tôi đang cố gắng thực hiện.

;; List containing names of functions that I want to create
(setq my/defun-list '(zz-abc
                      zz-def
                      zz-ghi))

;; Elisp macro to create an interactive defun whose name
;; is passed as the macro argument
(defmacro my/create-defun (defun-name)
  `(defun ,defun-name ()
     (interactive)
     (let ((fn-name (symbol-name ',defun-name)))
       (message "Testing creation of function %s" fn-name))))

;; Loop to call the above macro for each element in the list
;; DOES *NOT* WORK
(dolist (name my/defun-list)
  (my/create-defun name))

Nhưng nếu tôi hủy đăng ký vòng lặp theo cách thủ công, nó sẽ hoạt động:

;; WORKS
(my/create-defun zz-abc)
(my/create-defun zz-def)
(my/create-defun zz-ghi)

Nhưng bên dưới không hoạt động khi tôi chuyển vào các tên biểu tượng (có thể là những gì đang xảy ra khi vòng lặp tự kiểm soát). Lưu ý các trích dẫn trước các đối số vĩ mô.

;; DOES *NOT* WORK
(my/create-defun 'zz-abc)
(my/create-defun 'zz-def)
(my/create-defun 'zz-ghi)

Cập nhật

Nhờ sự giúp đỡ của @wvxvw , cuối cùng tôi cũng đã làm việc này !

Như @wvxvw gợi ý, tôi sẽ không tạo ra các đợt giảm giá hàng loạt cho bất kỳ và mọi trường hợp sử dụng. Đây là trường hợp sử dụng đặc biệt trong đó đối với một chủ đề có tên XYZ, tôi muốn tạo một defun được gọi là load-theme/XYZcông việc của

• Vô hiệu hóa tất cả các chủ đề khác có thể hoạt động
• Gọi load-themechoXYZ
• Làm một số công cụ tùy chỉnh hơn liên quan đến chủ đề đó; Tôi chuyển qua các cài đặt tùy chỉnh cho từng chủ đề thông qua my/themesalist.

Đây là một nỗ lực giải thích và một số gợi ý.

(defmacro my/create-defun (defun-name)
  `(defun ,defun-name ()
     (interactive)
     (let ((fn-name (symbol-name ',defun-name)))
       (message "Testing creation of function %s" fn-name))))

(dolist (name my/defun-list)
  ;; Macros are meant to create code, not execute it.  Think
  ;; about simply substituting the contents of your macro here
  ;; what would you expect it to do?
  (my/create-defun name))

(dolist (name my/defun-list)
  ;; This is not something a compiler (or interpreter)
  ;; can work with, it needs all sources of the code it
  ;; is going to execute
  (defun defun-name ()
    (interactive)
    (let ((fn-name (symbol-name 'defun-name)))
      (message "Testing creation of function %s" fn-name))))

;; This works because you, indeed created three defuns
(my/create-defun zz-abc)
(my/create-defun zz-def)
(my/create-defun zz-ghi)

;; This doesn't work because `defun' macro expect the name of
;; the function to be a symbol (but you are giving it a list
;; `(quote zz-abc)'.
(my/create-defun 'zz-abc)
(my/create-defun 'zz-def)
(my/create-defun 'zz-ghi)

Bây giờ, chúng ta hãy cố gắng khắc phục điều này:

;; Rewriting the original macro as a function and using a
;; macro to collect the generated forms gives:
(defun my/create-defun (defun-name)
  `(defun ,defun-name ()
     (interactive)
     (let ((fn-name (symbol-name ',defun-name)))
       (message "Testing creation of function %s" fn-name))))

(defmacro my/create-defuns (defuns)
  `(progn ,@(mapcar 'my/create-defun defuns)))

(macroexpand '(my/create-defuns (zz-abc zz-def zz-ghi)))
;; Just to make sure
(progn
  (defun zz-abc nil
    (interactive)
    (let ((fn-name (symbol-name (quote zz-abc))))
      (message "Testing creation of function %s" fn-name)))
  (defun zz-def nil
    (interactive)
    (let ((fn-name (symbol-name (quote zz-def))))
      (message "Testing creation of function %s" fn-name)))
  (defun zz-ghi nil
    (interactive)
    (let ((fn-name (symbol-name (quote zz-ghi))))
      (message "Testing creation of function %s" fn-name))))

Ví dụ với việc đọc tên hàm từ một biến

(defvar my/functions '((func-1 . 1) (func-2 . 2) (func-3 . 3)))

(defun my/create-defun-n (defun-name n)
  `(defun ,defun-name ()
     (message "function: %s, n %d" ',defun-name ,n)))

(defmacro my/create-defuns-var ()
  `(progn ,@(mapcar
             (lambda (x) (my/create-defun-n (car x) (cdr x)))
             my/functions)))

(macroexpand '(my/create-defuns-var))
(progn
  (defun func-1 nil (message "function: %s, n %d" (quote func-1) 1))
  (defun func-2 nil (message "function: %s, n %d" (quote func-2) 2))
  (defun func-3 nil (message "function: %s, n %d" (quote func-3) 3)))

Vấn đề thuộc loại khái niệm: macro là để tạo mã khi môi trường muốn đọc nó. Khi bạn tự thực thi mã (với tư cách là người dùng chương trình của mình) thì điều này đã quá muộn để thực hiện (môi trường nên biết sau đó chương trình là gì).

Một lưu ý ngoài lề: Tôi sẽ khuyên bạn không nên kết hợp với nhau defuns. Lý do là nó làm cho việc gỡ lỗi phức tạp hơn rất nhiều. Sự dư thừa nhỏ mà bạn có trong các định nghĩa lặp đi lặp lại rất tốt trong giai đoạn bảo trì (và bảo trì thường là giai đoạn dài nhất trong thời gian sống của chương trình).

(dolist (fun '(foo bar baz))
  (defalias fun (lambda (a)
                  "I'm a function defined in `dolist'!"
                  (interactive)
                  (message a))))
(bar "See? No macro!")

Không chính xác defun nhưng tại sao không? : P

Tôi có những điều sau đây trong init của mình:

(my/work-properties '("hostname" "username" "location"))

(defmacro jlp/make-def (name props doc &rest body)
  "Shortcut to programatically create new functions"
  (let ((funsymbol (intern name)))
    `(defun ,funsymbol ,props ,doc ,@body)))

(defun my/make-work-props (properties)
  "Create functions to retrieve properties from Org headlines."
  (dolist (prop properties)
    (let ((funsym   (format "my/org-get-%s" prop))
          (property (intern (format ":%s" (upcase prop))))
          (doc      (format "Retrieves `%s' from current headline"
                            (upcase prop)))
          (err (format "%s is not set" (capitalize prop))))
      (eval
       `(jlp/make-def ,funsym
                      ()
                      ,doc
                      (interactive)
                      (let ((x (or
                                (save-excursion
                                  (org-back-to-heading)
                                  (org-element-property
                                   ,property
                                   (org-element-at-point)))
                                (user-error ,err))))
                        (message "%s" x)
                         (kill-new x)))))))

(my/make-work-props my/org-work-properties)

Nó có thể hơi phức tạp hơn mức cần thiết (đặc biệt là thêm eval) nhưng nó cho phép tôi tạo ra các defun tôi cần cho các thuộc tính đó (và bao gồm các tài liệu với thông tin chính xác trong chuỗi).