Làm cách nào để tôi chỉnh sửa một hàm được xác định trong khối gói sử dụng?

Dưới đây là một ví dụ hoạt động tối thiểu để chứng minh vấn đề, bạn sẽ cần use-packagecài đặt gói:

(use-package ido
  :config
  (progn
    (defun dummy/function ()
      (interactive)
      (message "I am in the dummy function."))))

Khi tôi cố gắng thêm thiết bị edebug vào dummy/functionsử dụng M-x edebug-defun, nó sẽ khởi động edebug ngay lập tức như thể tôi đã làm M-x dummy/function. Tôi phải bỏ nó bằng cách đánh q. Nhưng sau đó khi tôi thực sự làm M-x dummy/function, tôi không thấy edebug kích hoạt.

Có một cái gì đó về use-packagetrình bao bọc gây rối với các thiết bị edebug? Làm thế nào nó có thể được cố định?

Khi bạn gọi edebug-defunnó là gỡ lỗi hình thức cấp cao nhất, trong trường hợp này là (use-package ...).

Bạn có thể sử dụng debug-on-entryđể gỡ lỗi một chức năng được đặt tên.

1. Đánh dấu defun thích hợp và gọi C-x nn( narrow-to-region)
2. C-u C-M-x( edebug-defun)
3. C-x nw( widen)

Nếu bạn thích làm việc nhanh chóng, phím tắt lispy cho việc này là N xe W.

edebug-defun

Cảm ơn @ abo-abo cho mẹo để đánh dấu defun đầu tiên.

Đây là một cách nhanh chóng để bật / tắt edebug-defun. Điều này sử dụng search-backward-regexpđể edebug-instrument hoặc eval tên defun hoặc defmacro một cách chính xác, cho dù nó được xác định trong use-packagetrình bao bọc hay không.

;; Edebug a defun or defmacro
(defvar modi/fns-in-edebug nil
  "List of functions for which `edebug' is instrumented.")

(defconst modi/fns-regexp (concat "(\\s-*"
                                  "\\(defun\\|defmacro\\)\\s-+"
                                  "\\(?1:\\(\\w\\|\\s_\\)+\\)\\_>") ; word or symbol char
  "Regexp to find defun or defmacro definition.")

(defun modi/toggle-edebug-defun ()
  (interactive)
  (let (fn)
    (save-excursion
      (search-backward-regexp modi/fns-regexp)
      (setq fn (match-string 1))
      (mark-sexp)
      (narrow-to-region (point) (mark))
      (if (member fn modi/fns-in-edebug)
          ;; If the function is already being edebugged, uninstrument it
          (progn
            (setq modi/fns-in-edebug (delete fn modi/fns-in-edebug))
            (eval-region (point) (mark))
            (setq-default eval-expression-print-length 12)
            (setq-default eval-expression-print-level  4)
            (message "Edebug disabled: %s" fn))
        ;; If the function is not being edebugged, instrument it
        (progn
          (add-to-list 'modi/fns-in-edebug fn)
          (setq-default eval-expression-print-length nil)
          (setq-default eval-expression-print-level  nil)
          (edebug-defun)
          (message "Edebug: %s" fn)))
      (widen))))

Cách sử dụng - Với điểm bất kỳ nơi nào trong thân hàm / macro, việc gọi modi/toggle-edebug-defunsẽ bật hoặc tắt edebugcho thực thể đó.

debug-on-entry

Nhờ @glucas và @Drew, tôi đã tạo ra một cách thuận tiện để chuyển đổi debug-on-entry. Điều này cũng sử dụng cách tiếp cận tương tự như trên để phân tích tên defun / defmacro.

;; Debug on entry
(defvar modi/fns-in-debug nil
  "List of functions for which `debug-on-entry' is instrumented.")

(defun modi/toggle-debug-defun ()
  (interactive)
  (let (fn)
    (save-excursion
      (search-backward-regexp modi/fns-regexp)
      (setq fn (match-string 1)))
    (if (member fn modi/fns-in-debug)
        ;; If the function is already being debugged, cancel its debug on entry
        (progn
          (setq modi/fns-in-debug (delete fn modi/fns-in-debug))
          (cancel-debug-on-entry (intern fn))
          (message "Debug-on-entry disabled: %s" fn))
      ;; If the function is not being debugged, debug it on entry
      (progn
        (add-to-list 'modi/fns-in-debug fn)
        (debug-on-entry (intern fn))
        (message "Debug-on-entry: %s" fn)))))

Cách sử dụng - Với điểm bất kỳ nơi nào trong thân hàm, việc gọi modi/toggle-debug-defunsẽ bật hoặc hủy debug-on-errorchức năng đó.