Làm thế nào tôi có thể lồng một bảng cú pháp trong một bảng khác?

Tôi đã viết một chế độ đơn giản để xử lý JSON. Nó sử dụng các máy móc có nguồn gốc để sử dụng lại hầu hết mã của chế độ json. Tuy nhiên, một bổ sung là bạn có thể chèn elisp vào văn bản JSON được đánh giá tại thời điểm gửi JSON. Ví dụ, một đoạn trích của json trông như thế này:

{
    "parameters": {
        "IRC_USER": "stsquad",
        "PUB_KEY": `(format "\"%s\"" (s-trim (shell-command-to-string "cat ~/.ssh/id_rsa.pub")))`
    }
}

Hiện tại cú pháp tô sáng cú pháp của văn bản này đã bị phá vỡ khi cú pháp JSON hightllight bị ném bởi elisp. Tôi muốn thiết lập một bảng cú pháp lồng nhau để elisp được nhận dạng đúng là elisp khi bên trong các ký tự thoát (tôi đã chọn `trong trường hợp này). Tôi hiểu rằng bạn có thể tham gia các bảng char (bảng cú pháp được xây dựng từ đó) với một cái gì đó như:

(defvar lava-mode-syntax-table
  (let ((json-table (copy-syntax-table json-mode-syntax-table))
        (elisp-table (copy-syntax-table lisp-mode-syntax-table)))
    (set-char-table-parent elisp-table json-table)
    (modify-syntax-entry ?` "(`" json-table)
    (modify-syntax-entry ?` ")`" json-table)
    json-table)
  "LAVA Mode syntax table.
This is a combination of json-mode-syntax-table with an escape into
  lisp-mode-syntax table for the embedded elisp.")

Nhưng tôi không hiểu làm thế nào tôi có thể sửa đổi bảng cú pháp để bắt đầu sử dụng bảng cú pháp con (elisp) trong khi giữa các ký tự thoát?

Bạn không muốn lồng một bảng cú pháp (là cấu trúc vectơ) bên trong một bảng khác, bạn muốn thiết lập một bộ đệm trong đó, tùy thuộc vào vị trí, một bảng cú pháp sẽ được sử dụng thay cho bảng khác.

Câu trả lời khác mô tả cách thực hiện việc này bằng cách sử dụng thuộc tính syntax-tablevăn bản. Đây là cách thực hiện bằng một trong các gói "nhiều chế độ chính", chế độ mmm . Nó sẽ sử dụng mọi thứ của chế độ chính ở cấp cao nhất của bộ đệm và bảng cú pháp của mã con, quy tắc khóa phông chữ, sơ đồ bàn phím, v.v. trong "tiểu vùng".

(require 'mmm-auto)
(setq mmm-global-mode 'auto)

(mmm-add-classes
 '((eljson :submode emacs-lisp-mode
           :front ": *\\(`\\)" :back "`"
           :front-match 1
           :face mmm-code-submode-face)))

(mmm-add-mode-ext-class 'json-mode "\\.el\\.json\\'" 'eljson)

Điều này giả định rằng các tập tin chế độ hỗn hợp của bạn được đặt tên *.el.json. Điều chỉnh cho phù hợp.

Bây giờ, cài đặt mmm-mode, đánh giá ở trên và (chỉ sau đó) mở một trong các tệp được đề cập.

Ok, chúng ta hãy lấy một số điều cơ bản thẳng.

Bảng cú pháp lồng nhau là có thể

Các bảng cú pháp không phải là toàn cục cho toàn bộ bộ đệm. Bạn có thể áp dụng chúng làm thuộc tính văn bản cho các vùng cụ thể. Điều này có nghĩa là bạn thực sự chỉ có thể áp dụng elispbảng cú pháp cho các vùng được bao quanh bởi backticks.

Làm thế nào để bạn làm điều đó?

Đây là một cách bạn có thể làm điều đó. Phương pháp này thực hiện ngay lập tức trước khi khóa phông chữ chạy qua bộ đệm, do đó, nó sẽ đặc biệt ngăn chặn các sự cố khóa phông chữ của bạn.

(defun endless/set-syntax-then-fontify (beg end loudly)
  "Apply elisp syntax table to relevant regions before calling font-lock."
  (save-match-data
    (save-excursion
      (save-restriction
        (widen)
        (narrow-to-region beg end)
        (while (search-forward "`" nil 'noerror)
          ;; Using `end' here excludes the `, I don't know which syntax you
          ;; want to apply to that.
          (let ((left (match-end 0)))
            (when (search-forward "`" nil 'noerror)
              (add-text-properties
               left (match-beginning 0)
               (list 'syntax-table emacs-lisp-mode-syntax-table))))))))
  (font-lock-default-fontify-region beg end loudly))

Trong định nghĩa chế độ chính của bạn, bạn sẽ cần thêm:

(set (make-local-variable 'font-lock-fontify-region-function)
     #'endless/set-syntax-then-fontify)

Các bảng cú pháp không giống như tô sáng cú pháp

Cú pháp tô sáng (hệ thống khóa phông chữ) sử dụng Bảng cú pháp như một phần thông tin của nó, vì vậy giải pháp ở trên sẽ ngăn không cho công cụ tô sáng đi.

Tuy nhiên, đó chỉ là một phần của dữ liệu, nếu bạn cũng muốn văn bản trong backticks được tô màu chính xác như bạn thấy trong bộ đệm elisp, bạn sẽ phải mở rộng chức năng ở trên để thực hiện điều đó một cách cụ thể.

(defun endless/set-syntax-then-fontify (beg end loudly)
  "Apply elisp syntax table to relevant regions before calling font-lock."
  (save-match-data
    (save-excursion
      (save-restriction
        (widen)
        (narrow-to-region beg end)
        (while (search-forward "`" nil 'noerror)
          ;; Using `end' here excludes the `, I don't know which syntax you
          ;; want to apply to that.
          (let ((left (match-end 0)))
            (when (search-forward "`" nil 'noerror)
              (add-text-properties
               left (match-beginning 0)
               (list 'syntax-table emacs-lisp-mode-syntax-table))))))))
  (font-lock-default-fontify-region beg end loudly)
  ;; Do some specific elisp fontifying here
  (save-match-data
    (save-excursion
      (save-restriction
        (widen)
        (narrow-to-region beg end)
        (while (search-forward "`" nil 'noerror)
          (let ((left (match-end 0)))
            (when (search-forward "`" nil 'noerror)
              ;; Call some function to fontify elisp between `left' and (match-beginning 0)
              )))))))