Làm thế nào để sử dụng cấu trúc if - other trong một tệp bó?

Tôi có một câu hỏi về cấu trúc if - other trong một tệp bó. Mỗi lệnh chạy riêng lẻ, nhưng tôi không thể sử dụng các khối "nếu - khác" một cách an toàn để các phần này trong chương trình của tôi không hoạt động. Làm thế nào tôi có thể làm cho những phần này chạy? Cảm ơn bạn.

IF %F%==1 IF %C%==1 (
    ::copying the file c to d
    copy "%sourceFile%" "%destinationFile%"
    )
ELSE IF %F%==1 IF %C%==0 (
    ::moving the file c to d
    move "%sourceFile%" "%destinationFile%"
    )

ELSE IF %F%==0 IF %C%==1 (
    ::copying a directory c from d, /s:  boş olanlar hariç, /e:boş olanlar dahil
    xcopy "%sourceCopyDirectory%" "%destinationCopyDirectory%" /s/e
    )
ELSE IF %F%==0 IF %C%==0 (
    ::moving a directory
    xcopy /E "%sourceMoveDirectory%" "%destinationMoveDirectory%"
    rd /s /q "%sourceMoveDirectory%"
    )

Cú pháp của bạn không chính xác. Bạn không thể sử dụng ELSE IF. Dường như bạn không thực sự cần nó. Đơn giản chỉ cần sử dụng nhiều IFcâu lệnh:

IF %F%==1 IF %C%==1 (
    ::copying the file c to d
    copy "%sourceFile%" "%destinationFile%"
    )

IF %F%==1 IF %C%==0 (
    ::moving the file c to d
    move "%sourceFile%" "%destinationFile%"
    )

IF %F%==0 IF %C%==1 (
    ::copying a directory c from d, /s:  boş olanlar hariç, /e:boş olanlar dahil
    xcopy "%sourceCopyDirectory%" "%destinationCopyDirectory%" /s/e
    )

IF %F%==0 IF %C%==0 (
    ::moving a directory
    xcopy /E "%sourceMoveDirectory%" "%destinationMoveDirectory%"
    rd /s /q "%sourceMoveDirectory%"
    )

Tài liệu tham khảo tập tin tuyệt vời: http://ss64.com/nt/if.html

Tôi nghĩ trong câu hỏi và trong một số câu trả lời có một chút nhầm lẫn về ý nghĩa của mã giả này trong DOS: IF A IF BX ELSE Y. Nó không có nghĩa là IF A và B) THEN X ELSE Y, nhưng trong thực tế có nghĩa là NẾU A (NẾU B THEN X ELSE Y). Nếu bài kiểm tra của A thất bại, thì toàn bộ phần bên trong nếu không sẽ bị bỏ qua.

Như một trong những câu trả lời được đề cập, trong trường hợp này chỉ có một trong các thử nghiệm có thể thành công nên không cần 'cái khác', nhưng tất nhiên chỉ hoạt động trong ví dụ này, nó không phải là một giải pháp chung để thực hiện nếu không.

Có rất nhiều cách xung quanh này. Dưới đây là một vài ý tưởng, tất cả đều khá xấu xí, nhưng này, đây là (hoặc ít nhất là) DOS!

@echo off

set one=1
set two=2

REM Example 1

IF %one%_%two%==1_1 (
   echo Example 1 fails
) ELSE IF %one%_%two%==1_2 (
   echo Example 1 works correctly
) ELSE (
    echo Example 1 fails
)

REM Example 2

set test1result=0
set test2result=0

if %one%==1 if %two%==1 set test1result=1
if %one%==1 if %two%==2 set test2result=1

IF %test1result%==1 (
   echo Example 2 fails
) ELSE IF %test2result%==1 (
   echo Example 2 works correctly
) ELSE (
    echo Example 2 fails
)

REM Example 3

if %one%==1 if %two%==1 (
   echo Example 3 fails
   goto :endoftests
)
if %one%==1 if %two%==2 (
   echo Example 3 works correctly
   goto :endoftests
)
echo Example 3 fails
)
:endoftests

AFAIK bạn không thể thực hiện một if elseđợt như bạn có thể bằng các ngôn ngữ khác, nó phải được lồngif .

Sử dụng iflô của bạn sẽ như thế nào

IF %F%==1 IF %C%==1(
    ::copying the file c to d
    copy "%sourceFile%" "%destinationFile%"
    ) ELSE (
        IF %F%==1 IF %C%==0(
        ::moving the file c to d
        move "%sourceFile%" "%destinationFile%"
        ) ELSE (
            IF %F%==0 IF %C%==1(
            ::copying a directory c from d, /s:  boş olanlar hariç, /e:boş olanlar dahil
            xcopy "%sourceCopyDirectory%" "%destinationCopyDirectory%" /s/e
            ) ELSE (
                IF %F%==0 IF %C%==0(
                ::moving a directory
                xcopy /E "%sourceMoveDirectory%" "%destinationMoveDirectory%"
                rd /s /q "%sourceMoveDirectory%"
                )
            )
        )
    )

hoặc như James đề xuất, xâu chuỗi của bạn if, tuy nhiên tôi nghĩ cú pháp thích hợp là

