Trong CMake, làm cách nào để kiểm tra xem trình biên dịch có phải là Clang không?

Chúng tôi có một bộ các kịch bản xây dựng CMake đa nền tảng và chúng tôi hỗ trợ xây dựng với Visual C ++ và GCC .

Chúng tôi đang thử Clang , nhưng tôi không thể tìm ra cách kiểm tra xem trình biên dịch có phải là Clang với tập lệnh CMake của chúng tôi hay không.

Tôi nên kiểm tra xem trình biên dịch có phải là Clang hay không? Chúng tôi hiện đang sử dụng MSVCvà CMAKE_COMPILER_IS_GNU<LANG>để kiểm tra Visual C ++ và GCC, tương ứng.

Một kiểm tra đáng tin cậy là sử dụng các CMAKE_<LANG>_COMPILER_IDbiến. Ví dụ, để kiểm tra trình biên dịch C ++:

if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  # using Clang
elseif (CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  # using GCC
elseif (CMAKE_CXX_COMPILER_ID STREQUAL "Intel")
  # using Intel C++
elseif (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
  # using Visual Studio C++
endif()

Chúng cũng hoạt động chính xác nếu một trình bao bọc trình biên dịch như ccache được sử dụng.

Kể từ CMake 3.0.0, CMAKE_<LANG>_COMPILER_IDgiá trị cho Clang do Apple cung cấp hiện đã có AppleClang. Để kiểm tra cả Clang do Apple cung cấp và Clang thông thường, hãy sử dụng các điều sau nếu có điều kiện:

if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  # using regular Clang or AppleClang
endif()

Cũng xem mô tả chính sách của AppleClang .

CMake 3.15 đã bổ sung hỗ trợ cho cả clang-cl và mặt trước clang thông thường. Bạn có thể xác định biến thể giao diện người dùng bằng cách kiểm tra biến CMAKE_CXX_COMPILER_FRONTEND_VARIANT:

if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  if (CMAKE_CXX_COMPILER_FRONTEND_VARIANT STREQUAL "MSVC")
    # using clang with clang-cl front end
  elseif (CMAKE_CXX_COMPILER_FRONTEND_VARIANT STREQUAL "GNU")
    # using clang with regular front end
  endif()
endif()

Mã nguồn của công cụ OGRE 3D sử dụng như sau kiểm tra :

if (CMAKE_CXX_COMPILER MATCHES ".*clang")
    set(CMAKE_COMPILER_IS_CLANGXX 1)
endif ()

Để tránh mọi vấn đề sai chính tả, tôi đang sử dụng phép so sánh không phân biệt chữ hoa chữ thường, như:

string( TOLOWER "${CMAKE_CXX_COMPILER_ID}" COMPILER_ID )
if (COMPILER_ID STREQUAL "clang")
    set(IS_CLANG_BUILD true)
else ()
    set(IS_CLANG_BUILD false)
endif ()

Để tạo ra biểu thức MATCHESkhông phân biệt chữ hoa chữ thường, tôi đã thử mọi thứ ở đây mà không thành công (dường như không được hỗ trợ trong CMake).

Đây là một câu trả lời chi tiết hơn một chút cho những người mới chơi cmake, được sửa đổi từ câu trả lời của sakra, chỉ cần nối các dòng sau vào CMakeLists.txt:

if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
  MESSAGE("Clang")
elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
  MESSAGE("GNU")
elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Intel")
  MESSAGE("Intel")
elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "MSVC")
  MESSAGE("MSVC")
endif()

Sau đó chạy cmake .trong thư mục chứa CMakeLists.txt. Sau đó, bạn sẽ thấy một loạt các kết quả đầu ra cùng với câu trả lời của bạn.

...
-- Detecting CXX compile features
-- Detecting CXX compile features - done
GNU
-- Configuring done
-- Generating done
...