Các tính năng ẩn của tệp bó Windows

Một số tính năng ít biết, nhưng quan trọng và hữu ích của các tệp bó Windows là gì?

Hướng dẫn:

• Một tính năng cho mỗi câu trả lời
• Cung cấp cả mô tả ngắn về tính năng và ví dụ , không chỉ là liên kết đến tài liệu
• Giới hạn câu trả lời cho tính tự nhiên bản địa , nghĩa là không yêu cầu phần mềm bổ sung, như Bộ tài nguyên Windows

Làm rõ: Chúng tôi đề cập ở đây các tập lệnh được xử lý bởi cmd.exe, đây là mặc định trên các biến thể WinNT.

(Xem thêm: Các tệp bó của Windows: .bat so với .cmd? )

Tiếp tục dòng:

call C:\WINDOWS\system32\ntbackup.exe ^
    backup ^
    /V:yes ^
    /R:no ^
    /RS:no ^
    /HC:off ^
    /M normal ^
    /L:s ^
    @daily.bks ^
    /F daily.bkf

PUSHD path

Đưa bạn đến thư mục được chỉ định bởi đường dẫn .

POPD

Đưa bạn trở lại thư mục mà bạn "đẩy" từ.

Không chắc chắn cách hữu ích này sẽ được trong một loạt tập tin, nhưng đó là một lệnh rất thuận tiện để sử dụng trong command prompt:

C:\some_directory> start .

Điều này sẽ mở Windows Explorer trong thư mục "some_directory".

Tôi đã tìm thấy điều này một tiết kiệm thời gian tuyệt vời.

Tôi luôn cảm thấy khó đọc các bình luận được đánh dấu bởi một từ khóa trên mỗi dòng:

REM blah blah blah

Dễ đọc hơn:

:: blah blah blah

Biến đổi con:

> set str=0123456789
> echo %str:~0,5%
01234
> echo %str:~-5,5%
56789
> echo %str:~3,-3%
3456

Lệnh FOR ! Trong khi tôi ghét viết các tập tin hàng loạt, tôi rất biết ơn về điều đó.

FOR /F "eol=; tokens=2,3* delims=, " %i in (myfile.txt) do @echo %i %j %k

sẽ phân tích từng dòng trong myfile.txt, bỏ qua các dòng bắt đầu bằng dấu chấm phẩy, chuyển mã thông báo thứ 2 và thứ 3 từ mỗi dòng sang phần thân, với các thẻ được phân tách bằng dấu phẩy và / hoặc dấu cách. Lưu ý tham chiếu câu lệnh cơ thể% i để nhận mã thông báo thứ 2,% j để nhận mã thông báo thứ 3 và% k để nhận tất cả các mã thông báo còn lại sau lần thứ 3.

Bạn cũng có thể sử dụng điều này để lặp lại các thư mục, nội dung thư mục, v.v ...

Thay vì xả một tập lệnh bằng các dòng REM hoặc ::, tôi thực hiện các thao tác sau ở đầu mỗi tập lệnh:

@echo OFF
goto :START

Description of the script.

Usage:
   myscript -parm1|parm2 > result.txt

:START

Lưu ý cách bạn có thể sử dụng các ký tự ống và chuyển hướng mà không thoát khỏi chúng.

Đường dẫn (có ổ đĩa) trong đó tập lệnh là: ~ dp0

set BAT_HOME=%~dp0
echo %BAT_HOME%
cd %BAT_HOME%

Đoạn% ~ dp0 đã được đề cập, nhưng thực sự có nhiều hơn thế: ký tự sau ~ xác định thông tin được trích xuất.
Không có chữ cái nào dẫn đến việc trả lại tên tệp vá
d - trả về ký tự ổ đĩa
p - trả về đường dẫn
s - trả về đường dẫn ngắn
x - trả về phần mở rộng tệp
Vì vậy, nếu bạn thực thi tập lệnh test.bat bên dưới từ c: \ Temp \ thư mục tên dài \ thư mục,