IF %F%==1 IF %C%==1(
    ::copying the file c to d
    copy "%sourceFile%" "%destinationFile%"
    )

Tôi tin rằng bạn có thể sử dụng một cái gì đó như

if ___ (

do this

) else if ___ (

do this

)

Một chút muộn và có lẽ vẫn tốt cho các điều kiện if phức tạp, bởi vì tôi muốn thêm một tham số "xong" để giữ cấu trúc if-then-other:

set done=0
if %F%==1 if %C%==0 (set done=1 & echo found F=1 and C=0: %F% + %C%)
if %F%==2 if %C%==0 (set done=1 & echo found F=2 and C=0: %F% + %C%)
if %F%==3 if %C%==0 (set done=1 & echo found F=3 and C=0: %F% + %C%)
if %done%==0 (echo do something)

IF...ELSE IF cấu trúc hoạt động rất tốt trong các tệp bó, đặc biệt khi bạn chỉ sử dụng một biểu thức điều kiện trên mỗi dòng IF:

IF %F%==1 (
    ::copying the file c to d
    copy "%sourceFile%1" "%destinationFile1%"
) ELSE IF %F%==0 (
    ::moving the file e to f
    move "%sourceFile2%" "%destinationFile2%" )

Trong ví dụ của bạn, bạn sử dụng IF...AND...IFkiểu xây dựng, trong đó 2 điều kiện phải được đáp ứng đồng thời. Trong trường hợp này, bạn vẫn có thể sử dụng IF...ELSE IFcấu trúc, nhưng có thêm dấu ngoặc đơn để tránh sự không chắc chắn cho điều kiện ELSE tiếp theo:

IF %F%==1 (IF %C%==1 (
    ::copying the file c to d
    copy "%sourceFile1%" "%destinationFile1%" )
) ELSE IF %F%==1 (IF %C%==0 (
    ::moving the file e to f
    move "%sourceFile2%" "%destinationFile2%"))

Cấu trúc trên tương đương với:

IF %F%==1 (
    IF %C%==1 (
    ::copying the file c to d
    copy "%sourceFile1%" "%destinationFile1%"
    ) ELSE IF %C%==0 (
    ::moving the file e to f
    move "%sourceFile2%" "%destinationFile2%"))

Trình tự xử lý các lệnh bó tùy thuộc vào thứ tự phân tích cú pháp CMD.exe . Chỉ cần đảm bảo rằng cấu trúc của bạn tuân theo thứ tự logic đó và theo quy tắc, nó sẽ hoạt động. Nếu tập lệnh bó của bạn được xử lý bởi Cmd.exe mà không có lỗi, điều đó có nghĩa đây là cấu trúc chính xác (nghĩa là được hỗ trợ bởi phiên bản OS Cmd.exe của bạn), ngay cả khi có ai đó nói khác.

Đây là mã của tôi Ví dụ cho if..else..if
mà làm như sau

Nhắc người dùng cho Tên quy trình

Nếu tên tiến trình không hợp lệ
thì nó sẽ ghi cho người dùng

Error : The Processor above doesn't seem to be exist 

nếu tên tiến trình là dịch vụ
thì nó sẽ ghi cho người dùng

Error : You can't kill the Processor above 

nếu tên quy trình hợp lệ và không phải dịch vụ
thì nó sẽ ghi cho người dùng

các quá trình đã bị giết quataskill

vì vậy tôi gọi nó là Process killer.bat
Đây là Mã của tôi:

@echo off

:Start
Rem preparing the batch  
cls
Title Processor Killer
Color 0B
Echo Type Processor name to kill It (Without ".exe")
set /p ProcessorTokill=%=%  

:tasklist
tasklist|find /i "%ProcessorTokill%.exe">nul & if errorlevel 1 (
REM check if the process name is invalid 
Cls 
Title %ProcessorTokill% Not Found
Color 0A
echo %ProcessorTokill%
echo Error : The Processor above doesn't seem to be exist    

) else if %ProcessorTokill%==services (
REM check if the process name is services and doesn't kill it
Cls 
Color 0c
Title Permission denied 
echo "%ProcessorTokill%.exe"
echo Error : You can't kill the Processor above 

) else (
REM if the process name is valid and not services
Cls 
Title %ProcessorTokill% Found
Color 0e
echo %ProcessorTokill% Found
ping localhost -n 2 -w 1000>nul
echo Killing %ProcessorTokill% ...
taskkill /f /im %ProcessorTokill%.exe /t>nul
echo %ProcessorTokill% Killed...
)

pause>nul



REM If else if Template
REM if thing1 (
REM Command here 2 ! 
REM ) else if thing2 (
REM command here 2 !
REM ) else (
REM command here 3 !
REM )

đây là cách tôi xử lý nếu khác

if %env%==dev ( 
    echo "dev env selected selected"
) else (
    if %env%==prod (
        echo "prod env selected"
    )
)

Lưu ý rằng nó không giống như khối if-otherif như các ngôn ngữ lập trình khác như C ++ hoặc Java nhưng nó sẽ làm những gì bạn cần làm