Làm thế nào để tôi có được kết quả của một lệnh trong một biến trong windows?

Tôi đang tìm cách lấy kết quả của một lệnh dưới dạng một biến trong tập lệnh bó của Windows (xem cách lấy kết quả của lệnh trong bash cho tương đương tập lệnh bash). Một giải pháp sẽ hoạt động trong tệp .bat được ưa thích, nhưng các giải pháp kịch bản Windows phổ biến khác cũng được hoan nghênh.

Nếu bạn phải nắm bắt tất cả đầu ra lệnh, bạn có thể sử dụng một lô như thế này:

@ECHO OFF
IF NOT "%1"=="" GOTO ADDV
SET VAR=
FOR /F %%I IN ('DIR *.TXT /B /O:D') DO CALL %0 %%I
SET VAR
GOTO END

:ADDV
SET VAR=%VAR%!%1

:END

Tất cả các dòng đầu ra được lưu trữ trong VAR được phân tách bằng "!".

@ John: có sử dụng thực tế cho việc này không? Tôi nghĩ bạn nên xem PowerShell hoặc bất kỳ ngôn ngữ lập trình nào khác có khả năng thực hiện các tác vụ kịch bản một cách dễ dàng (Python, Perl, PHP, Ruby)

Sự khiêm tốn cho mệnh lệnh đã tích lũy một số khả năng thú vị trong những năm qua:

D:\> FOR /F "delims=" %i IN ('date /t') DO set today=%i
D:\> echo %today%
Sat 20/09/2008

Lưu ý rằng "delims="ghi đè không gian mặc định và dấu phân cách tab để đầu ra của lệnh date bị ngấu nghiến cùng một lúc.

Để nắm bắt đầu ra đa dòng, về cơ bản nó vẫn có thể là một lớp lót (sử dụng biến lf làm dấu phân cách trong biến kết quả):

REM NB:in a batch file, need to use %%i not %i
setlocal EnableDelayedExpansion
SET lf=-
FOR /F "delims=" %%i IN ('dir \ /b') DO if ("!out!"=="") (set out=%%i) else (set out=!out!%lf%%%i)
ECHO %out%

Để chụp biểu thức đường ống, sử dụng ^|:

FOR /F "delims=" %%i IN ('svn info . ^| findstr "Root:"') DO set "URL=%%i"

Để có được thư mục hiện tại, bạn có thể sử dụng:

CD > tmpFile
SET /p myvar= < tmpFile
DEL tmpFile
echo test: %myvar%

Mặc dù nó đang sử dụng một tệp tạm thời, vì vậy nó không phải là đẹp nhất, nhưng nó chắc chắn hoạt động! 'CD' đặt thư mục hiện tại vào 'tmpFile', 'SET' tải nội dung của tmpFile.

Đây là một giải pháp cho nhiều dòng với "mảng":

@echo off

rem ---------
rem Obtain line numbers from the file
rem ---------

rem This is the file that is being read: You can replace this with %1 for dynamic behaviour or replace it with some command like the first example i gave with the 'CD' command.
set _readfile=test.txt

for /f "usebackq tokens=2 delims=:" %%a in (`find /c /v "" %_readfile%`) do set _max=%%a
set /a _max+=1
set _i=0
set _filename=temp.dat

rem ---------
rem Make the list
rem ---------

:makeList
find /n /v "" %_readfile% >%_filename%

rem ---------
rem Read the list
rem ---------

:readList
if %_i%==%_max% goto printList

rem ---------
rem Read the lines into the array
rem ---------
for /f "usebackq delims=] tokens=2" %%a in (`findstr /r "\[%_i%]" %_filename%`) do set _data%_i%=%%a
set /a _i+=1
goto readList

:printList
del %_filename%
set _i=1
:printMore
if %_i%==%_max% goto finished
set _data%_i%
set /a _i+=1
goto printMore

:finished

Nhưng bạn có thể muốn xem xét chuyển sang một trình bao mạnh hơn khác hoặc tạo một ứng dụng cho công cụ này. Nó kéo dài khả năng của các tệp bó khá nhiều.

