Làm nổi bật các biến shell trong dấu ngoặc kép

Trong vim, tài liệu sau đây sẽ làm cho $PWDdòng trên 2 và 3 được tô màu theo hai cách khác nhau:

#/bin/sh
echo "Current Directory: $PWD"
echo 'Current Directory: $PWD'

Ví dụ đầu tiên $PWDsẽ có màu khác với phần còn lại của chuỗi. Nó cho thấy một dấu hiệu trực quan rõ ràng rằng biến sẽ được mở rộng, thay vì được coi là văn bản bằng chữ. Ngược lại, phiên bản thứ hai của $PWDsẽ được tô màu giống như phần còn lại của chuỗi, bởi vì các dấu ngoặc đơn làm cho nó được coi là văn bản bằng chữ.

Có bất kỳ chế độ emacs hiện có nào cung cấp loại "nhận thức trích dẫn vỏ" này không?

Mã dưới đây sử dụng quy tắc khóa phông chữ với hàm thay vì regrec, hàm tìm kiếm các lần xuất hiện $VARnhưng chỉ khi chúng nằm trong chuỗi trích dẫn kép. Các chức năng (syntax-ppss)được sử dụng để xác định điều này.

Quy tắc khóa phông chữ sử dụng prependcờ để thêm chính nó vào đầu tô sáng chuỗi hiện có. (Lưu ý rằng nhiều gói sử dụng tcho việc này. Thật không may, điều này ghi đè lên tất cả các khía cạnh của tô sáng hiện có. Ví dụ: sử dụng prependsẽ giữ lại màu nền của chuỗi (nếu có) trong khi thay thế màu nền trước.)

(defun sh-script-extra-font-lock-is-in-double-quoted-string ()
  "Non-nil if point in inside a double-quoted string."
  (let ((state (syntax-ppss)))
    (eq (nth 3 state) ?\")))

(defun sh-script-extra-font-lock-match-var-in-double-quoted-string (limit)
  "Search for variables in double-quoted strings."
  (let (res)
    (while
        (and (setq res
                   (re-search-forward
                    "\\$\\({#?\\)?\\([[:alpha:]_][[:alnum:]_]*\\|[-#?@!]\\)"
                    limit t))
             (not (sh-script-extra-font-lock-is-in-double-quoted-string))))
    res))

(defvar sh-script-extra-font-lock-keywords
  '((sh-script-extra-font-lock-match-var-in-double-quoted-string
     (2 font-lock-variable-name-face prepend))))

(defun sh-script-extra-font-lock-activate ()
  (interactive)
  (font-lock-add-keywords nil sh-script-extra-font-lock-keywords)
  (if (fboundp 'font-lock-flush)
      (font-lock-flush)
    (when font-lock-mode
      (with-no-warnings
        (font-lock-fontify-buffer)))))

Bạn có thể gọi sử dụng điều này bằng cách thêm chức năng cuối cùng vào một hook phù hợp, ví dụ:

(add-hook 'sh-mode-hook 'sh-script-extra-font-lock-activate)

Tôi đã cải thiện câu trả lời của @ Lindydancer theo những cách sau:

• Inlined các sh-script-extra-font-lock-is-in-double-quoted-stringchức năng, vì nó chỉ được sử dụng một lần
• Thoát khỏi các công trình biến.
• Biến số ( $10, $1, vv) được đánh dấu.

Phá mã

(defun sh-script-extra-font-lock-match-var-in-double-quoted-string (limit)
  "Search for variables in double-quoted strings."
  (let (res)
    (while
        (and (setq res (progn (if (eq (get-byte) ?$) (backward-char))
                              (re-search-forward
                               "[^\\]\\$\\({#?\\)?\\([[:alpha:]_][[:alnum:]_]*\\|[-#?@!]\\|[[:digit:]]+\\)"
                               limit t)))
             (not (eq (nth 3 (syntax-ppss)) ?\")))) res))

(defvar sh-script-extra-font-lock-keywords
  '((sh-script-extra-font-lock-match-var-in-double-quoted-string
     (2 font-lock-variable-name-face prepend))))

(defun sh-script-extra-font-lock-activate ()
  (interactive)
  (font-lock-add-keywords nil sh-script-extra-font-lock-keywords)
  (if (fboundp 'font-lock-flush)
      (font-lock-flush)
    (when font-lock-mode (with-no-warnings (font-lock-fontify-buffer)))))