Đặt nền của các khối <code> được xuất theo chủ đề

Tôi xuất các tệp chế độ org khá thường xuyên và hầu như tất cả chúng đều có mã trong đó. Khi tôi thực hiện xuất mã, nó sẽ tô màu văn bản tùy thuộc vào chủ đề của tôi, tuy nhiên, tôi thường xuyên chuyển đổi giữa một chủ đề tối và một chủ đề sáng. Trong trường hợp chủ đề ánh sáng, các <code>khối cần phải có nền sáng và đối với chủ đề tối, chúng cần có nền tối (nếu không, tôi kết thúc bằng văn bản màu vàng nhạt trên nền màu xám và không thể đọc được).

Tôi phải thêm dòng này cho nền tối:

#+HTML_HEAD: <style>pre.src {background-color: #303030; color: #e5e5e5;}</style>

Và sau đó nhớ xóa nó bất cứ khi nào tôi chuyển sang nền màu sáng

Có cách nào để tôi có thể tự động phát hiện màu nền của chủ đề hiện tại khi xuất và sử dụng nó trong CSS của HTML đã xuất không?

CHỈNH SỬA

Tôi đang đi với câu trả lời của Jordon (cảm ơn Jordon, bạn sẽ nhận được điểm nghiệp chướng!), Tuy nhiên tôi muốn đăng giải pháp mà cuối cùng tôi đã thêm vào mã của mình, vì đó là phiên bản sửa đổi một chút của câu trả lời của anh ấy:

(defun my/org-inline-css-hook (exporter)
  "Insert custom inline css to automatically set the
background of code to whatever theme I'm using's background"
  (when (eq exporter 'html)
    (let* ((my-pre-bg (face-background 'default))
           (my-pre-fg (face-foreground 'default)))
      (setq
       org-html-head-extra
       (concat
        org-html-head-extra
        (format "<style type=\"text/css\">\n pre.src {background-color: %s; color: %s;}</style>\n"
                my-pre-bg my-pre-fg))))))

(add-hook 'org-export-before-processing-hook 'my/org-inline-css-hook)

Bộ này không chỉ đặt màu nền mà còn cả màu nền trước. Nó cũng nối thêm dòng vào org-html-head-extracài đặt hiện có để các HTML khác không bị ghi đè một cách tình cờ. Tôi đã thử nghiệm và điều này làm việc rất tốt cho tôi!

Đầu tiên, tôi tin rằng org có thể sử dụng htmlizeđể tự động tô màu các khối mã nguồn theo chủ đề của bạn.

Cách khác.

Kiểm tra http://definiteaplug.b0.cx/post/custom-inlines-css-in-org-mode-html-export/ . Nó có một ví dụ tuyệt vời về cách sử dụng org-export-before-processing-hookđể ném css tùy chỉnh vào tài liệu org trước khi xuất html.

Đây là mã trong trường hợp trang web bị sập:

Ở đây khi xuất html, org sẽ tìm một tệp có tên là style.css trong thư mục hiện tại hoặc một tệp mặc định trong thư mục .emacs.d và đưa css đó vào tài liệu. Điều này là tốt đẹp nhưng không hoàn hảo cho trường hợp sử dụng của bạn.

(defun my-org-inline-css-hook (exporter)
  "Insert custom inline css"
  (when (eq exporter 'html)
    (let* ((dir (ignore-errors (file-name-directory (buffer-file-name))))
           (path (concat dir "style.css"))
           (homestyle (or (null dir) (null (file-exists-p path))))
           (final (if homestyle "~/.emacs.d/org-style.css" path)))
      (setq org-html-head-include-default-style nil)
      (setq org-html-head (concat
                           "<style type=\"text/css\">\n"
                           "<!--/*--><![CDATA[/*><!--*/\n"
                           (with-temp-buffer
                             (insert-file-contents final)
                             (buffer-string))
                           "/*]]>*/-->\n"
                           "</style>\n")))))

(add-hook 'org-export-before-processing-hook 'my-org-inline-css-hook)

Bạn có thể tùy chỉnh điều này theo một số cách để làm cho nó hoạt động như bạn muốn.

Một cách sẽ là tự xây dựng css dựa trên chủ đề của bạn và chèn nó.

Đây là một phiên bản sửa đổi đặt nền của pre.srcgiá trị hex của các mặt mặc định: thuộc tính nền.

(defun my-org-inline-css-hook (exporter)
  "Insert custom inline css"
  (when (eq exporter 'html)
    (let ((my-pre-bg (face-background 'default)))
      (setq org-html-head-include-default-style nil)
      (setq org-html-head
            (format "<style type=\"text/css\">\n pre.src { background-color: %s;}</style>\n" my-pre-bg)))))

(add-hook 'org-export-before-processing-hook 'my-org-inline-css-hook)