Sao chép sâu một chuỗi trong Elisp?

Tôi có một chuỗi thích hợp. Tôi muốn tạo một bản sao sâu của nó để thêm nhiều thuộc tính, trong khi vẫn giữ các thuộc tính trong chuỗi gốc. Làm thế nào tôi có thể làm điều đó (dễ dàng)?

Thí dụ

Đánh giá từng cái một:

(setq test-str-1
      #(";; This `is' a test"
        0 3 (fontified nil face font-lock-comment-delimiter-face)
        3 9 (fontified nil face font-lock-comment-face)
        9 11 (fontified nil face (font-lock-constant-face font-lock-comment-face))
        11 19 (fontified nil face font-lock-comment-face)))
(setq test-str-2 (concat test-str-1))
(add-face-text-property 0 (length test-str-2) 'foobar t test-str-2)

Và kết quả:

test-str-2
;; =>
#(";; This `is' a test" 0 3 (fontified nil face (font-lock-comment-delimiter-face foobar))
  3 9 (fontified nil face (font-lock-comment-face foobar))
  9 11 (fontified nil face (font-lock-constant-face font-lock-comment-face foobar))
  11 19 (fontified nil face (font-lock-comment-face foobar)))
test-str-1
;; =>
#(";; This `is' a test" 0 3 (face font-lock-comment-delimiter-face fontified nil)
  3 9 (face font-lock-comment-face fontified nil)
  9 11 (face (font-lock-constant-face font-lock-comment-face foobar) ; <= foobar is here
        fontified nil)
  11 19 (face font-lock-comment-face fontified nil))

Bạn có thể sử dụng chức năng font-lock-append-text-propertyđể thêm thuộc tính văn bản. Nó không sửa đổi giá trị một cách triệt để.

Ví dụ:

(setq test-str-1
      #(";; This `is' a test"
        0 3 (fontified nil face font-lock-comment-delimiter-face)
        3 9 (fontified nil face font-lock-comment-face)
        9 11 (fontified nil face (font-lock-constant-face font-lock-comment-face))
        11 19 (fontified nil face font-lock-comment-face)))
(setq test-str-2 (concat test-str-1))
(font-lock-append-text-property 0 (length test-str-2) 'face '(foobar t) test-str-2)


test-str-1
#(";; This `is' a test"
  0 3 (face font-lock-comment-delimiter-face fontified nil)
  3 9 (face font-lock-comment-face fontified nil)
  9 11 (face (font-lock-constant-face font-lock-comment-face) fontified nil)
  11 19 (face font-lock-comment-face fontified nil))

test-str-2
#(";; This `is' a test"
  0 3 (fontified nil face (font-lock-comment-delimiter-face foobar t))
  3 9 (fontified nil face (font-lock-comment-face foobar t))
  9 11 (fontified nil face (font-lock-constant-face font-lock-comment-face foobar t))
  11 19 (fontified nil face (font-lock-comment-face foobar t)))

Ở đây, trong test-str-1, đã giữ lại giá trị ban đầu của nó.

Tôi thấy bạn có thể làm điều này bằng cách lặp lại các thuộc tính văn bản, sao chép dữ liệu thuộc tính cơ bản và ghi đè các thuộc tính hiện có bằng các bản sao mới.

(defun deep-copy-text-properties (str)
  (with-temp-buffer
    (insert str)
    (goto-char 1)
    (while (not (eobp))
      (set-text-properties (point)
                           (goto-char (next-char-property-change (point) (point-max)))
                           ;; copy-tree is the important part
                           (copy-tree (text-properties-at (1- (point))))))
    (buffer-string)))

Trong các thử nghiệm của tôi, điều này nhanh hơn khoảng 20% ​​so với readgiải pháp của bạn . Tôi cũng đã viết một phiên bản không sử dụng bộ đệm tạm thời và sửa đổi các thuộc tính của một chuỗi ít mã hơn nhưng chậm hơn.

Nhìn vào mã C, nó sao chép các thuộc tính, với copy_ resultence sẽ xây dựng lại cấu trúc danh sách nhưng không sao chép các phần tử theo giá trị, do đó các thuộc tính như khuôn mặt trong ví dụ của bạn có giá trị danh sách được sao chép qua tham chiếu và sửa đổi. Lỗi hay không, tôi không biết

Bạn có thể sử dụng (concat the-original-string).

Ví dụ:

(let ((s "TEXT"))
  (set-text-properties 2 3 '(:foreground "blue") s)
  (let ((q (concat s)))
    (add-text-properties 2 3 '(:background "red") q)
    (cons s q)))
;; Returns:
(#("TEXT" 2 3 (:foreground "blue")) . #("TEXT" 2 3 (:foreground "blue" :background "red")))

Tìm thấy một công việc (không hiệu quả lắm):

(setq test-str-2
      (read (prin1-to-string test-str-1)))