Tạo một ngày từ ngày tháng và năm với T-SQL

Tôi đang cố gắng chuyển đổi một ngày với các phần riêng lẻ, chẳng hạn như 12, 1, 2007 thành một datetime trong SQL Server 2005. Tôi đã thử như sau:

CAST(DATEPART(year, DATE)+'-'+ DATEPART(month, DATE) +'-'+ DATEPART(day, DATE) AS DATETIME)

nhưng điều này dẫn đến sai ngày. Cách chính xác để biến ba giá trị ngày thành định dạng datetime thích hợp.

Giả sử y, m, dlà tất cả int, làm thế nào về:

CAST(CAST(y AS varchar) + '-' + CAST(m AS varchar) + '-' + CAST(d AS varchar) AS DATETIME)

Vui lòng xem câu trả lời khác của tôi cho SQL Server 2012 trở lên

Thử cái này:

Declare @DayOfMonth TinyInt Set @DayOfMonth = 13
Declare @Month TinyInt Set @Month = 6
Declare @Year Integer Set @Year = 2006
-- ------------------------------------
Select DateAdd(day, @DayOfMonth - 1, 
          DateAdd(month, @Month - 1, 
              DateAdd(Year, @Year-1900, 0)))

Nó cũng hoạt động, đã thêm lợi ích của việc không thực hiện bất kỳ chuyển đổi chuỗi nào, do đó, nó xử lý số học thuần túy (rất nhanh) và nó không phụ thuộc vào bất kỳ định dạng ngày nào. Điều này tận dụng thực tế là đại diện bên trong của SQL Server cho các giá trị thời gian và thời gian nhỏ là hai phần giá trị phần đầu tiên là số nguyên biểu thị số ngày kể từ ngày 1 tháng 1 năm 1900 và phần thứ hai là phần thập phân biểu thị phần phân số của một ngày (đối với thời gian) --- Vì vậy, giá trị số nguyên 0 (không ) luôn dịch trực tiếp vào nửa đêm ngày 1 tháng 1 năm 1900 ...

hoặc, nhờ đề xuất từ ​​@brinary,

Select DateAdd(yy, @Year-1900,  
       DateAdd(m,  @Month - 1, @DayOfMonth - 1)) 

Được chỉnh sửa vào tháng 10 năm 2014. Theo ghi nhận của @cade Roux, SQL 2012 hiện có chức năng tích hợp:
DATEFROMPARTS(year, month, day)
thực hiện điều tương tự.

Đã chỉnh sửa ngày 3 tháng 10 năm 2016, (Cảm ơn @bambams vì đã nhận thấy điều này và @brinary đã sửa nó), Giải pháp cuối cùng, được đề xuất bởi @brinary. dường như không hoạt động trong nhiều năm, trừ khi việc bổ sung được thực hiện trước

select dateadd(month, @Month - 1, 
     dateadd(year, @Year-1900, @DayOfMonth - 1)); 

SQL Server 2012 có chức năng DATEFROMPARTS mới tuyệt vời và được chờ đợi từ lâu (sẽ gây ra lỗi nếu ngày không hợp lệ - phản đối chính của tôi đối với giải pháp dựa trên DATEADD cho vấn đề này):

http://msdn.microsoft.com/en-us/l Library / hh213228.aspx

DATEFROMPARTS(ycolumn, mcolumn, dcolumn)

hoặc là

DATEFROMPARTS(@y, @m, @d)

Hoặc chỉ sử dụng một hàm dữ liệu duy nhất:

DECLARE @day int, @month int, @year int
SELECT @day = 4, @month = 3, @year = 2011

SELECT dateadd(mm, (@year - 1900) * 12 + @month - 1 , @day - 1)

Sql Server 2012 có chức năng sẽ tạo ngày dựa trên các phần ( DATEFROMPARTS ). Đối với phần còn lại của chúng tôi, đây là một hàm db tôi đã tạo sẽ xác định ngày từ các phần (cảm ơn @Charles) ...

