Hàm Emacs để chuyển đổi một TÀI SẢN ORG tùy ý thành một chuỗi tùy ý (cụ thể là nhãn LaTeX)?

Tôi có nhiều tài liệu dưới dạng tệp org có thuộc tính CUSTOM_LABEL, như

* Introduction :PROPERTIES: :CUSTOM_LABEL: AP 1 :END:

Trong trường hợp này, các tệp cần được xuất dưới dạng LaTeX, dịch từng tệp CUSTOM_LABELlà a \label{marker}. Ví dụ trên nên dịch sang \label{AP 1}.

Tôi đã biết cách gọi các chức năng tùy chỉnh tại thời điểm xuất, nhưng tôi không đủ chuyên môn để viết một defun để thực hiện chuyển đổi cụ thể đó, tức là CUSTOM_LABEL->\label{}

Làm thế nào các defun để tiêm custom_labelnhư \label{}được viết?

Tôi sẽ đánh giá cao thậm chí chỉ một số mã giả, hoặc một số con trỏ.

Tôi đang hỏi câu hỏi này ở đây thay vì những nơi khác, bởi vì đây là câu hỏi của Emacs nhiều hơn, vì tôi đã tìm kiếm kỹ hướng dẫn sử dụng chế độ org và loại tính năng này hiện không có sẵn.

Một hàm chung để chuyển đổi một SỞ HỮU nhất định khi xuất (LaTeX, HTML hoặc bất kỳ định dạng nào khác), thậm chí còn tốt hơn.

Cảm ơn bạn.

Tôi đã viết một chức năng thực hiện những gì bạn muốn một cách khá mở rộng. Nó kiểm tra các tiêu đề nào chứa thuộc tính CUSTOM_LABEL (hoặc một số thuộc tính khác mà bạn định cấu hình) và gọi hàm endless/insert-org-label-latextrên mỗi chúng với giá trị của thuộc tính làm đối số.

Đoạn mã ví dụ cũng cho thấy cách mở rộng nó cho html hoặc các phụ trợ khác.

Cấu hình thay thế

Với biến này, bạn có thể định cấu hình các thuộc tính bạn quan tâm và các hàm nào được gọi để xử lý từng thuộc tính.

(defcustom endless/org-property-mapping 
  '((latex ("CUSTOM_LABEL" . endless/insert-org-label-latex))
    (html ("CUSTOM_LABEL" . endless/insert-org-label-html)))
  "List of mappings from org property to arbitrary strings.
Each element is a list:
  (BACKEND (PROPERTY1 . FUNCTION1) (PROPERTY2 . FUNCTION2) ...)

FUNCTION are functions which get called with a single
argument (the value of PROPERTY) and are responsible for doing
whatever should be done."
  :type '(repeat (cons symbol (repeat (cons string string)))))

Công nhân nặng

Chức năng này là những gì bạn nên thêm vào hook xuất org. Nó đảm nhiệm việc kiểm tra các thuộc tính được liệt kê ở trên và gọi các hàm liên quan đến các thuộc tính đó.

(defun endless/replace-org-property (backend)
  "Convert org properties using `endless/org-property-mapping'.
Lookup BACKEND in `endless/org-property-mapping' for a list of
\(PROPERTY REPLACEMENT). For each healine being exported, if it has a
PROPERTY listed insert a string immediately after the healine given by
    (format REPLACEMENT PROPERTY-VALUE)"
  (let ((map (cdr (assoc backend endless/org-property-mapping)))
        value replacement)
    (when map      
      (org-map-entries
       (lambda () 
         (dolist (it map)
           (save-excursion
             (when (setq value (org-entry-get (point) (car it))) 
               (funcall (cdr it) value)))))))))

(add-hook 'org-export-before-processing-hook #'endless/replace-org-property)

Các chức năng bạn xác định

Đây là những người làm thay thế thực tế. Dưới đây là một ví dụ cho trường hợp latex.

(defun endless/insert-org-label-latex (label)
  "Insert \"\\\\label{LABEL}\\n\" after the :PROPERTY: drawer."
  (search-forward-regexp org-property-end-re)
  (forward-char 1)
  (insert (format "\\label{%s}\n" label)))

Kết quả

Đánh giá tất cả các mã này ở trên, sau đó xuất bộ đệm org sau sang latex.

* Test
  :PROPERTIES:
  :CUSTOM_LABEL: hi
  :END:
Test

Bộ đệm latex kết quả nên là một cái gì đó như thế này.

\section{Test}
\label{sec-1}
\label{hi}
Test

Lưu ý đối với các đoạn mã bạn phải sử dụng phiên bản phát triển hiện tại , (org-version) => "8.3beta".

Vui lòng sử dụng CUSTOM_IDvà liên kết nội bộ. Xem (info "(org) Handling links").

Trong hầu hết các trường hợp, bạn không nên quan tâm đến kết quả xuất khẩu của việc đặt tên nội bộ trong Org. Liên kết đến số liệu và tiêu đề, nói, sẽ chính xác khi xuất khẩu. Xem (info "(org) Internal links").

Đối với LaTeX hãy thử:

(with-temp-buffer
  (let ((org-latex-prefer-user-labels t))
(insert "
* h
:PROPERTIES:
:CUSTOM_ID: h
:END:")
(org-mode)
(org-latex-export-as-latex nil nil nil t)))

Kết quả:

\section{h}
\label{h}

Trong các nhà xuất khẩu như ox-odtvà ox-htmltiêu đề chứa cả id nội bộ IDvà CUSTOM_ID. Liên kết nào được sử dụng phụ thuộc vào liên kết:

(with-temp-buffer
  (let ((org-export-with-toc nil))
(insert "
* h
:PROPERTIES:
:CUSTOM_ID: h
:END:
[[*h]] [[#h]]")
(org-mode)
(org-html-export-as-html nil nil nil t)))

Kết quả:

<div id="outline-container-h" class="outline-2">
<h2 id="h"><a id="sec-1"></a><span class="section-number-2">1</span> h</h2>
<div class="outline-text-2" id="text-h">
<p>
<a href="#sec-1">1</a> <a href="#h">1</a>
</p>
</div>
</div>

Tôi không chắc chắn, nhưng bạn có thể cần phải tư vấn hoặc thậm chí ghi đè chức năng nhà xuất khẩu. Trong Org 8, đó là org-latex-export-headline.

Hàm lấy phần tử tiêu đề, nội dung tiêu đề và danh sách thuộc tính bổ sung. Trong hàm xuất khẩu, bạn có thể nhận các thuộc tính phần tử (bao gồm nhãn tùy chỉnh của bạn) với org-element-property.