Vim có thể theo dõi các thay đổi trong thời gian thực đối với một tệp tin không

Câu hỏi của tôi tương tự như câu hỏi này là làm thế nào để theo dõi một tệp văn bản trong thời gian thực nhưng tôi muốn làm điều đó trong vim. Tôi biết mình có thể đọc tệp sử dụng tệp đã mở tail -f sample.xmlvà khi nội dung mới được ghi vào tệp, nó cũng sẽ ghi nội dung mới vào màn hình của tôi. Tôi có thể có vim tự động điền dữ liệu mới khi tệp được cập nhật không?

Bạn có thể :set autoreadđể vim đọc tệp khi nó thay đổi. Tuy nhiên (tùy thuộc vào nền tảng của bạn), bạn phải tập trung cho nó.

Từ sự trợ giúp:

Khi một tệp được phát hiện đã bị thay đổi bên ngoài Vim và nó không bị thay đổi bên trong Vim, hãy tự động đọc lại tệp đó. Khi tệp đã bị xóa, điều này không được thực hiện.

Không biết về tự động, nhưng bạn có thể nhập:

:e!

để tải lại tệp

Đặt những điều sau vào của bạn .vimrc:

"kiểm tra một lần sau 4 giây không hoạt động ở chế độ bình thường
đặt autoread                                                                                                                                                                                    
au CursorHold * kiểm tra thời gian                                                                                                                                                                       

như @flukus đã nói trong một nhận xét cho câu trả lời trước đó mà bạn có thể call feedkeys["lh"](nó di chuyển con trỏ sang phải và quay lại bên trái, điều này bình thường không gây hại khi xem tệp nhật ký)

Vì vậy, nếu bạn kết hợp phần còn lại của câu trả lời, bạn có một đường thẳng, bạn có thể chạy từ ex (whithin vim) khi cần:

:set autoread | au CursorHold * checktime | call feedkeys("lh")

(nếu bạn muốn chuyển (gần) đến cuối tệp, chỉ cần sử dụng "G" thay vì "lh" với phím nguồn cấp dữ liệu)

Giải thích:
- autoread : đọc tệp khi được thay đổi từ bên ngoài (nhưng nó không tự hoạt động, không có bộ đếm thời gian bên trong hoặc thứ gì đó tương tự. Nó sẽ chỉ đọc tệp khi vim thực hiện một hành động, như lệnh trong ex :!
- Thời gian kiểm tra CursorHold * : khi người dùng không di chuyển con trỏ trong thời gian được chỉ định trong 'thời gian cập nhật' (theo mặc định là 4000 mili giây), thời gian kiểm tra được thực thi, kiểm tra các thay đổi từ bên ngoài tệp
- hãy gọi feedkeys ("lh") : con trỏ được di chuyển một lần, sang phải và qua trái. và sau đó không có gì xảy ra (... có nghĩa là CursorHold được kích hoạt, có nghĩa là chúng ta có một vòng lặp )

Ngoài ra, bạn có thể :set syntax=logtalktô màu nhật ký

Để dừng cuộn khi sử dụng call feedkeys("G"), hãy thực thi :set noautoread- bây giờ vim sẽ cho biết, tệp đã bị thay đổi. Hãy hỏi xem người ta có muốn đọc các thay đổi hay không)

(Điều này có bất kỳ tác dụng phụ nào không?)

Chỉnh sửa: Tôi thấy một tác dụng phụ: nếu một người sử dụng phím nguồn cấp dữ liệu "G", nó sẽ cuộn xuống mọi vùng đệm hiện đang mở ?! Vì vậy, không thể làm việc trong bộ đệm bên trái của cửa sổ splittet trong khi bộ đệm bên phải tự động cuộn xuống tệp nhật ký

