Giải quyết đường dẫn tuyệt đối từ đường dẫn tương đối và / hoặc tên tệp

Có cách nào trong tập lệnh bó Windows để trả về một đường dẫn tuyệt đối từ một giá trị chứa tên tệp và / hoặc đường dẫn tương đối không?

Được:

"..\"
"..\somefile.txt"

Tôi cần đường dẫn tuyệt đối liên quan đến tệp bó.

Thí dụ:

• "somefile.txt" nằm trong "C: \ Foo \"
• "test.bat" nằm trong "C: \ Foo \ Bar".
• Người dùng mở một cửa sổ lệnh trong "C: \ Foo" và gọi Bar\test.bat ..\somefile.txt
• Trong tệp bó "C: \ Foo \ somefile.txt" sẽ được lấy từ %1

Trong các tệp bó, như trong các chương trình C tiêu chuẩn, đối số 0 chứa đường dẫn đến tập lệnh hiện đang thực thi. Bạn có thể sử dụng %~dp0để chỉ lấy phần đường dẫn của đối số 0 (là tập lệnh hiện tại) - đường dẫn này luôn là đường dẫn đủ điều kiện.

Bạn cũng có thể có được đường dẫn đủ điều kiện của đối số đầu tiên của mình bằng cách sử dụng %~f1, nhưng điều này đưa ra một đường dẫn theo thư mục làm việc hiện tại, đây rõ ràng không phải là điều bạn muốn.

Cá nhân, tôi thường sử dụng %~dp0%~1thành ngữ trong tệp bó của mình, nó diễn giải đối số đầu tiên liên quan đến đường dẫn của lô thực thi. Mặc dù vậy, nó có một thiếu sót: nó thất bại thảm hại nếu đối số đầu tiên đủ điều kiện.

Nếu bạn cần hỗ trợ cả hai đường dẫn tương đối và tuyệt đối, bạn có thể sử dụng giải pháp của Frédéric Ménez : tạm thời thay đổi thư mục làm việc hiện tại.

Đây là một ví dụ sẽ chứng minh từng kỹ thuật sau:

@echo off
echo %%~dp0 is "%~dp0"
echo %%0 is "%0"
echo %%~dpnx0 is "%~dpnx0"
echo %%~f1 is "%~f1"
echo %%~dp0%%~1 is "%~dp0%~1"

rem Temporarily change the current working directory, to retrieve a full path 
rem   to the first parameter
pushd .
cd %~dp0
echo batch-relative %%~f1 is "%~f1"
popd

Nếu bạn lưu cái này dưới dạng c: \ temp \ example.bat và chạy nó từ c: \ Users \ Public dưới dạng

c: \ Users \ Public> \ temp \ example.bat .. \ windows

... bạn sẽ quan sát đầu ra sau:

%~dp0 is "C:\temp\"
%0 is "\temp\example.bat"
%~dpnx0 is "C:\temp\example.bat"
%~f1 is "C:\Users\windows"
%~dp0%~1 is "C:\temp\..\windows"
batch-relative %~f1 is "C:\Windows"

tài liệu cho bộ sửa đổi được phép trên một đối số bó có thể được tìm thấy ở đây: https://docs.microsoft.com/en-us/windows-server/adftime/windows-commands/call

Tôi đã gặp một nhu cầu tương tự sáng nay: làm thế nào để chuyển đổi một đường dẫn tương đối thành một đường dẫn tuyệt đối bên trong một tập lệnh của Windows.

Sau đây đã thực hiện các mẹo:

@echo off

set REL_PATH=..\..\
set ABS_PATH=

rem // Save current directory and change to target directory
pushd %REL_PATH%

rem // Save value of CD variable (current directory)
set ABS_PATH=%CD%

rem // Restore original directory
popd

echo Relative path: %REL_PATH%
echo Maps to path: %ABS_PATH%

Hầu hết các câu trả lời này có vẻ điên rồ vì lỗi phức tạp và siêu lỗi, đây là của tôi - nó hoạt động trên bất kỳ biến môi trường nào, không %CD%hoặc PUSHD/ POPDhoặc for /fvô nghĩa - chỉ là các hàm lô cũ đơn giản. - Thư mục & tập tin thậm chí không tồn tại.

CALL :NORMALIZEPATH "..\..\..\foo\bar.txt"
SET BLAH=%RETVAL%

ECHO "%BLAH%"

:: ========== FUNCTIONS ==========
EXIT /B

:NORMALIZEPATH
  SET RETVAL=%~dpfn1
  EXIT /B

Không cần phải có một tệp bó khác để truyền đối số cho (và sử dụng các toán tử đối số), bạn có thể sử dụng FOR /F:

