Kiểm tra xem tệp có tồn tại bằng VBA không

Sub test()

thesentence = InputBox("Type the filename with full extension", "Raw Data File")

Range("A1").Value = thesentence

If Dir("thesentence") <> "" Then
    MsgBox "File exists."
Else
    MsgBox "File doesn't exist."
End If

End Sub

Trong điều này, khi tôi lấy giá trị văn bản từ hộp nhập, nó không hoạt động. Tuy nhiên, nếu xóa "the sentence"khỏi If Dir()và thay thế nó bằng tên thực trong mã, nó sẽ hoạt động. Ai đó có thể giúp đỡ?

Lưu ý rằng mã của bạn Dir("thesentence")phải có Dir(thesentence).

Thay đổi mã của bạn thành cái này

Sub test()

thesentence = InputBox("Type the filename with full extension", "Raw Data File")

Range("A1").Value = thesentence

If Dir(thesentence) <> "" Then
    MsgBox "File exists."
Else
    MsgBox "File doesn't exist."
End If

End Sub

Sử dụng FileDialogđối tượng Office để yêu cầu người dùng chọn tệp từ hệ thống tệp. Thêm một tham chiếu trong dự án VB của bạn hoặc trong trình soạn thảo VBA Microsoft Office Libraryvà xem trợ giúp. Điều này tốt hơn nhiều so với việc mọi người đi vào các con đường đầy đủ.

Đây là một ví dụ sử dụng msoFileDialogFilePickerđể cho phép người dùng chọn nhiều tệp. Bạn cũng có thể sử dụng msoFileDialogOpen.

'Note: this is Excel VBA code
Public Sub LogReader()
    Dim Pos As Long
    Dim Dialog As Office.FileDialog
    Set Dialog = Application.FileDialog(msoFileDialogFilePicker)

    With Dialog
        .AllowMultiSelect = True
        .ButtonName = "C&onvert"
        .Filters.Clear
        .Filters.Add "Log Files", "*.log", 1
        .Title = "Convert Logs to Excel Files"
        .InitialFileName = "C:\InitialPath\"
        .InitialView = msoFileDialogViewList

        If .Show Then
            For Pos = 1 To .SelectedItems.Count
                LogRead .SelectedItems.Item(Pos) ' process each file
            Next
        End If
    End With
End Sub

Có rất nhiều tùy chọn, vì vậy bạn sẽ cần xem toàn bộ tệp trợ giúp để hiểu tất cả những gì có thể. Bạn có thể bắt đầu với đối tượng FileDialog của Office 2007 (tất nhiên, bạn sẽ cần tìm trợ giúp chính xác cho phiên bản bạn đang sử dụng).

Sửa thành tệpExists từ @UberNubIsTrue:

Function fileExists(s_directory As String, s_fileName As String) As Boolean

  Dim obj_fso As Object, obj_dir As Object, obj_file As Object
  Dim ret As Boolean
   Set obj_fso = CreateObject("Scripting.FileSystemObject")
   Set obj_dir = obj_fso.GetFolder(s_directory)
   ret = False
   For Each obj_file In obj_dir.Files
     If obj_fso.fileExists(s_directory & "\" & s_fileName) = True Then
        ret = True
        Exit For
      End If
   Next

   Set obj_fso = Nothing
   Set obj_dir = Nothing
   fileExists = ret

 End Function

EDIT: phiên bản rút gọn

' Check if a file exists
Function fileExists(s_directory As String, s_fileName As String) As Boolean

    Dim obj_fso As Object

    Set obj_fso = CreateObject("Scripting.FileSystemObject")
    fileExists = obj_fso.fileExists(s_directory & "\" & s_fileName)

End Function

chỉ cần loại bỏ những dấu hiệu bài phát biểu

Sub test()

Dim thesentence As String

thesentence = InputBox("Type the filename with full extension", "Raw Data File")

Range("A1").Value = thesentence

If Dir(thesentence) <> "" Then
    MsgBox "File exists."
Else
    MsgBox "File doesn't exist."
End If

End Sub

Đây là một trong những tôi thích:

Option Explicit

Enum IsFileOpenStatus
    ExistsAndClosedOrReadOnly = 0
    ExistsAndOpenSoBlocked = 1
    NotExists = 2
End Enum


Function IsFileReadOnlyOpen(FileName As String) As IsFileOpenStatus

With New FileSystemObject
    If Not .FileExists(FileName) Then
        IsFileReadOnlyOpen = 2  '  NotExists = 2
        Exit Function 'Or not - I don't know if you want to create the file or exit in that case.
    End If
End With

Dim iFilenum As Long
Dim iErr As Long
On Error Resume Next
    iFilenum = FreeFile()
    Open FileName For Input Lock Read As #iFilenum
    Close iFilenum
    iErr = Err
On Error GoTo 0

Select Case iErr
    Case 0: IsFileReadOnlyOpen = 0 'ExistsAndClosedOrReadOnly = 0
    Case 70: IsFileReadOnlyOpen = 1 'ExistsAndOpenSoBlocked = 1
    Case Else: IsFileReadOnlyOpen = 1 'Error iErr
End Select

End Function    'IsFileReadOnlyOpen

Function FileExists(fullFileName As String) As Boolean
    FileExists = VBA.Len(VBA.Dir(fullFileName)) > 0
End Function

Hoạt động rất tốt, gần như, tại trang web của tôi. Nếu tôi gọi nó bằng "" chuỗi trống, Dir trả về " connection.odc " !! Sẽ rất tuyệt nếu các bạn có thể chia sẻ kết quả của mình.

Dù sao, tôi làm như thế này:

Function FileExists(fullFileName As String) As Boolean
  If fullFileName = "" Then
    FileExists = False
  Else
    FileExists = VBA.Len(VBA.Dir(fullFileName)) > 0
  End If
End Function

Function FileExists(fullFileName As String) As Boolean
    FileExists = VBA.Len(VBA.Dir(fullFileName)) > 0
End Function

Tôi không chắc chắn cụ thể mã của bạn có gì sai, nhưng tôi sử dụng chức năng này mà tôi tìm thấy trực tuyến (URL trong nhận xét) để kiểm tra xem tệp có tồn tại hay không:

Private Function File_Exists(ByVal sPathName As String, Optional Directory As Boolean) As Boolean
    'Code from internet: http://vbadud.blogspot.com/2007/04/vba-function-to-check-file-existence.html
    'Returns True if the passed sPathName exist
    'Otherwise returns False
    On Error Resume Next
    If sPathName <> "" Then

        If IsMissing(Directory) Or Directory = False Then

            File_Exists = (Dir$(sPathName) <> "")
        Else

            File_Exists = (Dir$(sPathName, vbDirectory) <> "")
        End If

    End If
End Function

Bài đăng rất cũ, nhưng vì nó đã giúp tôi sau khi tôi thực hiện một số sửa đổi, tôi nghĩ tôi sẽ chia sẻ. Nếu bạn đang kiểm tra xem thư mục có tồn tại hay không, bạn sẽ muốn thêm đối số vbDirectory vào hàm Dir, nếu không bạn sẽ quay lại 0mỗi lần. (Chỉnh sửa: đây là câu trả lời của Roy, nhưng tôi đã vô tình biến nó thành câu trả lời thông thường.)

Private Function FileExists(fullFileName As String) As Boolean
    FileExists = Len(Dir(fullFileName, vbDirectory)) > 0
End Function

dựa trên các câu trả lời khác ở đây, tôi muốn chia sẻ một lớp lót của mình sẽ hoạt động cho dirs và tệp :

• Len(Dir(path)) > 0 or Or Len(Dir(path, vbDirectory)) > 0  'version 1 - ... <> "" should be more inefficient generally
  

  • (chỉ Len(Dir(path))không hoạt động cho các thư mục (Excel 2010 / Win7))

• CreateObject("Scripting.FileSystemObject").FileExists(path)  'version 2 - could be faster sometimes, but only works for files (tested on Excel 2010/Win7)
  

như PathExists(path)chức năng:

Public Function PathExists(path As String) As Boolean
    PathExists = Len(Dir(path)) > 0 Or Len(Dir(path, vbDirectory)) > 0
End Function