Cách khôi phục ngoại lệ tương tự trong SQL Server

Tôi muốn tạo lại cùng một ngoại lệ trong SQL Server vừa xảy ra trong khối thử của tôi. Tôi có thể gửi cùng một thông báo nhưng tôi muốn ném cùng một lỗi.

BEGIN TRANSACTION
    BEGIN TRY
        INSERT INTO Tags.tblDomain (DomainName, SubDomainId, DomainCode, Description)
            VALUES(@DomainName, @SubDomainId, @DomainCode, @Description)
        COMMIT TRANSACTION
    END TRY
    
    BEGIN CATCH
        declare @severity int; 
        declare @state int;

        select @severity=error_severity(), @state=error_state();

        RAISERROR(@@Error,@ErrorSeverity,@state);
        ROLLBACK TRANSACTION
    END CATCH

RAISERROR(@@Error, @ErrorSeverity, @state);

Dòng này sẽ hiển thị lỗi, nhưng tôi muốn chức năng giống như vậy. Điều này gây ra lỗi với số lỗi 50000, nhưng tôi muốn số lỗi được đưa ra mà tôi đang vượt qua @@error,

Tôi muốn ghi lại lỗi này không có ở giao diện người dùng.

I E

catch (SqlException ex)
{
    if ex.number==2627
    MessageBox.show("Duplicate value cannot be inserted");
}

Tôi muốn chức năng này. mà không thể đạt được bằng cách sử dụng raiseerror. Tôi không muốn đưa ra thông báo lỗi tùy chỉnh ở phía sau.

RAISEERROR sẽ trả về lỗi được đề cập bên dưới khi tôi vượt qua ErrorNo để được ném vào bắt

Msg 2627, Level 14, State 1, Procedure spOTest_DomainInsert,

Dòng 14 Vi phạm ràng buộc KEY DUY NHẤT 'UK_DomainCode'. Không thể chèn khóa trùng lặp trong đối tượng 'Tags.tblDomain'. Các tuyên bố này đã bị chấm dứt.

BIÊN TẬP:

Hạn chế của việc không sử dụng khối try catch là gì nếu tôi muốn ngoại lệ được xử lý ở giao diện người dùng xem xét thủ tục được lưu trữ chứa nhiều truy vấn cần được thực thi?

Đây là một mẫu mã sạch đầy đủ chức năng để khôi phục một loạt các câu lệnh nếu xảy ra lỗi và báo cáo thông báo lỗi.

begin try
    begin transaction;

    ...

    commit transaction;
end try
begin catch
    if @@trancount > 0 rollback transaction;
    throw;
end catch

Trước SQL 2012

begin try
    begin transaction;
    
    ...
    
    commit transaction;
end try
begin catch
    declare @ErrorMessage nvarchar(max), @ErrorSeverity int, @ErrorState int;
    select @ErrorMessage = ERROR_MESSAGE() + ' Line ' + cast(ERROR_LINE() as nvarchar(5)), @ErrorSeverity = ERROR_SEVERITY(), @ErrorState = ERROR_STATE();
    if @@trancount > 0 rollback transaction;
    raiserror (@ErrorMessage, @ErrorSeverity, @ErrorState);
end catch

SQL 2012 giới thiệu câu lệnh ném:

http://msdn.microsoft.com/en-us/library/ee677615.aspx

Nếu câu lệnh THROW được chỉ định mà không có tham số, nó phải xuất hiện bên trong khối CATCH. Điều này làm cho ngoại lệ đã bắt được tăng lên.

BEGIN TRY
    BEGIN TRANSACTION
    ...
    COMMIT TRANSACTION
END TRY
BEGIN CATCH
    ROLLBACK TRANSACTION;
    THROW
END CATCH

Lật lại bên trong khối CATCH (mã trước SQL2012, sử dụng câu lệnh THROW cho SQL2012 trở lên):

DECLARE
    @ErrorMessage nvarchar(4000) = ERROR_MESSAGE(),
    @ErrorNumber int = ERROR_NUMBER(),
    @ErrorSeverity int = ERROR_SEVERITY(),
    @ErrorState int = ERROR_STATE(),
    @ErrorLine int = ERROR_LINE(),
    @ErrorProcedure nvarchar(200) = ISNULL(ERROR_PROCEDURE(), '-');
SELECT @ErrorMessage = N'Error %d, Level %d, State %d, Procedure %s, Line %d, ' + 'Message: ' + @ErrorMessage;
RAISERROR (@ErrorMessage, @ErrorSeverity, 1, @ErrorNumber, @ErrorSeverity, @ErrorState, @ErrorProcedure, @ErrorLine)

Tôi nghĩ lựa chọn của bạn là:

• Không bắt lỗi (để nó nổi lên)
• Nâng cao một tùy chỉnh

Tại một số điểm, SQL có thể sẽ giới thiệu một lệnh reraise, hoặc khả năng chỉ bắt một số lỗi nhất định. Nhưng hiện tại, hãy sử dụng một giải pháp thay thế. Lấy làm tiếc.

Bạn không thể: chỉ động cơ mới có thể tạo ra lỗi nhỏ hơn 50000. Tất cả những gì bạn có thể làm là ném một ngoại lệ giống như nó ...

Vui lòng xem câu trả lời của tôi ở đây

Người hỏi ở đây đã sử dụng các giao dịch phía khách hàng để làm những gì anh ta muốn mà tôi nghĩ là hơi ngớ ngẩn ...