FOR /F %%i IN ("..\relativePath") DO echo absolute path: %%~fi

trong đó iin %%~filà biến được định nghĩa tại /F %%i. ví dụ. nếu bạn thay đổi nó thành /F %%aphần cuối cùng sẽ là %%~fa.

Để làm điều tương tự ngay tại dấu nhắc lệnh (chứ không phải trong tệp bó) thay thế %%bằng %...

Điều này là để giúp lấp đầy những khoảng trống trong câu trả lời của Adrien Plisson (cần được nâng cấp ngay khi anh ta chỉnh sửa nó ;-):

bạn cũng có thể nhận được đường dẫn đủ điều kiện của đối số đầu tiên của mình bằng cách sử dụng% ~ f1, nhưng điều này đưa ra một đường dẫn theo đường dẫn hiện tại, đây rõ ràng không phải là điều bạn muốn.

Thật không may, tôi không biết cách kết hợp cả hai lại với nhau ...

Người ta có thể xử lý %0và %1tương tự:

• %~dpnx0đối với ổ đĩa đủ điều kiện + đường dẫn + tên + phần mở rộng của chính tệp,
  %~f0cũng đủ;
• %~dpnx1đối với ổ đĩa đủ điều kiện + đường dẫn + tên + phần mở rộng của đối số đầu tiên [nếu đó hoàn toàn là tên tệp],
  %~f1cũng đủ;

%~f1sẽ hoạt động độc lập với cách bạn đã chỉ định đối số đầu tiên của mình: với các đường dẫn tương đối hoặc với các đường dẫn tuyệt đối (nếu bạn không chỉ định phần mở rộng của tệp khi đặt tên %1, thì nó sẽ không được thêm vào, ngay cả khi bạn sử dụng %~dpnx1- tuy nhiên.

Nhưng làm thế nào trên trái đất bạn sẽ đặt tên một tệp trên một ổ đĩa khác nếu bạn không cung cấp thông tin đường dẫn đầy đủ đó trên dòng lệnh ở vị trí đầu tiên?

Tuy nhiên, %~p0, %~n0, %~nx0và %~x0có thể có ích, bạn nên quan tâm đến con đường (không có tên ổ đĩa), tên tập tin (không có phần mở rộng), tên tập tin đầy đủ với phần mở rộng hoặc chỉ phần mở rộng tên tập tin của. Nhưng lưu ý, trong khi %~p1và %~n1sẽ làm việc để tìm ra đường dẫn hoặc tên của đối số đầu tiên %~nx1và %~x1sẽ không thêm + hiển thị phần mở rộng, trừ khi bạn đã sử dụng nó trên dòng lệnh.

Bạn cũng có thể sử dụng các hàm bó cho việc này:

@echo off
setlocal 

goto MAIN
::-----------------------------------------------
:: "%~f2" get abs path of %~2. 
::"%~fs2" get abs path with short names of %~2.
:setAbsPath
  setlocal
  set __absPath=%~f2
  endlocal && set %1=%__absPath%
  goto :eof
::-----------------------------------------------

:MAIN
call :setAbsPath ABS_PATH ..\
echo %ABS_PATH%

endlocal

Cải thiện nhỏ cho giải pháp tuyệt vời của BrainSlugs83 . Tổng quát hóa để cho phép đặt tên biến môi trường đầu ra trong cuộc gọi.

@echo off
setlocal EnableDelayedExpansion

rem Example input value.
set RelativePath=doc\build

rem Resolve path.
call :ResolvePath AbsolutePath %RelativePath%

rem Output result.
echo %AbsolutePath%

rem End.
exit /b

rem === Functions ===

rem Resolve path to absolute.
rem Param 1: Name of output variable.
rem Param 2: Path to resolve.
rem Return: Resolved absolute path.
:ResolvePath
    set %1=%~dpfn2
    exit /b

Nếu chạy từ C:\projectđầu ra là:

C:\project\doc\build

Tôi chưa thấy nhiều giải pháp cho vấn đề này. Một số giải pháp sử dụng truyền tải thư mục bằng CD và các giải pháp khác sử dụng các hàm bó. Sở thích cá nhân của tôi là dành cho các hàm hàng loạt và đặc biệt là hàm MakeAbsolute được cung cấp bởi DosTips.

Hàm này có một số lợi ích thực sự, chủ yếu là nó không thay đổi thư mục làm việc hiện tại của bạn và thứ hai là các đường dẫn được đánh giá thậm chí không phải tồn tại. Bạn cũng có thể tìm thấy một số lời khuyên hữu ích về cách sử dụng chức năng ở đây .

Đây là một kịch bản ví dụ và kết quả đầu ra của nó:

@echo off

set scriptpath=%~dp0
set siblingfile=sibling.bat
set siblingfolder=sibling\
set fnwsfolder=folder name with spaces\
set descendantfolder=sibling\descendant\
set ancestorfolder=..\..\
set cousinfolder=..\uncle\cousin

call:MakeAbsolute siblingfile      "%scriptpath%"
call:MakeAbsolute siblingfolder    "%scriptpath%"
call:MakeAbsolute fnwsfolder       "%scriptpath%"
call:MakeAbsolute descendantfolder "%scriptpath%"
call:MakeAbsolute ancestorfolder   "%scriptpath%"
call:MakeAbsolute cousinfolder     "%scriptpath%"

echo scriptpath:       %scriptpath%
echo siblingfile:      %siblingfile%
echo siblingfolder:    %siblingfolder%
echo fnwsfolder:       %fnwsfolder%
echo descendantfolder: %descendantfolder%
echo ancestorfolder:   %ancestorfolder%
echo cousinfolder:     %cousinfolder%
GOTO:EOF

::----------------------------------------------------------------------------------
:: Function declarations
:: Handy to read http://www.dostips.com/DtTutoFunctions.php for how dos functions
:: work.
::----------------------------------------------------------------------------------
:MakeAbsolute file base -- makes a file name absolute considering a base path
::                      -- file [in,out] - variable with file name to be converted, or file name itself for result in stdout
::                      -- base [in,opt] - base path, leave blank for current directory
:$created 20060101 :$changed 20080219 :$categories Path
:$source http://www.dostips.com
SETLOCAL ENABLEDELAYEDEXPANSION
set "src=%~1"
if defined %1 set "src=!%~1!"
set "bas=%~2"
if not defined bas set "bas=%cd%"
for /f "tokens=*" %%a in ("%bas%.\%src%") do set "src=%%~fa"
( ENDLOCAL & REM RETURN VALUES
    IF defined %1 (SET %~1=%src%) ELSE ECHO.%src%
)
EXIT /b

Và đầu ra:

C:\Users\dayneo\Documents>myscript
scriptpath:       C:\Users\dayneo\Documents\
siblingfile:      C:\Users\dayneo\Documents\sibling.bat
siblingfolder:    C:\Users\dayneo\Documents\sibling\
fnwsfolder:       C:\Users\dayneo\Documents\folder name with spaces\
descendantfolder: C:\Users\dayneo\Documents\sibling\descendant\
ancestorfolder:   C:\Users\
cousinfolder:     C:\Users\dayneo\uncle\cousin

Tôi hy vọng điều này sẽ giúp ... Nó chắc chắn đã giúp tôi :) PS Cảm ơn một lần nữa với DosTips! Bạn đá!

