Theo tôi, SET XACT_ABORT ON đã bị lỗi thời khi bổ sung BEGIN TRY / BEGIN CATCH trong SQL 2k5. Trước các khối ngoại lệ trong Transact-SQL, thực sự rất khó để xử lý lỗi và các quy trình không cân bằng đều quá phổ biến (các quy trình có @@ TRANCOUNT khác khi thoát so với mục nhập).
Với việc bổ sung xử lý ngoại lệ Transact-SQL sẽ dễ dàng hơn nhiều để viết các quy trình chính xác được đảm bảo để cân bằng chính xác các giao dịch. Chẳng hạn, tôi sử dụng mẫu này để xử lý ngoại lệ và giao dịch lồng nhau :
create procedure [usp_my_procedure_name]
as
begin
set nocount on;
declare @trancount int;
set @trancount = @@trancount;
begin try
if @trancount = 0
begin transaction
else
save transaction usp_my_procedure_name;
-- Do the actual work here
lbexit:
if @trancount = 0
commit;
end try
begin catch
declare @error int, @message varchar(4000), @xstate int;
select @error = ERROR_NUMBER(), @message = ERROR_MESSAGE(), @xstate = XACT_STATE();
if @xstate = -1
rollback;
if @xstate = 1 and @trancount = 0
rollback
if @xstate = 1 and @trancount > 0
rollback transaction usp_my_procedure_name;
raiserror ('usp_my_procedure_name: %d: %s', 16, 1, @error, @message) ;
end catch
end
go
Nó cho phép tôi viết các thủ tục nguyên tử chỉ quay lại công việc của chính họ trong trường hợp có lỗi có thể phục hồi.
Một trong những vấn đề chính mà các thủ tục Transact-SQL phải đối mặt là độ tinh khiết của dữ liệu : đôi khi các tham số nhận được hoặc dữ liệu trong các bảng chỉ đơn giản là sai, dẫn đến lỗi khóa trùng lặp, lỗi ràng buộc tham chiếu, kiểm tra lỗi ràng buộc, v.v. Xét cho cùng, đó chính xác là vai trò của các ràng buộc này, nếu các lỗi về độ tinh khiết dữ liệu này là không thể và tất cả bị logic kinh doanh nắm bắt, các ràng buộc đó sẽ bị lỗi thời (cường điệu hóa thêm vào có hiệu lực). Nếu XACT_ABORT BẬT thì tất cả các lỗi này dẫn đến toàn bộ giao dịch bị mất, trái ngược với việc có thể mã hóa các khối ngoại lệ xử lý ngoại lệ một cách duyên dáng. Một ví dụ điển hình là cố gắng thực hiện một CHERTN và trở lại CẬP NHẬT về vi phạm PK.