@echo off
echo %0
echo %~d0
echo %~p0
echo %~dp0
echo %~x0
echo %~s0
echo %~sp0

bạn nhận được đầu ra sau

test
c:
\Temp\long dir name\
c:\Temp\long dir name\
.bat
c:\Temp\LONGDI~1\test.bat
\Temp\LONGDI~1\

Và nếu một tham số được truyền vào tập lệnh của bạn như trong
thử nghiệm c: \ temp \ mysrc \ test.cpp
thì các thao tác tương tự có thể được thực hiện với biến% 1.

Nhưng kết quả của việc mở rộng% 0 phụ thuộc vào vị trí!
Ở "cấp cao nhất" của lô, nó mở rộng thành tên tệp bó hiện tại.
Trong một hàm (gọi), nó mở rộng thành tên hàm.

@echo off
echo %0
call :test
goto :eof

:test
echo %0
echo %~0
echo %~n0

Đầu ra là (batchfile được bắt đầu với myBatch.bat)

myBatch.bat
:test
:test
myBatch

Bằng cách sử dụng CALL, EXIT / B, SETLOCAL & ENDLOCAL, bạn có thể triển khai chương trình con với các biến cục bộ.

thí dụ:

@echo off

set x=xxxxx
call :sub 10
echo %x%
exit /b

:sub
setlocal
set /a x=%1 + 1
echo %x%
endlocal
exit /b

Cái này sẽ in

11
xxxxx

mặc dù: phụ sửa đổi x.

Thủ thuật lén lút để chờ N giây (không phải là một phần của cmd.exe nhưng không phải là phần mềm bổ sung vì nó đi kèm với Windows), hãy xem dòng ping. Bạn cần ping N + 1 kể từ khi ping đầu tiên tắt mà không bị trễ.

    echo %time%
    call :waitfor 5
    echo %time%
    goto :eof
:waitfor
    setlocal
    set /a "t = %1 + 1"
    >nul ping 127.0.0.1 -n %t%
    endlocal
    goto :eof

Thoát khỏi "hệ thống ống nước":

echo ^| ^< ^> ^& ^\ ^^

Có thể chạy các lệnh và xử lý đầu ra (như backticks của '$ ()' trong bash).

for /f %i in ('dir /on /b *.jpg') do echo --^> %i

Nếu có khoảng trắng trong tên tệp, hãy sử dụng:

for /f "tokens=*" %i in ('dir /on /b *.jpg') do echo --^> %i

Tạo một tệp trống:

> copy nul filename.ext

Để ẩn tất cả đầu ra từ một lệnh chuyển hướng đến> nul 2> & 1.

Ví dụ, một số chương trình dòng lệnh hiển thị đầu ra ngay cả khi bạn chuyển hướng đến> nul. Nhưng, nếu bạn chuyển hướng đầu ra như dòng bên dưới, tất cả đầu ra sẽ bị chặn.

PSKILL NOTEPAD >nul 2>&1

EDIT: Xem Bỏ qua đầu ra của lệnh để được giải thích về cách thức hoạt động của lệnh này.

PAUSE

Dừng thực thi và hiển thị lời nhắc sau:

Bấm phím bất kỳ để tiếp tục . . .

Hữu ích nếu bạn muốn chạy một lô bằng cách bấm đúp vào nó trong Windows Explorer và thực sự muốn xem đầu ra thay vì chỉ là một đèn flash của cửa sổ lệnh.

Tương đương với bash (và các shell khác)

echo -n Hello # or
echo Hello\\c

mà đầu ra " Hello" mà không có một dòng mới. Một hack cmd để làm điều này:

<nul set /p any-variable-name=Hello

set /plà một cách để nhắc người dùng nhập liệu. Nó phát ra chuỗi đã cho và sau đó chờ, (trên cùng một dòng, tức là không có CRLF), để người dùng nhập phản hồi.

<nul chỉ đơn giản là một câu trả lời trống rỗng cho set /p lệnh, vì vậy kết quả thực là chuỗi dấu nhắc phát ra. (Biến được sử dụng vẫn không thay đổi do phản hồi trống.)

