Làm cách nào để xóa macro LaTeX trong khi bảo tồn nội dung văn bản của nó?

Trong TeXStudio bằng cách nhấn ALT+ DELtrong macro LaTeX như thế này \macroname{content}trong khi con trỏ đứng ngay trước dấu đầu tiên {sẽ dẫn đến xóa tất cả những thứ đó ngoại trừ nó content(như hiển thị bên dưới).

Đặt con trỏ (điểm) ngay trước dấu ngoặc nhọn đầu tiên:

Lượt ALT+ DELvà bạn nhận được:

Làm thế nào để đạt được điều này trong Emacs?

Cập nhật
Theo sự làm rõ của T.Verron, có một vấn đề C-c C-f C-dvì nó phàn nàn về lỗi của dấu ngoặc đơn không cân bằng khi được thực thi trong một số macro trong LaTeX. Hãy xem xét ví dụ dưới đây:

ném lỗi này : up-list: Scan error: "Unbalanced parentheses", 8074, 1. \ textenglish {} thuộc gói polyglossia.

Làm thế nào để thoát khỏi cảnh báo này?

Hãy thử chức năng này:

(defun mg-TeX-delete-current-macro (&optional arg)
  "Remove the current macro.
With an optional argument ARG, delete just the ARG-th macro
starting from the innermost."
  (interactive "*p")
  (let (macro end)
    (when 
    (dotimes (i arg macro)
      (goto-char (TeX-find-macro-start))
      (setq macro (TeX-current-macro)
        end (TeX-find-macro-end))
      ;; If we need to look for an outer macro we have to "exit" from the
      ;; current one.
      (backward-char))
      ;; Return to the beginning of the macro to be deleted.
      (forward-char)
      (re-search-forward
       (concat (regexp-quote TeX-esc) macro "\\(?:\\[[^]]*\\]\\)?"
           TeX-grop "\\(\\(.\\|\n\\)*\\)")
       end t)
      (replace-match "\\1")
      ;; Delete the closing brace.
      (delete-backward-char 1))))

Giới hạn: không hoạt động với các macro giống như nguyên văn. Hàm này sẽ đưa ra một lỗi ( Wrong type argument: integer-or-marker-p, nil) nếu đối số phổ quát lớn hơn số lượng điểm bao quanh macro.

Liên kết các chức năng với phím tắt yêu thích của bạn. Ví dụ

(eval-after-load "tex"
  '(local-set-key (kbd "M-DEL") 'mg-TeX-delete-current-macro))

để ràng buộc nó M-DEL.

Nếu bộ đệm của bạn có ( !là điểm)

\onemacro{\anothermacro{!argument}}

sau đó C-2 M-DELsẽ cho bạn

\anothermacro{argument}

Từ nút thủ công AocateeX về Thay đổi phông chữ :

C-c C-f C-d

Delete the innermost font specification containing point.

Đây là một chức năng đơn giản để loại bỏ macro chứa tại điểm:

(defun TeX-remove-macro ()
  "Remove current macro and return `t'.  If no macro at point,
return `nil'."
  (interactive)
  (when (TeX-current-macro)
    (let ((bounds (TeX-find-macro-boundaries))
          (brace  (save-excursion
                    (goto-char (1- (TeX-find-macro-end)))
                    (TeX-find-opening-brace))))
      (delete-region (1- (cdr bounds)) (cdr bounds))
      (delete-region (car bounds) (1+ brace)))
    t))

Do đó, với *điểm:

\footnote{Here's a * footnote} 
  => Here's a footnote

Với chức năng trên, đây là một lớp lót để loại bỏ tất cả các macro tại điểm:

(defun TeX-remove-all-macros ()
  "Remove all containing macros for text at point."
  (interactive)
  (while (TeX-remove-macro)))

Do đó, một lần nữa với *quan điểm:

\footnote{Here's a \textbf{footnote with \emph{emphasized * text}}} 
  => Here's a footnote with emphasized text