Truy vấn Bảng tính Google: Tôi có thể xóa tiêu đề cột không?

98

Tôi đang thực hiện truy vấn này trên bảng tính google của mình:

=QUERY(H4:L35;"select sum(L) where H='First Week'"; -1)

Nhưng nó trả về một bảng nhỏ với "sum" làm tiêu đề và kết quả bên dưới nó. Điều tôi muốn chỉ là kết quả! Làm cách nào để xóa tiêu đề? Tôi có thể?

— Poliane Brito
nguồn

Điều này có vẻ thẳng hơn về phía trước: stackoverflow.com/a/41797729/5316231

— user19581

187

Thử cái này:

=QUERY(H4:L35,"select sum(L) where H='First Week' label sum(L) ''")

Hy vọng rằng Giúp được!

— KRR
nguồn

3

Tôi vừa thử nghiệm điều này trong một trong các trang tính của mình và nó xóa tiêu đề khỏi kết quả trả về; điều này sẽ được đánh dấu là câu trả lời đúng. :)

— FooBar

1

Điều này thật tuyệt và nó hoạt động, nhưng có ai có thể giải thích tại sao hai dấu ngoặc kép lại cần ở cuối không? Điều đó làm gì từ góc độ cú pháp?

— y-i_guy

2

Dấu nháy đơn thay thế tiêu đề tổng bằng không gian trống. Hy vọng rằng giải thích câu hỏi của bạn !!

— KRR

2

Cảm ơn vì câu trả lời! Tôi cần làm tương tự với nhiều cột nhưng tôi không thể đạt được nó! Tôi mong đợi điều này sẽ hoạt động: = QUERY (H4: L35, "chọn sum (L), sum (H) trong đó H = 'Tuần đầu tiên' nhãn sum (L) '' nhãn sum (H) ''")

— Emilio Nicolás

11

LABEL B 'Label1', C 'Label2'cho nhiều cột

— sojim2

30

=QUERY(QUERY(A1:D, "SELECT *", 1), "SELECT * OFFSET 1", 0)

Truy vấn bên ngoài: "SELECT * OFFSET 1"loại trừ hàng đầu tiên (tiêu đề).

Truy vấn bên trong chỉ định rõ ràng một hàng tiêu đề (thông qua đối số thứ ba được cung cấp cho QUERY), trong khi truy vấn bên ngoài chỉ định không có.

— user280150
nguồn

3

Một chút giải thích?

— J Fabian Meier

Tại sao điều thứ hai là QUERYcần thiết? Tham số "0" không làm giảm tiêu đề, vì vậy bạn có thể sử dụng nó ở đầu tiên QUERY, như sau: QUERY('Form responses 3'!$A$2:$P$1017, "SELECT max(E),max(C), max(D) WHERE B='" & B14 & "' GROUP BY B LIMIT 1 ", 0)

— Steven M. Mortimer

3

Tôi tin rằng OFFSET 1trong truy vấn thứ hai sẽ giảm hàng đầu tiên của tập dữ liệu được trả về, không phải tiêu đề trong hàng đầu tiên.

— Steven M. Mortimer

2

Câu trả lời này có thể dài dòng hơn nhưng nó cũng mạnh mẽ hơn và có thể được sử dụng mà không cần lặp lại các chuỗi tổng hợp cột. Nó thậm chí có thể được sử dụng với pivot, mà không hoạt động với bất kỳ câu trả lời nào khác ở đây.

— 7yl4r

1

Trừ khi tôi nhầm lẫn, điều này không thực sự giải quyết được thách thức cụ thể mà người đăng ban đầu đưa ra, tức là loại bỏ các tiêu đề được QUERY tự động tạo ra khi sử dụng các hàm tổng hợp như SUM. Khi sử dụng hàm SUM (hoặc bất kỳ hàm tổng hợp nào khác), QUERY tự động tạo một hàng tiêu đề chỉ định tập hợp được thực hiện, ví dụ: "sum". Nó sẽ thực hiện điều này ngay cả khi bạn đặt tiêu đề thành 0 và ngay cả khi bạn áp dụng mệnh đề OFFSET 1. Công thức sau vẫn trả về tiêu đề. = QUERY (Sheet1! A: B, "SELECT A, SUM (B) GROUP BY A OFFSET 1", 0) Câu trả lời được chấp nhận sẽ giải quyết được thử thách này.

— Dave Meindl

0

Tôi có một QUERY đang trả về top 3. Tôi không thể làm cho điều này hoạt động khi trả về nhiều hàng. Tôi đã kết thúc chỉ ẩn hàng với công thức và chỉ có câu trả lời hiển thị bây giờ.

— Brian Wochele
nguồn

0

=INDEX(QUERY(H4:L35;"select sum(L) where H='First Week'"; -1),2,1)

Thao tác này chỉ phân tích cú pháp mảng được trả về và chọn bản ghi thứ 2 được trả về trong cột đầu tiên.

Bạn cũng có thể thực hiện việc này với chức năng lọc ít tính toán hơn.

=SUM(FILTER(L4:L35, H4:H35 = "First Week"))

— Dean Falconer
nguồn

-3

Xem định dạng tại đây .

Thí dụ:

=QUERY(B4:C38,
   "SELECT C, sum(B) where C!='' group by C label C 'Member', sum(B) 'Sum'"
)

— Andy
nguồn

2

Ví dụ được cung cấp không trả về kết quả không có tiêu đề.

— Rubén