Vấn đề là: Không thể tạo ra một dấu bằng hàng đầu và trên các ký tự khoảng trắng hàng đầu của Vista bị xóa, nhưng không phải trên XP.

Tìm kiếm và thay thế khi thiết lập các biến môi trường:

> @set fname=%date:/=%

... Xóa "/" khỏi ngày để sử dụng trong tên tệp được đánh dấu thời gian.

và các chuỗi con quá ...

> @set dayofweek=%fname:~0,3%

Số học số nguyên:

> SET /A result=10/3 + 1
4

Dấu phân cách lệnh:

cls & dir
copy a b && echo Success
copy a b || echo Failure

Ở dòng thứ 2, lệnh sau && chỉ chạy nếu lệnh đầu tiên thành công.

Ở dòng thứ 3, lệnh sau | | chỉ chạy nếu lệnh đầu tiên thất bại.

Xuất một dòng trống:

echo.

Bạn có thể xâu chuỗi các câu lệnh để có được hiệu ứng như boolean ngắn mạch `và '.

if foo if bar baz

Để nhanh chóng chuyển đổi tệp văn bản Unicode (16 bit / char) sang tệp ASCII DOS (8 bit / char).

C:\> type unicodeencoded.txt > dosencoded.txt

như một phần thưởng, nếu có thể, các ký tự được ánh xạ chính xác.

nếu cấu trúc khối:

if "%VS90COMNTOOLS%"=="" (
  echo: Visual Studio 2008 is not installed
  exit /b
)

Sự mở rộng của các biến bị trì hoãn (với các chuỗi con được đưa vào để đo lường tốt):

    @echo off
    setlocal enableextensions enabledelayedexpansion
    set full=/u01/users/pax
:loop1
    if not "!full:~-1!" == "/" (
        set full2=!full:~-1!!full2!
        set full=!full:~,-1!
        goto :loop1
    )
    echo !full!
    endlocal

Không cung cấp nhiều chức năng, nhưng bạn có thể sử dụng lệnh tiêu đề cho một vài mục đích sử dụng, như cung cấp trạng thái trên một tập lệnh dài trong thanh tác vụ hoặc chỉ để nâng cao phản hồi của người dùng.

@title Searching for ...
:: processing search
@title preparing search results
:: data processing

Không có trình chỉnh sửa tiện dụng và cần tạo một tệp bó?

copy con test.bat

Chỉ cần gõ các lệnh, nhấn enter cho một dòng mới. Nhấn Ctrl-Z và Enter để đóng tệp.

ví dụ về phép trừ chuỗi trên datevà timeđể lấy tệp có tên "YYYY-MM-DD HH: MM: SS.txt"

echo test > "%date:~0,4%-%date:~5,2%-%date:~8,2% %time:~0,2%_%time:~3,2%_%time:~6,2%.txt"

Tôi sử dụng colorđể cho biết nếu tập lệnh của tôi kết thúc thành công, thất bại hoặc cần một số đầu vào bằng cách thay đổi màu sắc của văn bản và nền. Nó thực sự hữu ích khi bạn có một số máy trong tầm nhìn của bạn nhưng khá xa

màu XY

Trong đó X và Y là giá trị hex từ 0đến F, trong đó X - nền, Y - văn bản, khi màu X = Y sẽ không thay đổi.

màu Z

thay đổi màu văn bản thành 'Z' và đặt nền đen, 'màu 0' sẽ không hoạt động

cho tên của màu sắc gọi

màu sắc ?

Tổng kiểm soát đầu ra với các ký tự khoảng cách và thoát:

echo.    ^<resourceDir^>/%basedir%/resources^</resourceDir^>

TheSoftwareJedi đã đề cập đến lệnh for, nhưng tôi sẽ đề cập lại vì nó rất mạnh.

Sau đây xuất ra ngày hiện tại ở định dạng YYYYMMDD, tôi sử dụng điều này khi tạo thư mục để sao lưu.

for /f "tokens=2-4 delims=/- " %a in ('DATE/T') do echo %c%b%a