bạn cần sử dụng SETlệnh với tham số /Pvà hướng đầu ra của bạn tới nó. Ví dụ: xem http://www.ss64.com/nt/set.html . Sẽ hoạt động cho CMD, không chắc chắn về các tệp .BAT

Từ một bình luận cho bài viết này:

Liên kết đó có lệnh " Set /P _MyVar=<MyFilename.txt" cho biết nó sẽ được đặt thành _MyVardòng đầu tiên từ đó MyFilename.txt. Điều này có thể được sử dụng như " myCmd > tmp.txt" với " set /P myVar=<tmp.txt". Nhưng nó sẽ chỉ nhận được dòng đầu tiên của đầu ra, không phải tất cả đầu ra

Ví dụ để đặt trong biến môi trường "V" tệp gần đây nhất

FOR /F %I IN ('DIR *.* /O:D /B') DO SET V=%I

trong một tệp bó, bạn phải sử dụng tiền tố kép trong biến vòng lặp:

FOR /F %%I IN ('DIR *.* /O:D /B') DO SET V=%%I

Chỉ cần sử dụng kết quả từ FORlệnh. Ví dụ: (bên trong một tệp bó):

for /F "delims=" %%I in ('dir /b /a-d /od FILESA*') do (echo %%I)

Bạn có thể sử dụng %%Inhư giá trị bạn muốn. Chỉ như thế này : %%I.

Và trước %%Iđó không có bất kỳ khoảng trắng hoặc ký tự CR nào và có thể được sử dụng để so sánh !!

Nếu bạn đang tìm kiếm giải pháp được cung cấp trong Sử dụng kết quả của lệnh làm đối số trong bash?

đây là đoạn mã:

@echo off
if not "%1"=="" goto get_basename_pwd
for /f "delims=X" %%i in ('cd') do call %0 %%i
for /f "delims=X" %%i in ('dir /o:d /b') do echo %%i>>%filename%.txt
goto end

:get_basename_pwd
set filename=%~n1

:end

• Điều này sẽ tự gọi với kết quả của lệnh CD, giống như pwd.
• Khai thác chuỗi trên các tham số sẽ trả về tên tệp / thư mục.
• Lấy nội dung của thư mục này và nối vào filename.txt

[Tín dụng] : Nhờ tất cả các câu trả lời khác và một số hoạt động đào trên trang lệnh Windows XP .

@echo off

ver | find "6.1." > nul
if %ERRORLEVEL% == 0 (
echo Win7
for /f "delims=" %%a in ('DIR "C:\Program Files\Microsoft Office\*Outlook.EXE" /B /P /S') do call set findoutlook=%%a
%findoutlook%
)

ver | find "5.1." > nul
if %ERRORLEVEL% == 0 (
echo WinXP
for /f "delims=" %%a in ('DIR "C:\Program Files\Microsoft Office\*Outlook.EXE" /B /P /S') do call set findoutlook=%%a
%findoutlook%
)
echo Outlook dir:  %findoutlook%
"%findoutlook%"

Tôi muốn thêm một nhận xét cho các giải pháp trên:

Tất cả các cú pháp này hoạt động hoàn toàn tốt NẾU QUYỀN CỦA BẠN ĐƯỢC TÌM KIẾM TRONG ĐƯỜNG hoặc NẾU QUYỀN LÀ một cmdpath KHÔNG CÓ SPACES HOẶC ĐẶC ĐIỂM ĐẶC BIỆT.

Nhưng nếu bạn cố gắng sử dụng một lệnh thực thi nằm trong thư mục chứa đường dẫn chứa các ký tự đặc biệt thì bạn sẽ cần phải đóng đường dẫn lệnh của mình thành dấu ngoặc kép (") và sau đó cú pháp FOR / F không hoạt động.

Ví dụ:

$ for /f "tokens=* USEBACKQ" %f in (
    `""F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" Hello '"F:\GLW7\Distrib\System\Shells and scripting"'`
) do echo %f
The filename, directory name, or volume label syntax is incorrect.

hoặc là

$ for /f "tokens=* USEBACKQ" %f in (
      `"F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe" "Hello World" "F:\GLW7\Distrib\System\Shells and scripting"`
) do echo %f
'F:\GLW7\Distrib\System\Shells' is not recognized as an internal or external command, operable program or batch file.

hoặc là

`$ for /f "tokens=* USEBACKQ" %f in (
     `""F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" "Hello World" "F:\GLW7\Distrib\System\Shells and scripting"`
) do echo %f
'"F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" "Hello' is not recognized as an internal or external command, operable program or batch file.

