tập tin đánh dấu đoạn văn đã thay đổi, ngay cả khi nó không làm gì cả

Bất cứ khi nào tôi gọi fill-paragraph, bộ đệm luôn được đánh dấu là đã sửa đổi, ngay cả khi lệnh không có hiệu lực (tức là nếu đoạn văn đã được điền). Nó cũng tạo ra một hành động hoàn tác trống rỗng (dễ dàng phát hiện với undo-tree-mode). Các lệnh khác có khả năng thực hiện thay đổi, chẳng hạn như các lệnh thụt lề, không đánh dấu bộ đệm là đã sửa đổi hoặc tạo một hành động không thể xóa được nếu không có gì thay đổi. Có cách nào để fill-paragraphđánh dấu bộ đệm được sửa đổi và tạo ra một hành động không thể hoàn tác chỉ khi nó thực sự thay đổi một cái gì đó?

Lưu ý rằng điều này được cố định cho Emacsen mới hơn (v.26 trở lên).

Vấn đề là fill-paragraph(hoặc đúng hơn, fill-region-as-paragraph) sẽ loại bỏ và chèn lại các dòng mới trong khi nó phá vỡ đoạn văn của bạn. Nó sẽ không sửa đổi bộ đệm nếu chỉ có một dòng. No-op trong danh sách hoàn tác mà bạn chứng kiến ​​chỉ là fill-paragraphloại bỏ và chèn lại dòng mới.

Nó là không tầm thường để tránh điều này. Sau đây là một bản hack khá tệ và kém hiệu quả đối với các bộ đệm lớn, nhưng có lẽ nó hiệu quả với bạn. Lệnh bắt chước fill-paragraph( M-q) với hành vi giống hệt nhau, ngoại trừ nó lưu trữ nội dung của bộ đệm trước khi gọi nó và sau đó, nếu nội dung giữ nguyên, nó sẽ khôi phục trạng thái sửa đổi và hoàn tác danh sách từ trước khi thay đổi. Để làm điều này, nó cần một bản sao (hai, thực sự) của nội dung bộ đệm, vì vậy thực sự, điều này khá không hiệu quả. :-)

(defun my/fill-paragraph (&optional justify region)
  (interactive (progn
                 (barf-if-buffer-read-only)
                 (list (if current-prefix-arg 'full) t)))
  (let ((old-text (buffer-string))
        (old-modified (buffer-modified-p))
        (old-undo-list buffer-undo-list))
    (fill-paragraph justify region)
    (when (equal old-text (buffer-string))
      (setq buffer-undo-list old-undo-list)
      (set-buffer-modified-p old-modified))))

Bạn có thể ràng buộc điều đó với M-q.

Trả lời muộn, nhưng đây là phiên bản đơn giản không sửa đổi bộ đệm nếu văn bản không thay đổi.

(defun my-fill-paragraph (&optional justify region)
  "Fill paragraph, but don't modify the buffer if filling doesn't
change the text.  See `fill-paragraph' for details."
  (interactive (progn
                 (barf-if-buffer-read-only)
                 (list (if current-prefix-arg 'full) t)))
  (if (buffer-modified-p)
      ;; if modified: use standard fill-paragraph
      (fill-paragraph justify region)
    ;; if unmodified: get a candidate filled version
    (save-excursion
      (let* ((col fill-column)
             (beg (progn (forward-paragraph -1)
                         (skip-syntax-forward " >")
                         (point)))
             (end (progn (forward-paragraph 1)
                         (skip-syntax-backward " >")
                         (point)))
             (old (buffer-substring-no-properties beg end))
             (new (with-temp-buffer
                    (setq fill-column col)
                    (insert old)
                    (fill-paragraph justify region)
                    (buffer-string))))
        ;; don't modify unless the old and new versions differ
        (unless (string-equal old new)
          (delete-region beg end)
          (insert new))))))

Nó điều chỉnh một số ý tưởng trong câu trả lời của @ JorgenSchäfer, nhưng chỉ hoạt động với đoạn hiện tại và chỉ theo cách đơn giản, tách biệt khoảng trắng (xem nhận xét về câu trả lời của @ JorgenSchäfer về các biến chứng dưới mui xe).

Đây là về trường hợp sử dụng duy nhất phù hợp với mục đích của riêng tôi (nghĩa là sử dụng tương tác với văn xuôi "bình thường", không có vùng hoạt động), vì vậy tôi sẽ đăng nó trong trường hợp bất kỳ ai muốn sử dụng hoặc cải thiện nó cho các trường hợp sử dụng phức tạp hơn .