Làm cách nào để tìm nạp nhiều cột để sử dụng trong vòng lặp con trỏ?

Question 1

Khi tôi cố gắng chạy đoạn mã SQL sau bên trong vòng lặp con trỏ,

set @cmd = N'exec sp_rename ' + @test + N',' +
           RIGHT(@test,LEN(@test)-3) + '_Pct' + N',''COLUMN'''

Tôi nhận được tin nhắn sau,

Msg 15248, Mức 11, Trạng thái 1, Thủ tục sp_rename, Dòng 213
Hoặc tham số @objnamekhông rõ ràng hoặc xác nhận quyền sở hữu @objtype(COLUMN) là sai.

Điều gì là sai và làm thế nào để tôi sửa chữa nó? Tôi đã thử đặt tên cột trong dấu ngoặc []và dấu ngoặc kép ""như một số kết quả tìm kiếm được đề xuất.

Chỉnh sửa 1 -

Đây là toàn bộ kịch bản. Làm cách nào để chuyển tên bảng sang tên sp? Tôi không chắc làm thế nào để làm điều đó vì tên cột nằm ở một trong nhiều bảng.

BEGIN TRANSACTION

declare @cnt int
declare @test nvarchar(128)
declare @cmd nvarchar(500) 
declare Tests cursor for
SELECT COLUMN_NAME FROM INFORMATION_SCHEMA.COLUMNS WHERE COLUMN_NAME LIKE 'pct%' AND TABLE_NAME LIKE 'TestData%'

open Tests
fetch next from Tests into @test
while @@fetch_status = 0
BEGIN
  set @cmd = N'exec sp_rename ' + @test + N',' + RIGHT(@test,LEN(@test)-3) + '_Pct' + N', column' 

  print @cmd

  EXEC sp_executeSQL @cmd

  fetch next from Tests into @test
END

close Tests 
deallocate Tests


ROLLBACK TRANSACTION
--COMMIT TRANSACTION

Chỉnh sửa 2 - Tập lệnh được thiết kế để đổi tên các cột có tên khớp với một mẫu, trong trường hợp này là tiền tố "pct". Các cột xuất hiện trong nhiều bảng trong cơ sở dữ liệu. Tất cả các tên bảng đều có tiền tố là "TestData".

Question 2

Đây là phiên bản sửa đổi một chút. Các thay đổi được ghi nhận dưới dạng bình luận mã.

BEGIN TRANSACTION

declare @cnt int
declare @test nvarchar(128)
-- variable to hold table name
declare @tableName nvarchar(255)
declare @cmd nvarchar(500) 
-- local means the cursor name is private to this code
-- fast_forward enables some speed optimizations
declare Tests cursor local fast_forward for
 SELECT COLUMN_NAME, TABLE_NAME
   FROM INFORMATION_SCHEMA.COLUMNS 
  WHERE COLUMN_NAME LIKE 'pct%' 
    AND TABLE_NAME LIKE 'TestData%'

open Tests
-- Instead of fetching twice, I rather set up no-exit loop
while 1 = 1
BEGIN
  -- And then fetch
  fetch next from Tests into @test, @tableName
  -- And then, if no row is fetched, exit the loop
  if @@fetch_status <> 0
  begin
     break
  end
  -- Quotename is needed if you ever use special characters
  -- in table/column names. Spaces, reserved words etc.
  -- Other changes add apostrophes at right places.
  set @cmd = N'exec sp_rename ''' 
           + quotename(@tableName) 
           + '.' 
           + quotename(@test) 
           + N''',''' 
           + RIGHT(@test,LEN(@test)-3) 
           + '_Pct''' 
           + N', ''column''' 

  print @cmd

  EXEC sp_executeSQL @cmd
END

close Tests 
deallocate Tests

ROLLBACK TRANSACTION
--COMMIT TRANSACTION