Cách tạo và ghi vào tệp txt bằng VBA

Tôi có một tệp được thêm vào hoặc sửa đổi theo cách thủ công dựa trên các đầu vào. Vì hầu hết các nội dung đều lặp lại trong tệp đó, chỉ có các giá trị hex là thay đổi, tôi muốn đặt nó thành tệp do công cụ tạo.

Tôi muốn viết các mã c sẽ được in trong tệp .txt đó .

Lệnh tạo tệp .txt bằng VBA là gì và làm cách nào để ghi vào tệp đó

Để giải thích rõ hơn về câu trả lời của Ben :

Nếu bạn thêm một tham chiếu đến Microsoft Scripting Runtimevà nhập chính xác biến fso, bạn có thể tận dụng lợi thế của tính năng tự động hoàn thành (Intellisense) và khám phá các tính năng tuyệt vời khác của FileSystemObject.

Đây là một mô-đun ví dụ hoàn chỉnh:

Option Explicit

' Go to Tools -> References... and check "Microsoft Scripting Runtime" to be able to use
' the FileSystemObject which has many useful features for handling files and folders
Public Sub SaveTextToFile()

    Dim filePath As String
    filePath = "C:\temp\MyTestFile.txt"

    ' The advantage of correctly typing fso as FileSystemObject is to make autocompletion
    ' (Intellisense) work, which helps you avoid typos and lets you discover other useful
    ' methods of the FileSystemObject
    Dim fso As FileSystemObject
    Set fso = New FileSystemObject
    Dim fileStream As TextStream

    ' Here the actual file is created and opened for write access
    Set fileStream = fso.CreateTextFile(filePath)

    ' Write something to the file
    fileStream.WriteLine "something"

    ' Close it, so it is not locked anymore
    fileStream.Close

    ' Here is another great method of the FileSystemObject that checks if a file exists
    If fso.FileExists(filePath) Then
        MsgBox "Yay! The file was created! :D"
    End If

    ' Explicitly setting objects to Nothing should not be necessary in most cases, but if
    ' you're writing macros for Microsoft Access, you may want to uncomment the following
    ' two lines (see https://stackoverflow.com/a/517202/2822719 for details):
    'Set fileStream = Nothing
    'Set fso = Nothing

End Sub

Sử dụng FSO để tạo tệp và ghi vào tệp đó.

Dim fso as Object
Set fso = CreateObject("Scripting.FileSystemObject")
Dim oFile as Object
Set oFile = FSO.CreateTextFile(strPath)
oFile.WriteLine "test" 
oFile.Close
Set fso = Nothing
Set oFile = Nothing    

Xem tài liệu tại đây:

• http://technet.microsoft.com/en-us/library/ee198742.aspx
• http://technet.microsoft.com/en-us/library/ee198716.aspx

Open ThisWorkbook.Path & "\template.txt" For Output As #1
Print #1, strContent
Close #1

Thêm thông tin:

• Microsoft Docs: Opentuyên bố
• Microsoft Docs: Print #tuyên bố
• Microsoft Docs: Closetuyên bố
• wellr.com: VBA ghi vào tệp văn bản với PrintStatement
• Hỗ trợ văn phòng: Workbook.Pathtài sản

một cách dễ dàng mà không có nhiều dư thừa.

    Dim fso As Object
    Set fso = CreateObject("Scripting.FileSystemObject")

    Dim Fileout As Object
    Set Fileout = fso.CreateTextFile("C:\your_path\vba.txt", True, True)
    Fileout.Write "your string goes here"
    Fileout.Close

Dim SaveVar As Object

Sub Main()

    Console.WriteLine("Enter Text")

    Console.WriteLine("")

    SaveVar = Console.ReadLine

    My.Computer.FileSystem.WriteAllText("N:\A-Level Computing\2017!\PPE\SaveFile\SaveData.txt", "Text: " & SaveVar & ", ", True)

    Console.WriteLine("")

    Console.WriteLine("File Saved")

    Console.WriteLine("")

    Console.WriteLine(My.Computer.FileSystem.ReadAllText("N:\A-Level Computing\2017!\PPE\SaveFile\SaveData.txt"))
    Console.ReadLine()

End Sub()