Gắn cái này vào .vimrc của bạn và nó sẽ hoạt động như một ông chủ. (Lấy từ: http://vim.wikia.com/wiki/Have_Vim_check_automatically_if_the_file_has_changed_externally )

" Function to Watch for changes if buffer changed on disk
function! WatchForChanges(bufname, ...)
  " Figure out which options are in effect
  if a:bufname == '*'
    let id = 'WatchForChanges'.'AnyBuffer'
    " If you try to do checktime *, you'll get E93: More than one match for * is given
    let bufspec = ''
  else
    if bufnr(a:bufname) == -1
      echoerr "Buffer " . a:bufname . " doesn't exist"
      return
    end
    let id = 'WatchForChanges'.bufnr(a:bufname)
    let bufspec = a:bufname
  end
  if len(a:000) == 0
    let options = {}
  else
    if type(a:1) == type({})
      let options = a:1
    else
      echoerr "Argument must be a Dict"
    end
  end
  let autoread    = has_key(options, 'autoread')    ? options['autoread']    : 0
  let toggle      = has_key(options, 'toggle')      ? options['toggle']      : 0
  let disable     = has_key(options, 'disable')     ? options['disable']     : 0
  let more_events = has_key(options, 'more_events') ? options['more_events'] : 1
  let while_in_this_buffer_only = has_key(options, 'while_in_this_buffer_only') ? options['while_in_this_buffer_only'] : 0
  if while_in_this_buffer_only
    let event_bufspec = a:bufname
  else
    let event_bufspec = '*'
  end
  let reg_saved = @"
  "let autoread_saved = &autoread
  let msg = "\n"
  " Check to see if the autocommand already exists
  redir @"
    silent! exec 'au '.id
  redir END
  let l:defined = (@" !~ 'E216: No such group or event:')
  " If not yet defined...
  if !l:defined
    if l:autoread
      let msg = msg . 'Autoread enabled - '
      if a:bufname == '*'
        set autoread
      else
        setlocal autoread
      end
    end
    silent! exec 'augroup '.id
      if a:bufname != '*'
        "exec "au BufDelete    ".a:bufname . " :silent! au! ".id . " | silent! augroup! ".id
        "exec "au BufDelete    ".a:bufname . " :echomsg 'Removing autocommands for ".id."' | au! ".id . " | augroup! ".id
        exec "au BufDelete    ".a:bufname . " execute 'au! ".id."' | execute 'augroup! ".id."'"
      end
        exec "au BufEnter     ".event_bufspec . " :checktime ".bufspec
        exec "au CursorHold   ".event_bufspec . " :checktime ".bufspec
        exec "au CursorHoldI  ".event_bufspec . " :checktime ".bufspec
      " The following events might slow things down so we provide a way to disable them...
      " vim docs warn:
      "   Careful: Don't do anything that the user does
      "   not expect or that is slow.
      if more_events
        exec "au CursorMoved  ".event_bufspec . " :checktime ".bufspec
        exec "au CursorMovedI ".event_bufspec . " :checktime ".bufspec
      end
    augroup END
    let msg = msg . 'Now watching ' . bufspec . ' for external updates...'
  end
  " If they want to disable it, or it is defined and they want to toggle it,
  if l:disable || (l:toggle && l:defined)
    if l:autoread
      let msg = msg . 'Autoread disabled - '
      if a:bufname == '*'
        set noautoread
      else
        setlocal noautoread
      end
    end
    " Using an autogroup allows us to remove it easily with the following
    " command. If we do not use an autogroup, we cannot remove this
    " single :checktime command
    " augroup! checkforupdates
    silent! exec 'au! '.id
    silent! exec 'augroup! '.id
    let msg = msg . 'No longer watching ' . bufspec . ' for external updates.'
  elseif l:defined
    let msg = msg . 'Already watching ' . bufspec . ' for external updates'
  end
  echo msg
  let @"=reg_saved
endfunction

let autoreadargs={'autoread':1}
execute WatchForChanges("*",autoreadargs)

Tail Bundle nên làm những gì bạn muốn. Lưu ý, bản thân chưa sử dụng.

Nếu unix + neovim

:term tail -f <filename>

Rõ ràng là điều này sẽ không hiệu quả với tất cả mọi người, nhưng đó là cách tôi làm.

Ngoài ra còn có một plugin:

https://github.com/djoshea/vim-autoread

Đây là cách duy nhất tôi có thể làm cho nó hoạt động trên OSX.

VIM sẽ cảnh báo bạn khi tệp đã được cập nhật để bạn không ghi đè lên những thay đổi đã được thực hiện kể từ khi bạn mở tệp. Tại thời điểm đó, nó sẽ nhắc bạn tải lại tệp.