Cấu trúc vòng lặp bên trong gnuplot?

Có cách nào để truy xuất lặp lại dữ liệu từ nhiều tệp và vẽ chúng trên cùng một biểu đồ trong gnuplot. Giả sử tôi có các tệp như data1.txt, data2.txt ...... data1000.txt; mỗi cột có cùng số cột. Bây giờ tôi có thể viết một cái gì đó như-

plot "data1.txt" using 1:2 title "Flow 1", \
     "data2.txt" using 1:2 title "Flow 2", \
      .
      .
      .
     "data1000.txt"  using 1:2 title "Flow 6"

Nhưng điều này sẽ thực sự bất tiện. Tôi đã tự hỏi liệu có cách nào để lặp lại phần cốt truyện trong gnuplot không.

Chắc chắn là có (trong gnuplot 4.4+):

plot for [i=1:1000] 'data'.i.'.txt' using 1:2 title 'Flow '.i

Biến icó thể được hiểu là một biến hoặc một chuỗi, vì vậy bạn có thể làm điều gì đó như

plot for [i=1:1000] 'data'.i.'.txt' using 1:($2+i) title 'Flow '.i

nếu bạn muốn có các dòng lệch nhau.

Gõ help iterationvào dòng lệnh gnuplot để biết thêm thông tin.

Cũng nhớ xem câu trả lời của @ DarioP về do forcú pháp; cung cấp cho bạn một cái gì đó gần hơn với forvòng lặp truyền thống .

Cũng hãy xem do { ... }lệnh kể từ gnuplot 4.6 vì nó rất mạnh:

do for [t=0:50] {
  outfile = sprintf('animation/bessel%03.0f.png',t)
  set output outfile
  splot u*sin(v),u*cos(v),bessel(u,t/50.0) w pm3d ls 1
}

http://www.gnuplotting.org/gnuplot-4-6-do/

Tôi có kịch bản tất cả. P

set ...
...
list=system('ls -1B *.dat')
plot for [file in list] file w l u 1:2 t file

Ở đây hai hàng cuối cùng là nghĩa đen, không phải heuristic. Sau đó tôi chạy

$ gnuplot -p all.p

Thay đổi *.datloại tệp bạn có hoặc thêm các loại tệp.

Bước tiếp theo: Thêm vào ~ / .bashrc dòng này

alias p='gnuplot -p ~/./all.p'

và đặt tệp của bạn vào thư mục chính all.pcủa bạn và thì đấy. Bạn có thể vẽ tất cả các tệp trong bất kỳ thư mục nào bằng cách gõ p và enter.

CHỈNH SỬA Tôi đã thay đổi lệnh vì nó không hoạt động. Trước đây nó chứa list(i)=word(system(ls -1B *.dat),i).

Sử dụng phần sau nếu bạn có các cột rời rạc để vẽ biểu đồ

do for [indx in "2 3 7 8"] {
  column = indx + 0
  plot ifile using 1:column ;  
}

Tôi muốn sử dụng các ký tự đại diện để vẽ nhiều tệp thường được đặt trong các thư mục khác nhau, trong khi làm việc từ bất kỳ thư mục nào. Giải pháp tôi tìm thấy là tạo hàm sau trong~/.bashrc

plo () {
local arg="w l"
local str="set term wxt size 900,500 title 'wild plotting'
set format y '%g'
set logs
plot"
while [ $# -gt 0 ]
        do str="$str '$1' $arg,"
        shift
done
echo "$str" | gnuplot -persist
}

và sử dụng nó, ví dụ như plo *.dat ../../dir2/*.out, để vẽ tất cả .datcác tệp trong thư mục hiện tại và tất cả .outcác tệp trong một thư mục tình cờ được nâng cấp và được gọi dir2.

Đây là lệnh thay thế:

gnuplot -p -e 'plot for [file in system("find . -name \\*.txt -depth 1")] file using 1:2 title file with lines'