Làm thế nào để ghi đè các ràng buộc chế độ chính

Đôi khi các phím bấm toàn cầu của tôi bị ghi đè bởi một chế độ chính. Một ví dụ dễ hiểu là cài đặt sau trong tệp init của tôi

(global-set-key (kbd "C-j") 'newline-and-indent)

Nhưng thật khó chịu khi thao tác bấm phím này bị ẩn bởi chế độ chính "Tương tác Lisp" là chế độ mặc định của bộ đệm đầu.

Khi tôi thấy mình trong một tình huống mà một chế độ chính (hoặc chế độ phụ) đang ẩn khóa liên kết toàn cầu của tôi, làm thế nào tôi có thể lấy lại được?

Lưu ý: Câu hỏi của tôi không phải là "Làm thế nào tôi có thể ràng buộc C-jđể newline-and-indent'? Chế độ' trong" Lisp Interaction Tôi quan tâm đến một câu trả lời tổng quát hơn nhiều về cách xử lý các keymap mà xung đột hoặc các keybindings bị ẩn bởi một số chế độ chính / phụ.

Có một cách tiếp cận "phím tắt" cho cùng một giải pháp nếu bạn không muốn xác định chế độ nhỏ của riêng mình (mà tôi nói về câu trả lời đầu tiên của tôi).

Bạn có thể cài đặt use-packagegói có sẵn từ Melpa và sử dụng bind-key*hoặc bind-keys*macro đó là một phần của bind-keygói đi kèm use-package.

Từ các tài liệu của bind-key.el:

;; If you want the keybinding to override all minor modes that may also bind
;; the same key, use the `bind-key*' form:
;;
;;   (bind-key* "<C-return>" 'other-window)

;; To bind multiple keys in a `bind-key*' way (to be sure that your bindings
;; will not be overridden by other modes), you may use `bind-keys*' macro:
;;
;;    (bind-keys*
;;     ("C-o" . other-window)
;;     ("C-M-n" . forward-page)
;;     ("C-M-p" . backward-page))

Bạn có thể xác định chế độ phụ của riêng mình và bản đồ chính của nó và có chế độ ghi đè tất cả các chế độ khác (phụ + chính). Đó chính xác là lý do tại sao tôi chọn viết chế độ nhỏ của riêng mình.

Các bước để có các ràng buộc chính của bạn ghi đè tất cả các ràng buộc:

• Xác định chế độ nhỏ của riêng bạn và bản đồ chính như dưới đây.
• Kích hoạt chế độ nhỏ của bạn trên toàn cầu
• (define-key my-mode-map (kbd "C-j") #'newline-and-indent)

Tương tự, các ràng buộc khóa khác của bạn được đặt trong chế độ nhỏ của bạn sẽ ghi đè lên các ràng buộc trong các chế độ khác.

Tôi đặc biệt khuyên bạn nên đọc bài đăng trên blog của Christopher Wellons về cách viết một chế độ nhỏ. Blog đó cộng với sự khó chịu khi phải đặt nhiều ràng buộc chính nilở nhiều chế độ chính và phụ đã thôi thúc tôi viết chế độ nhỏ của riêng mình.

Phần tốt nhất của việc sử dụng phương pháp này là khi bạn muốn kiểm tra các ràng buộc chính làm gì trong cấu hình mặc định của emacs, bạn chỉ cần tắt chế độ nhỏ của mình; sau đó bạn bật lại và bạn lấy lại các ràng buộc khóa tùy chỉnh của mình.

;; Main use is to have my key bindings have the highest priority
;; https://github.com/kaushalmodi/.emacs.d/blob/master/elisp/modi-mode.el

(defvar my-mode-map (make-sparse-keymap)
  "Keymap for `my-mode'.")

;;;###autoload
(define-minor-mode my-mode
  "A minor mode so that my key settings override annoying major modes."
  ;; If init-value is not set to t, this mode does not get enabled in
  ;; `fundamental-mode' buffers even after doing \"(global-my-mode 1)\".
  ;; More info: http://emacs.stackexchange.com/q/16693/115
  :init-value t
  :lighter " my-mode"
  :keymap my-mode-map)

;;;###autoload
(define-globalized-minor-mode global-my-mode my-mode my-mode)

;; https://github.com/jwiegley/use-package/blob/master/bind-key.el
;; The keymaps in `emulation-mode-map-alists' take precedence over
;; `minor-mode-map-alist'
(add-to-list 'emulation-mode-map-alists `((my-mode . ,my-mode-map)))

;; Turn off the minor mode in the minibuffer
(defun turn-off-my-mode ()
  "Turn off my-mode."
  (my-mode -1))
(add-hook 'minibuffer-setup-hook #'turn-off-my-mode)

(provide 'my-mode)

;; Minor mode tutorial: http://nullprogram.com/blog/2013/02/06/

Để có một ràng buộc toàn cầu ghi đè lên một ràng buộc chế độ chính, chỉ cần đặt liên kết thành niltrong chế độ chính:

(define-key my-major-mode-map (kbd "C-j") nil)

Không thể có sự ràng buộc toàn cầu được ưu tiên hơn tất cả các chế độ nói chung (nếu không sẽ không có điểm nào trong việc có các chế độ chính), nhưng bạn có thể hack xung quanh nó bằng cách tạo chế độ nhỏ của riêng bạn với các ràng buộc quan trọng nhất của bạn. Sau đó, bạn ít nhất sẽ có quyền ưu tiên hơn hầu hết các chế độ (mặc dù không nhất thiết là tất cả).

Bạn có thể sử dụng các macro này:

(defmacro expose-global-keybinding (binding map)
  `(define-key ,map ,binding (lookup-key (current-global-map) ,binding)))

(defmacro expose-bindings (map bindings)
  `(dolist (bnd ,bindings)
     (expose-global-keybinding (kbd bnd) ,map)))

CHỈNH SỬA :

Kiểm tra ví dụ dưới đây:

Nếu sơ đồ bàn phím X ghi đè lên ràng buộc toàn cầu Y của bạn, bạn viết:

(expose-bindings X '("Y"))

Và sau đó, phần ghi đè sẽ được 'hoàn tác'.