Cách trả về kết quả từ hàm VBA

Làm thế nào để tôi trả về một kết quả từ một chức năng?

Ví dụ:

Public Function test() As Integer
    return 1
End Function

Điều này đưa ra một lỗi biên dịch.

Làm thế nào để tôi thực hiện chức năng này trả về một số nguyên?

Đối với các kiểu trả về không phải đối tượng, bạn phải gán giá trị cho tên hàm của mình, như thế này:

Public Function test() As Integer
    test = 1
End Function

Ví dụ sử dụng:

Dim i As Integer
i = test()

Nếu hàm trả về một loại Đối tượng, thì bạn phải sử dụng Settừ khóa như thế này:

Public Function testRange() As Range
    Set testRange = Range("A1")
End Function

Ví dụ sử dụng:

Dim r As Range
Set r = testRange()

Lưu ý rằng việc gán giá trị trả về cho tên hàm không chấm dứt việc thực thi hàm của bạn. Nếu bạn muốn thoát khỏi chức năng, thì bạn cần phải nói rõ ràng Exit Function. Ví dụ:

Function test(ByVal justReturnOne As Boolean) As Integer
    If justReturnOne Then
        test = 1
        Exit Function
    End If
    'more code...
    test = 2
End Function

Tài liệu: http://msdn.microsoft.com/en-us/l Library / office / gg264233% 28v = office.14% 29.aspx

Các hàm VBA coi chính tên hàm là một loại biến. Vì vậy, thay vì sử dụng returncâu lệnh "", bạn chỉ cần nói:

test = 1

Mặc dù vậy, lưu ý rằng điều này không thoát ra khỏi chức năng. Bất kỳ mã nào sau câu lệnh này cũng sẽ được thực thi. Do đó, bạn có thể có nhiều câu lệnh gán gán các giá trị khác nhau testvà bất kể giá trị là gì khi bạn đạt đến cuối hàm sẽ là giá trị được trả về.

Chỉ cần đặt giá trị trả về cho tên hàm vẫn không hoàn toàn giống với câu lệnh Java (hoặc khác) return, bởi vì trong java, returnthoát khỏi hàm, như thế này:

public int test(int x) {
    if (x == 1) {
        return 1; // exits immediately
    }

    // still here? return 0 as default.
    return 0;
}

Trong VB, tương đương chính xác mất hai dòng nếu bạn không đặt giá trị trả về ở cuối hàm . Vì vậy, trong VB, hệ quả chính xác sẽ như thế này:

Public Function test(ByVal x As Integer) As Integer
    If x = 1 Then
        test = 1 ' does not exit immediately. You must manually terminate...
        Exit Function ' to exit
    End If

    ' Still here? return 0 as default.
    test = 0
    ' no need for an Exit Function because we're about to exit anyway.
End Function 

Vì đây là trường hợp, thật tuyệt khi biết rằng bạn có thể sử dụng biến trả về như bất kỳ biến nào khác trong phương thức. Như thế này:

Public Function test(ByVal x As Integer) As Integer

    test = x ' <-- set the return value

    If test <> 1 Then ' Test the currently set return value
        test = 0 ' Reset the return value to a *new* value
    End If

End Function 

Hoặc, ví dụ cực đoan về cách biến trả về hoạt động (nhưng không nhất thiết là một ví dụ hay về cách bạn thực sự nên viết mã). Đây là một ví dụ sẽ giúp bạn thức dậy vào ban đêm:

Public Function test(ByVal x As Integer) As Integer

    test = x ' <-- set the return value

    If test > 0 Then

        ' RECURSIVE CALL...WITH THE RETURN VALUE AS AN ARGUMENT,
        ' AND THE RESULT RESETTING THE RETURN VALUE.
        test = test(test - 1)

    End If

End Function

Đoạn mã dưới đây lưu trữ giá trị trả về vào biến retValvà sau đó MsgBoxcó thể được sử dụng để hiển thị giá trị:

Dim retVal As Integer
retVal = test()
Msgbox retVal