Trong trường hợp đó, giải pháp duy nhất tôi tìm thấy để sử dụng lệnh và lưu trữ kết quả của nó trong một biến là đặt (tạm thời) thư mục mặc định thành chính lệnh đó:

pushd "%~d0%~p0"
FOR /F "tokens=* USEBACKQ" %%F IN (
    `FOLDERBROWSE "Hello world!" "F:\GLW7\Distrib\System\Layouts (print,display...)"`
) DO (SET MyFolder=%%F)
popd
echo My selected folder: %MyFolder%

Kết quả là chính xác:

My selected folder: F:\GLW7\Distrib\System\OS install, recovery, VM\
Press any key to continue . . .

Tất nhiên trong ví dụ trên, tôi giả sử rằng tập lệnh bó của tôi nằm trong cùng thư mục với một trong những lệnh thực thi của tôi để tôi có thể sử dụng cú pháp "% ~ d0% ~ p0". Nếu đây không phải là trường hợp của bạn, thì bạn phải tìm cách xác định vị trí đường dẫn lệnh của mình và thay đổi thư mục mặc định thành đường dẫn của nó.

NB: Đối với những người thắc mắc, lệnh mẫu được sử dụng ở đây (để chọn thư mục) là FOLDERBROWSE.EXE. Tôi tìm thấy nó trên trang web f2ko.de ( http://f2ko.de/en/cmd.php ).

Nếu bất cứ ai có một giải pháp tốt hơn cho loại lệnh đó có thể truy cập thông qua một đường dẫn phức tạp, tôi sẽ rất vui mừng khi nghe về nó.

Gilles

Bạn có thể nắm bắt tất cả đầu ra trong một biến, nhưng các dòng sẽ được phân tách bằng một ký tự bạn chọn (# trong ví dụ bên dưới) thay vì CR-LF thực tế.

@echo off
setlocal EnableDelayedExpansion
for /f "delims=" %%i in ('dir /b') do (
    if "!DIR!"=="" (set DIR=%%i) else (set DIR=!DIR!#%%i)
)
echo directory contains:
echo %DIR%

Phiên bản thứ hai, nếu bạn cần in nội dung ra từng dòng một. Điều này có lợi cho thực tế là sẽ không có dòng đầu ra trùng lặp từ "dir / b", vì vậy nó có thể không hoạt động trong trường hợp chung.

@echo off
setlocal EnableDelayedExpansion
set count=0
for /f "delims=" %%i in ('dir /b') do (
    if "!DIR!"=="" (set DIR=%%i) else (set DIR=!DIR!#%%i)
    set /a count = !count! + 1
)

echo directory contains:
echo %DIR%

for /l %%c in (1,1,%count%) do (
    for /f "delims=#" %%i in ("!DIR!") do (
        echo %%i
        set DIR=!DIR:%%i=!
    )
)

@echo off
setlocal EnableDelayedExpansion
FOR /F "tokens=1 delims= " %%i IN ('echo hola') DO (
    set TXT=%%i
)
echo 'TXT: %TXT%'

kết quả là 'TXT: hola'

Bạn nên sử dụng forlệnh, đây là một ví dụ:

@echo off
rem Commands go here
exit /b
:output
for /f "tokens=* useback" %%a in (`%~1`) do set "output=%%a"

và bạn có thể sử dụng call :output "Command goes here"thì đầu ra sẽ ở trong %output%biến.

Lưu ý: Nếu bạn có đầu ra lệnh là multiline, công cụ này sẽ setxuất đầu ra đến dòng cuối cùng của lệnh multiline của bạn.

Vui lòng tham khảo http://technet.microsoft.com/en-us/l Library / bb490982.aspx này để giải thích những gì bạn có thể làm với đầu ra lệnh.