Ok, đây là một giải pháp thay thế ... :-)

DECLARE @Error_Number INT
BEGIN TRANSACTION 
    BEGIN TRY
    INSERT INTO Test(Id, Name) VALUES (newID(),'Ashish') 
    /* Column 'Name' has unique constraint on it*/
    END TRY
    BEGIN CATCH

            SELECT ERROR_NUMBER()
            --RAISERROR (@ErrorMessage,@Severity,@State)
            ROLLBACK TRAN
    END CATCH

Nếu bạn lưu ý khối bắt, Nó không tăng lỗi mà trả về số lỗi thực tế (và cũng sẽ khôi phục giao dịch). Bây giờ trong mã .NET của bạn, thay vì bắt ngoại lệ, nếu bạn sử dụng ExecuteScalar (), bạn sẽ nhận được số lỗi thực tế mà bạn muốn và hiển thị số thích hợp.

int errorNumber=(int)command.ExecuteScalar();
if(errorNumber=<SomeNumber>)
{
    MessageBox.Show("Some message");
}

Hi vọng điêu nay co ich,

CHỈNH SỬA: - Chỉ cần lưu ý, Nếu bạn muốn có số lượng bản ghi bị ảnh hưởng và cố gắng sử dụng ExecuteNonQuery, giải pháp trên có thể không hiệu quả với bạn. Nếu không, tôi nghĩ nó sẽ phù hợp với những gì bạn cần. Cho tôi biết.

Cách để dừng thực thi trong một thủ tục được lưu trữ sau khi xảy ra lỗi và đánh dấu lỗi trở lại chương trình đang gọi là làm theo từng câu lệnh có thể gây ra lỗi với mã này:

If @@ERROR > 0
Return

Bản thân tôi đã rất ngạc nhiên khi phát hiện ra rằng việc thực thi trong một thủ tục được lưu trữ có thể tiếp tục sau khi có lỗi - việc không nhận ra điều này có thể dẫn đến một số lỗi khó theo dõi.

Loại xử lý lỗi này song song (pre .Net) Visual Basic 6. Mong đợi lệnh Throw trong SQL Server 2012.

Giả sử rằng bạn vẫn chưa chuyển sang năm 2012, một cách để triển khai mã lỗi ban đầu là sử dụng phần tin nhắn văn bản của ngoại lệ bạn đang (lại) ném từ khối bắt. Hãy nhớ rằng nó có thể chứa một số cấu trúc, chẳng hạn như văn bản XML để mã người gọi của bạn phân tích cú pháp trong khối bắt của nó.

Bạn cũng có thể tạo một thủ tục được lưu trữ trong trình bao bọc cho các trường hợp đó khi bạn muốn câu lệnh SQL được thực thi trong giao dịch và cung cấp lỗi cho mã của bạn.

CREATE PROCEDURE usp_Execute_SQL_Within_Transaction
(
    @SQL nvarchar(max)
)
AS

SET NOCOUNT ON

BEGIN TRY
    BEGIN TRANSACTION
        EXEC(@SQL)
    COMMIT TRANSACTION
END TRY

BEGIN CATCH
    DECLARE @ErrorMessage nvarchar(max), @ErrorSeverity int, @ErrorState int
    SELECT @ErrorMessage = N'Error Number: ' + CONVERT(nvarchar(5), ERROR_NUMBER()) + N'. ' + ERROR_MESSAGE() + ' Line ' + CONVERT(nvarchar(5), ERROR_LINE()), @ErrorSeverity = ERROR_SEVERITY(), @ErrorState = ERROR_STATE()
    ROLLBACK TRANSACTION
    RAISERROR (@ErrorMessage, @ErrorSeverity, @ErrorState)
END CATCH

GO

-- Test it
EXEC usp_Execute_SQL_Within_Transaction @SQL = 'SELECT 1; SELECT 2'
EXEC usp_Execute_SQL_Within_Transaction @SQL = 'SELECT 1/0; SELECT 2'
EXEC usp_Execute_SQL_Within_Transaction @SQL = 'EXEC usp_Another_SP'

Từ quan điểm thiết kế, việc ném các ngoại lệ với số lỗi ban đầu và thông báo tùy chỉnh có ích gì? Ở một mức độ nào đó, nó phá vỡ hợp đồng giao diện giữa các ứng dụng và cơ sở dữ liệu. Nếu bạn muốn bắt lỗi ban đầu và xử lý chúng trong mã cao hơn, đừng xử lý chúng trong cơ sở dữ liệu. Sau đó, khi bạn bắt gặp một ngoại lệ, bạn có thể thay đổi thông báo được hiển thị cho người dùng thành bất kỳ thứ gì bạn muốn. Tuy nhiên, tôi sẽ không làm điều đó, bởi vì nó làm cho mã cơ sở dữ liệu của bạn hmm 'không đúng'. Như những người khác đã nói, bạn nên xác định một tập hợp các mã lỗi của riêng mình (trên 50000) và thay thế chúng. Sau đó, bạn có thể giải quyết các vấn đề về tính toàn vẹn ('Không cho phép các giá trị trùng lặp') riêng biệt với các vấn đề kinh doanh tiềm ẩn - 'Mã zip không hợp lệ', 'Không tìm thấy hàng nào phù hợp với tiêu chí', v.v.