Chuyển hướng đầu ra từ trong tệp Batch

Tôi đang tạo một tệp hàng loạt với một số lệnh đơn giản để thu thập thông tin từ hệ thống. Tệp lô chứa các lệnh để lấy thời gian, thông tin IP, người dùng, v.v.

Tôi đã tập hợp tất cả các lệnh trong một tệp lô và nó chạy, nhưng tôi muốn tệp lô, khi chạy sẽ xuất kết quả ra tệp văn bản (nhật ký). Có lệnh nào mà tôi có thể thêm vào lô sẽ làm như vậy không?

Hãy nhớ rằng tôi không muốn chạy hàng loạt từ cmd, sau đó chuyển hướng đầu ra; Tôi muốn chuyển hướng đầu ra từ bên trong lô, nếu điều đó có thể.

Cách đơn giản đơn giản là chậm vì nó mở và định vị con trỏ tệp đến End-Of-File nhiều lần.

@echo off
command1 >output.txt
command2 >>output.txt
...
commandN >>output.txt

Một cách tốt hơn - dễ viết hơn và nhanh hơn vì tệp chỉ được mở và định vị một lần.

@echo off
>output.txt (
  command1
  command2
  ...
  commandN
)

Một cách tốt và nhanh chóng khác chỉ mở và định vị tệp một lần

@echo off
call :sub >output.txt
exit /b

:sub
command1
command2
...
commandN

Chỉnh sửa 2020-04-17

Thỉnh thoảng bạn có thể muốn ghi liên tục vào hai hoặc nhiều tệp. Bạn cũng có thể muốn các thông báo khác nhau trên màn hình. Bạn vẫn có thể thực hiện điều này một cách hiệu quả bằng cách chuyển hướng đến các chốt điều khiển không xác định bên ngoài khối hoặc chương trình con có dấu ngoặc đơn, sau đó sử dụng &ký hiệu để tham chiếu đến các tệp đã được mở.

call :sub 9>File1.txt 8>File2.txt
exit /b

:sub
echo Screen message 1
>&9 File 1 message 1
>&8 File 2 message 1
echo Screen message 2
>&9 File 1 message 2
>&8 File 2 message 2
exit /b

Tôi đã chọn sử dụng các tay cầm 9 và 8 theo thứ tự ngược lại vì cách đó có nhiều khả năng tránh chuyển hướng vĩnh viễn tiềm ẩn do lỗi thiết kế triển khai chuyển hướng của Microsoft khi thực hiện nhiều chuyển hướng trên cùng một lệnh. Rất khó xảy ra, nhưng ngay cả cách tiếp cận đó cũng có thể làm lộ ra lỗi nếu bạn đủ cố gắng. Nếu bạn chuyển hướng giai đoạn hơn bạn đảm bảo tránh được sự cố.

3>File1.txt ( 4>File2.txt call :sub)
exit /b

:sub
etc.

nếu bạn muốn cả luồng ngoài và luồng sai được chuyển hướng

dir >> a.txt 2>&1

Tôi biết đây là một bài đăng cũ hơn, nhưng ai đó sẽ tình cờ tìm thấy nó trong một tìm kiếm của Google và có vẻ như một số câu hỏi mà OP hỏi trong các bình luận đã không được giải quyết cụ thể. Ngoài ra, hãy bình tĩnh với tôi vì đây là câu trả lời đầu tiên của tôi được đăng trên SO. :)

Để chuyển hướng đầu ra đến một tệp bằng tên tệp được tạo động, cách tiếp cận chuyển đến (đọc: nhanh & bẩn) của tôi là giải pháp thứ hai được cung cấp bởi @dbenham. Ví dụ:

@echo off
> filename_prefix-%DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log (
echo Your Name Here
echo Beginning Date/Time: %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log
REM do some stuff here
echo Your Name Here
echo Ending Date/Time: %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log
)

Sẽ tạo một tệp giống như những gì bạn thấy trong ảnh chụp màn hình này của tệp trong thư mục đích

Điều đó sẽ chứa đầu ra này:

Your Name Here
Beginning Date/Time: 2016-09-16_141048.log
Your Name Here
Ending Date/Time: 2016-09-16_141048.log

Cũng nên nhớ rằng giải pháp này phụ thuộc vào ngôn ngữ, vì vậy hãy cẩn thận khi bạn sử dụng nó như thế nào / khi nào.

echo some output >"your logfile"

hoặc là

(
 echo some output
 echo more output
)>"Your logfile"

nên điền vào hóa đơn.

Nếu bạn muốn APPENDđầu ra, hãy sử dụng >>thay vì >. >sẽ bắt đầu một tệp nhật ký mới.

