Có cách nào tốt hơn để xử lý các tài liệu đa dòng trong elisp không?

Tôi ghét cái cách mà elisp (không chắc chắn nếu LISP nói chung) xử lý các tài liệu đa dòng.

(defun foo ()
  "This is
a multi
liner
docstring"
  (do-stuff))

Tôi chắc chắn ước gì tôi có thể làm một cái gì đó như

(defun foo ()
  (eval-when-compile 
    (concat
      "This is\n"
       "a multi\n"
       "line\n"
       "docstring"))
  (do-stuff))

để vết lõm phù hợp.

Thật không may, eval-khi-biên dịch không thực hiện công việc.

Có ai có ý tưởng nào?

Tất nhiên một my-defunmacro là cách dễ dàng. Nhưng một giải pháp đơn giản hơn sẽ là

(advice-add 'eval-when-compile :filter-return
            (lambda (exp)
              (if (and (eq 'quote (car-safe exp))
                       (stringp (cadr exp)))
                  (cadr exp)
                exp)))

Điều này sẽ làm cho thủ thuật của bạn hoạt động, ít nhất là trong tất cả các trường hợp hàm được khai thác vĩ mô trước khi nó thực sự được xác định, bao gồm các trường hợp sử dụng chính (ví dụ: nếu nó được tải từ một tệp, nếu nó được biên dịch byte hoặc nếu nó được xác định thông qua M-C-x).

Tuy nhiên, điều này sẽ không sửa tất cả các mã hiện có, vì vậy có lẽ câu trả lời tốt hơn là:

;; -*- lexical-binding:t -*-

(defun my-shift-docstrings (orig ppss)
  (let ((face (funcall orig ppss)))
    (when (eq face 'font-lock-doc-face)
      (save-excursion
        (let ((start (point)))
          (parse-partial-sexp (point) (point-max) nil nil ppss 'syntax-table)
          (while (search-backward "\n" start t)
            (put-text-property (point) (1+ (point)) 'display
                               (propertize "\n  " 'cursor 0))))))
    face))

(add-hook 'emacs-lisp-mode-hook
          (lambda ()
            (font-lock-mode 1)
            (push 'display font-lock-extra-managed-props)
            (add-function :around (local 'font-lock-syntactic-face-function)
                          #'my-shift-docstrings)))

chỉ nên thay đổi các tài liệu theo 2 khoảng trắng, nhưng chỉ ở phía hiển thị, mà không ảnh hưởng đến nội dung thực tế của bộ đệm.

Bạn có thể sử dụng một macro như thế này:

(defmacro my-defun (name arglist &rest forms)
  "Like `defun', but concatenates strings."
  (declare (indent defun))
  (let (doc-lines)
    (while (and (stringp (car-safe forms))
                (> (length forms) 1))
      (setq doc-lines
            (append doc-lines (list (pop forms)))))
    `(defun ,name ,arglist
       ,(mapconcat #'identity doc-lines "\n")
       ,@forms)))

Sau đó, bạn có thể xác định chức năng của mình như thế này:

(my-defun test (a)
  "Description"
  "asodksad"
  "ok"
  (interactive)
  (+ 1 a))

Tuy nhiên, tôi muốn mạnh mẽ khuyến cáo không đi ngược lại các tiêu chuẩn cho một lợi ích cận biên như vậy. Việc thụt lề không thường xuyên, mà làm phiền bạn chỉ bằng 2 cột, chưa kể nó giúp làm nổi bật dòng tài liệu đầu tiên quan trọng hơn.

Tôi đã thấy các gói xác định các tài liệu như thế này:

(defun my-function (x y) "
this is my docstring
that lines always lines up
across multiple lines."
  (+ x y))

Đặt trích dẫn đầu tiên trên dòng đầu tiên sau đó bắt đầu văn bản trên dòng tiếp theo để tất cả chúng xếp hàng. Đó chắc chắn không phải là tiêu chuẩn nhưng bạn sẽ không phải là người duy nhất làm điều đó.