IF EXISTS (SELECT * FROM dbo.sysobjects WHERE id = object_id(N'[dbo].[func_DateFromParts]'))
    DROP FUNCTION [dbo].[func_DateFromParts]
GO

CREATE FUNCTION [dbo].[func_DateFromParts]
(
    @Year INT,
    @Month INT,
    @DayOfMonth INT,
    @Hour INT = 0,  -- based on 24 hour clock (add 12 for PM :)
    @Min INT = 0,
    @Sec INT = 0
)
RETURNS DATETIME
AS
BEGIN

    RETURN DATEADD(second, @Sec, 
            DATEADD(minute, @Min, 
            DATEADD(hour, @Hour,
            DATEADD(day, @DayOfMonth - 1, 
            DATEADD(month, @Month - 1, 
            DATEADD(Year, @Year-1900, 0))))))

END

GO

Bạn có thể gọi nó như thế này ...

SELECT dbo.func_DateFromParts(2013, 10, 4, 15, 50, DEFAULT)

Trả về ...

2013-10-04 15:50:00.000

Hãy thử CHUYỂN ĐỔI thay vì CAST.

CONVERT cho phép tham số thứ ba cho biết định dạng ngày.

Danh sách các định dạng ở đây: http://msdn.microsoft.com/en-us/l Library / ms187928.aspx

Cập nhật sau khi câu trả lời khác đã được chọn là câu trả lời "đúng":

Tôi thực sự không hiểu tại sao câu trả lời được chọn rõ ràng phụ thuộc vào cài đặt NLS trên máy chủ của bạn mà không chỉ ra hạn chế này.

Bạn cũng có thể dùng

select DATEFROMPARTS(year, month, day) as ColDate, Col2, Col3 
From MyTable Where DATEFROMPARTS(year, month, day) Between @DateIni and @DateEnd

Hoạt động trong SQL kể từ ver.2012 và AzureQuery

An toàn hơn và gọn gàng hơn khi sử dụng điểm bắt đầu rõ ràng '19000101'

create function dbo.fnDateTime2FromParts(@Year int, @Month int, @Day int, @Hour int, @Minute int, @Second int, @Nanosecond int)
returns datetime2
as
begin
    -- Note! SQL Server 2012 includes datetime2fromparts() function
    declare @output datetime2 = '19000101'
    set @output = dateadd(year      , @Year - 1900  , @output)
    set @output = dateadd(month     , @Month - 1    , @output)
    set @output = dateadd(day       , @Day - 1      , @output)
    set @output = dateadd(hour      , @Hour         , @output)
    set @output = dateadd(minute    , @Minute       , @output)
    set @output = dateadd(second    , @Second       , @output)
    set @output = dateadd(ns        , @Nanosecond   , @output)
    return @output
end

Nếu bạn không muốn giữ các chuỗi bên ngoài nó, điều này cũng hoạt động (Đặt nó vào một hàm):

DECLARE @Day int, @Month int, @Year int
SELECT @Day = 1, @Month = 2, @Year = 2008

SELECT DateAdd(dd, @Day-1, DateAdd(mm, @Month -1, DateAdd(yy, @Year - 2000, '20000101')))

Tôi thêm giải pháp một dòng nếu bạn cần một datetime từ cả hai phần ngày và giờ :

select dateadd(month, (@Year -1900)*12 + @Month -1, @DayOfMonth -1) + dateadd(ss, @Hour*3600 + @Minute*60 + @Second, 0) + dateadd(ms, @Millisecond, 0)

Thử

CAST(STR(DATEPART(year, DATE))+'-'+ STR(DATEPART(month, DATE)) +'-'+ STR(DATEPART(day, DATE)) AS DATETIME)

Đối với các phiên bản SQL Server dưới 12, tôi có thể khuyên bạn nên sử dụng CASTkết hợp vớiSET DATEFORMAT

-- 26 February 2015
SET DATEFORMAT dmy
SELECT CAST('26-2-2015' AS DATE)

SET DATEFORMAT ymd
SELECT CAST('2015-2-26' AS DATE)

cách bạn tạo ra các chuỗi đó là tùy thuộc vào bạn

