Groovy thực thi các lệnh shell

Groovy thêm executephương thức để Stringthực hiện shell thực hiện khá dễ dàng;

println "ls".execute().text

nhưng nếu xảy ra lỗi, thì không có kết quả đầu ra. Có cách nào dễ dàng để loại bỏ cả lỗi tiêu chuẩn và tiêu chuẩn không? (ngoài việc tạo ra một loạt mã để; tạo hai luồng để đọc cả hai luồng đầu vào, sau đó sử dụng luồng cha để chờ chúng hoàn thành sau đó chuyển đổi chuỗi trở lại văn bản?)

Nó sẽ là tốt đẹp để có một cái gì đó như;

 def x = shellDo("ls /tmp/NoFile")
 println "out: ${x.out} err:${x.err}"

Ok, tự mình giải quyết nó;

def sout = new StringBuilder(), serr = new StringBuilder()
def proc = 'ls /badDir'.execute()
proc.consumeProcessOutput(sout, serr)
proc.waitForOrKill(1000)
println "out> $sout err> $serr"

hiển thị:

out> err> ls: cannot access /badDir: No such file or directory

"ls".execute()trả về một Processđối tượng đó là lý do tại sao "ls".execute().texthoạt động. Bạn có thể chỉ cần đọc luồng lỗi để xác định xem có lỗi nào không.

Có một phương thức bổ sung Processcho phép bạn vượt qua a StringBufferđể lấy văn bản : consumeProcessErrorStream(StringBuffer error).

Thí dụ:

def proc = "ls".execute()
def b = new StringBuffer()
proc.consumeProcessErrorStream(b)

println proc.text
println b.toString()

// a wrapper closure around executing a string                                  
// can take either a string or a list of strings (for arguments with spaces)    
// prints all output, complains and halts on error                              
def runCommand = { strList ->
  assert ( strList instanceof String ||
           ( strList instanceof List && strList.each{ it instanceof String } ) \
)
  def proc = strList.execute()
  proc.in.eachLine { line -> println line }
  proc.out.close()
  proc.waitFor()

  print "[INFO] ( "
  if(strList instanceof List) {
    strList.each { print "${it} " }
  } else {
    print strList
  }
  println " )"

  if (proc.exitValue()) {
    println "gave the following error: "
    println "[ERROR] ${proc.getErrorStream()}"
  }
  assert !proc.exitValue()
}

Tôi thấy điều này thành ngữ hơn:

def proc = "ls foo.txt doesnotexist.txt".execute()
assert proc.in.text == "foo.txt\n"
assert proc.err.text == "ls: doesnotexist.txt: No such file or directory\n"

Như một bài đăng khác đề cập, đây là những cuộc gọi chặn, nhưng vì chúng tôi muốn làm việc với đầu ra, điều này có thể cần thiết.

Để thêm một thông tin quan trọng vào câu trả lời được cung cấp ở trên -

Cho một quá trình

def proc = command.execute();

luôn cố gắng sử dụng

def outputStream = new StringBuffer();
proc.waitForProcessOutput(outputStream, System.err)
//proc.waitForProcessOutput(System.out, System.err)

thay vì

def output = proc.in.text;

để nắm bắt các kết quả đầu ra sau khi thực hiện các lệnh trong Groovy vì sau này là một cuộc gọi chặn ( câu hỏi SO vì lý do ).

def exec = { encoding, execPath, execStr, execCommands ->

def outputCatcher = new ByteArrayOutputStream()
def errorCatcher = new ByteArrayOutputStream()

def proc = execStr.execute(null, new File(execPath))
def inputCatcher = proc.outputStream

execCommands.each { cm ->
    inputCatcher.write(cm.getBytes(encoding))
    inputCatcher.flush()
}

proc.consumeProcessOutput(outputCatcher, errorCatcher)
proc.waitFor()

return [new String(outputCatcher.toByteArray(), encoding), new String(errorCatcher.toByteArray(), encoding)]

}

def out = exec("cp866", "C:\\Test", "cmd", ["cd..\n", "dir\n", "exit\n"])

println "OUT:\n" + out[0]
println "ERR:\n" + out[1]

command = "ls *"

def execute_state=sh(returnStdout: true, script: command)

nhưng nếu lệnh thất bại, quá trình sẽ chấm dứt