Bạn chỉ có thể nối chúng.

SET ABS_PATH=%~dp0 
SET REL_PATH=..\SomeFile.txt
SET COMBINED_PATH=%ABS_PATH%%REL_PATH%

nó trông có vẻ kỳ lạ với \ .. \ ở giữa đường dẫn của bạn nhưng nó hoạt động. Không cần làm gì điên cả :)

Trong ví dụ của bạn, từ Bar \ test.bat, DIR / B / S .. \ somefile.txt sẽ trả về đường dẫn đầy đủ.

PowerShell khá phổ biến hiện nay vì vậy tôi sử dụng nó thường xuyên như một cách nhanh chóng để gọi C # vì nó có chức năng cho mọi thứ khá nhiều:

@echo off
set pathToResolve=%~dp0\..\SomeFile.txt
for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo Resolved path: %resolvedPath%

Hơi chậm một chút, nhưng chức năng thu được rất khó để đánh bại trừ khi không dùng đến ngôn ngữ kịch bản thực tế.

giải pháp của stijn hoạt động với các thư mục con bên dưới C:\Program Files (86)\,

@echo off
set projectDirMc=test.txt

for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo full path:    %resolvedPath%

Tập tin Xem tất cả các câu trả lời khác

Thư mục

Với ..đường dẫn tương đối của bạn và giả sử bạn hiện đang ở D:\Projects\EditorProject:

cd .. & cd & cd EditorProject (đường dẫn tương đối)

trả về đường dẫn tuyệt đối, vd

D:\Projects

SET CD=%~DP0

SET REL_PATH=%CD%..\..\build\

call :ABSOLUTE_PATH    ABS_PATH   %REL_PATH%

ECHO %REL_PATH%

ECHO %ABS_PATH%

pause

exit /b

:ABSOLUTE_PATH

SET %1=%~f2

exit /b