Hãy thử truy vấn này:

    SELECT SUBSTRING(CONVERT(VARCHAR,JOINGDATE,103),7,4)AS
    YEAR,SUBSTRING(CONVERT(VARCHAR,JOINGDATE,100),1,2)AS
MONTH,SUBSTRING(CONVERT(VARCHAR,JOINGDATE,100),4,3)AS DATE FROM EMPLOYEE1

Kết quả:

2014    Ja    1
2015    Ja    1
2014    Ja    1
2015    Ja    1
2012    Ja    1
2010    Ja    1
2015    Ja    1

Tôi biết OP đang yêu cầu câu trả lời SQL 2005 nhưng câu hỏi khá cũ nên nếu bạn đang chạy SQL 2012 trở lên, bạn có thể sử dụng như sau:

SELECT DATEADD(DAY, 1, EOMONTH(@somedate, -1))

Tham khảo: https://docs.microsoft.com/en-us/sql/t-sql/fifts/eomonth-transact-sql?view=sql-server-2017&viewFallbackFrom=sql-server-preinglyversions

Cá nhân tôi thích Chuỗi con hơn vì nó cung cấp các tùy chọn làm sạch và khả năng phân tách chuỗi khi cần. Giả định là dữ liệu có định dạng 'dd, mm, yyyy'.

--2012 and above
SELECT CONCAT (
        RIGHT(REPLACE(@date, ' ', ''), 4)
        ,'-'
        ,RIGHT(CONCAT('00',SUBSTRING(REPLACE(@date, ' ', ''), CHARINDEX(',', REPLACE(@date, ' ', '')) + 1, LEN(REPLACE(@date, ' ', '')) - CHARINDEX(',', REPLACE(@date, ' ', '')) - 5)),2)
        ,'-'
        ,RIGHT(CONCAT('00',SUBSTRING(REPLACE(@date, ' ', ''), 1, CHARINDEX(',', REPLACE(@date, ' ', '')) - 1)),2)
        )

--2008 and below
SELECT   RIGHT(REPLACE(@date, ' ', ''), 4)
        +'-'
        +RIGHT('00'+SUBSTRING(REPLACE(@date, ' ', ''), CHARINDEX(',', REPLACE(@date, ' ', '')) + 1, LEN(REPLACE(@date, ' ', '')) - CHARINDEX(',', REPLACE(@date, ' ', '')) - 5),2)
        +'-'
        +RIGHT('00'+SUBSTRING(REPLACE(@date, ' ', ''), 1, CHARINDEX(',', REPLACE(@date, ' ', '')) - 1),2)

Dưới đây là một minh chứng về cách nó có thể bị kiện nếu dữ liệu được lưu trữ trong một cột. Không cần phải nói, lý tưởng của nó là kiểm tra tập kết quả trước khi áp dụng cho cột

DECLARE @Table TABLE (ID INT IDENTITY(1000,1), DateString VARCHAR(50), DateColumn DATE)

INSERT INTO @Table
SELECT'12, 1, 2007',NULL
UNION
SELECT'15,3, 2007',NULL
UNION
SELECT'18, 11 , 2007',NULL
UNION
SELECT'22 , 11, 2007',NULL
UNION
SELECT'30, 12, 2007  ',NULL

UPDATE @Table
SET DateColumn = CONCAT (
        RIGHT(REPLACE(DateString, ' ', ''), 4)
        ,'-'
        ,RIGHT(CONCAT('00',SUBSTRING(REPLACE(DateString, ' ', ''), CHARINDEX(',', REPLACE(DateString, ' ', '')) + 1, LEN(REPLACE(DateString, ' ', '')) - CHARINDEX(',', REPLACE(DateString, ' ', '')) - 5)),2)
        ,'-'
        ,RIGHT(CONCAT('00',SUBSTRING(REPLACE(DateString, ' ', ''), 1, CHARINDEX(',', REPLACE(DateString, ' ', '')) - 1)),2)
        ) 

SELECT ID,DateString,DateColumn
FROM @Table