(Các) lệnh hàng loạt của Windows để đọc dòng đầu tiên từ tệp văn bản

Làm cách nào để tôi có thể đọc dòng đầu tiên từ tệp văn bản bằng tệp loạt Windows? Vì tệp lớn nên tôi chỉ muốn xử lý dòng đầu tiên.

Đây là một tệp hàng loạt có mục đích chung để in các ndòng trên cùng từ một tệp như headtiện ích GNU , thay vì chỉ một dòng.

@echo off

if [%1] == [] goto usage
if [%2] == [] goto usage

call :print_head %1 %2
goto :eof

REM
REM print_head
REM Prints the first non-blank %1 lines in the file %2.
REM
:print_head
setlocal EnableDelayedExpansion
set /a counter=0

for /f ^"usebackq^ eol^=^

^ delims^=^" %%a in (%2) do (
        if "!counter!"=="%1" goto :eof
        echo %%a
        set /a counter+=1
)

goto :eof

:usage
echo Usage: head.bat COUNT FILENAME

Ví dụ:

Z:\>head 1 "test file.c"
; this is line 1

Z:\>head 3 "test file.c"
; this is line 1
    this is line 2
line 3 right here

Nó hiện không đếm dòng trống. Nó cũng phải tuân theo giới hạn độ dài dòng của tệp loạt là 8 KB.

uh? imo cái này đơn giản hơn nhiều

  set /p texte=< file.txt  
  echo %texte%

Uh các bạn ...

C:\>findstr /n . c:\boot.ini | findstr ^1:

1:[boot loader]

C:\>findstr /n . c:\boot.ini | findstr ^3:

3:default=multi(0)disk(0)rdisk(0)partition(1)\WINNT

C:\>

Bạn có thể thử cái này:

@echo off

for /f %%a in (sample.txt) do (
  echo %%a
  exit /b
)

chỉnh sửa Hoặc, giả sử bạn có bốn cột dữ liệu và muốn từ hàng thứ 5 trở xuống dưới cùng, hãy thử điều này:

@echo off

for /f "skip=4 tokens=1-4" %%a in (junkl.txt) do (
  echo %%a %%b %%c %%d
)

Nhờ thetalkingwalnut với (các) lệnh hàng loạt của Windows để đọc dòng đầu tiên từ tệp văn bản, tôi đã đưa ra giải pháp sau:

@echo off
for /f "delims=" %%a in ('type sample.txt') do (
echo %%a
exit /b
)

Dựa trên câu trả lời của người khác. Giờ đây, cho phép bạn chỉ định tệp bạn muốn đọc và biến bạn muốn đưa kết quả vào:

@echo off
for /f "delims=" %%x in (%2) do (
set %1=%%x
exit /b
)

Điều này có nghĩa là bạn có thể sử dụng ở trên như thế này (giả sử bạn đã gọi nó là getline.bat)

c:\> dir > test-file
c:\> getline variable test-file
c:\> set variable  
variable= Volume in drive C has no label.

Một lớp lót, hữu ích cho chuyển hướng stdout với ">":

@for /f %%i in ('type yourfile.txt') do @echo %%i & exit

Thử đi

@echo off
setlocal enableextensions enabledelayedexpansion
set firstLine=1
for /f "delims=" %%i in (yourfilename.txt) do (
    if !firstLine!==1 echo %%i
    set firstLine=0
)
endlocal

Vấn đề với các EXIT /Bgiải pháp, khi thực tế hơn bên trong một tệp loạt chỉ là một phần của nó như sau. Không có quá trình xử lý tiếp theo nào trong tệp lô đã nói sau EXIT /B. Thông thường, có nhiều thứ phải làm theo lô hơn là chỉ một nhiệm vụ giới hạn.

Để giải quyết vấn đề đó:

@echo off & setlocal enableextensions enabledelayedexpansion
set myfile_=C:\_D\TEST\My test file.txt
set FirstLine=
for /f "delims=" %%i in ('type "%myfile_%"') do (
  if not defined FirstLine set FirstLine=%%i)
echo FirstLine=%FirstLine%
endlocal & goto :EOF

(Tuy nhiên, những nhân vật được gọi là độc dược vẫn sẽ là một vấn đề.)

Tìm hiểu thêm về chủ đề nhận một dòng cụ thể với các lệnh hàng loạt:

Làm cách nào để lấy dòng thứ n, dòng đầu tiên và dòng cuối cùng của tệp văn bản? " Http://www.netikka.net/tsneti/info/tscmd023.htm

[Đã thêm ngày 28 tháng 8 năm 2012] Người ta cũng có thể có:

@echo off & setlocal enableextensions
set myfile_=C:\_D\TEST\My test file.txt
for /f "tokens=* delims=" %%a in (
  'type "%myfile_%"') do (
    set FirstLine=%%a& goto _ExitForLoop)
:_ExitForLoop
echo FirstLine=%FirstLine%
endlocal & goto :EOF

Để cicle một tập tin ( file1.txt, file1[1].txt, file1[2].txt, vv):

START/WAIT C:\LAERCIO\DELPHI\CICLADOR\dprCiclador.exe C:\LAERCIUM\Ciclavel.txt

rem set/p ciclo=< C:\LAERCIUM\Ciclavel.txt:
set/p ciclo=< C:\LAERCIUM\Ciclavel.txt

rem echo %ciclo%:
echo %ciclo%

Và nó đang chạy.

Lưu ý, các phương pháp tiếp cận tệp hàng loạt sẽ bị giới hạn ở giới hạn dòng cho bộ xử lý lệnh DOS - hãy xem Giới hạn độ dài dòng lệnh là gì? .

Vì vậy, nếu cố gắng xử lý một tệp có bất kỳ dòng nào nhiều hơn 8192 ký tự, tập lệnh sẽ chỉ bỏ qua chúng vì giá trị không thể được giữ.

Cách khác

setlocal enabledelayedexpansion
@echo off
for /f "delims=" %%i in (filename.txt) do (
if 1==1 (
set first_line=%%i
echo !first_line!
goto :eof
))

Đây là một cách giải quyết bằng cách sử dụng powershell:

powershell (Get-Content file.txt)[0]

(Bạn cũng có thể dễ dàng đọc một loạt các dòng với powershell (Get-Content file.txt)[0..3])

Nếu bạn cần đặt một biến bên trong tập lệnh lô làm dòng đầu tiên file.txtbạn có thể sử dụng:

for /f "usebackq delims=" %%a in (`powershell ^(Get-Content file.txt^)[0]`) do (set "head=%%a")

for /f "delims=" %a in (downing.txt) do echo %a & pause>nul

In dòng đầu tiên, sau đó đợi người dùng nhấn phím để in dòng tiếp theo. Sau khi in các dòng cần thiết, nhấn Ctrl + C để dừng.

@Ross Presser: Phương pháp này chỉ in các dòng, không thêm số dòng trước.