@echo off
>output.txt (
echo Checking your system infor, Please wating...

systeminfo | findstr /c:"Host Name" 
systeminfo | findstr /c:"Domain"

ipconfig /all | find "Physical Address" 

ipconfig | find "IPv4" 
ipconfig | find "Default Gateway"

)

@pause

Có một chương trình nhỏ thú vị mà bạn có thể sử dụng để chuyển hướng đầu ra tới một tệp và bảng điều khiển

some_command  ^|  TEE.BAT  [ -a ]  filename 

@ECHO OFF
:: Check Windows version
IF NOT "%OS%"=="Windows_NT" GOTO Syntax

:: Keep variables local
SETLOCAL

:: Check command line arguments
SET Append=0
IF /I [%1]==[-a] (
	SET Append=1
	SHIFT
)
IF     [%1]==[] GOTO Syntax
IF NOT [%2]==[] GOTO Syntax

:: Test for invalid wildcards
SET Counter=0
FOR /F %%A IN ('DIR /A /B %1 2^>NUL') DO CALL :Count "%%~fA"
IF %Counter% GTR 1 (
	SET Counter=
	GOTO Syntax
)

:: A valid filename seems to have been specified
SET File=%1

:: Check if a directory with the specified name exists
DIR /AD %File% >NUL 2>NUL
IF NOT ERRORLEVEL 1 (
	SET File=
	GOTO Syntax
)

:: Specify /Y switch for Windows 2000 / XP COPY command
SET Y=
VER | FIND "Windows NT" > NUL
IF ERRORLEVEL 1 SET Y=/Y

:: Flush existing file or create new one if -a wasn't specified
IF %Append%==0 (COPY %Y% NUL %File% > NUL 2>&1)

:: Actual TEE
FOR /F "tokens=1* delims=]" %%A IN ('FIND /N /V ""') DO (
	>  CON    ECHO.%%B
	>> %File% ECHO.%%B
)

:: Done
ENDLOCAL
GOTO:EOF

:Count
SET /A Counter += 1
SET File=%1
GOTO:EOF

:Syntax
ECHO.
ECHO Tee.bat,  Version 2.11a for Windows NT 4 / 2000 / XP
ECHO Display text on screen and redirect it to a file simultaneously
ECHO.
IF NOT "%OS%"=="Windows_NT" ECHO Usage:  some_command  ³  TEE.BAT  [ -a ]  filename
IF NOT "%OS%"=="Windows_NT" GOTO Skip
ECHO Usage:  some_command  ^|  TEE.BAT  [ -a ]  filename
:Skip
ECHO.
ECHO Where:  "some_command" is the command whose output should be redirected
ECHO         "filename"     is the file the output should be redirected to
ECHO         -a             appends the output of the command to the file,
ECHO                        rather than overwriting the file
ECHO.
ECHO Written by Rob van der Woude
ECHO http://www.robvanderwoude.com
ECHO Modified by Kees Couprie
ECHO http://kees.couprie.org
ECHO and Andrew Cameron

Thêm hai dòng này gần đầu tệp hàng loạt của bạn, tất cả stdout và stderr sau đó sẽ được chuyển hướng đến log.txt:

if not "%1"=="STDOUT_TO_FILE"  %0 STDOUT_TO_FILE %*  >log.txt 2>&1
shift /1

@echo OFF
[your command] >> [Your log file name].txt

Tôi đã sử dụng lệnh trên trong tệp lô của mình và nó hoạt động. Trong tệp nhật ký, nó hiển thị kết quả lệnh của tôi.

Điều này có thể không thành công trong trường hợp các ký tự "độc hại" trong đầu vào. Xem xét đầu vào như thế nàyIsAnIn ^^^^ đặt là một cách tốt để hiểu những gì đang xảy ra. Chắc chắn có một quy tắc rằng chuỗi đầu vào PHẢI nằm trong dấu ngoặc kép nhưng tôi có cảm giác rằng quy tắc này là quy tắc hợp lệ chỉ khi ý nghĩa của đầu vào là một vị trí trên phân vùng NTFS (có thể đó là quy tắc cho các URL I không chắc chắn). Nhưng nó không phải là một quy tắc cho một chuỗi đầu vào tùy ý tất nhiên (đó là "một thực hành tốt" nhưng bạn không thể đếm với nó).

Thêm các dòng sau vào cuối tệp hàng loạt của bạn sẽ lấy mọi thứ giống như hiển thị bên trong cửa sổ CMD và xuất thành tệp văn bản:

powershell -c "$wshell = New-Object -ComObject wscript.shell; $wshell.SendKeys('^a')
powershell -c "$wshell = New-Object -ComObject wscript.shell; $wshell.SendKeys('^c')
powershell Get-Clipboard > MyLog.txt

Về cơ bản, nó thực hiện chọn tất cả -> sao chép vào khay nhớ tạm -> dán vào tệp văn bản .