Thay thế chuỗi XSLT

Tôi thực sự không biết XSL nhưng tôi cần sửa mã này, tôi đã giảm nó để làm cho nó đơn giản hơn.
Tôi nhận được lỗi này

Hàm XSLT / XPath không hợp lệ

trên dòng này

<xsl:variable name="text" select="replace($text,'a','b')"/>

Đây là XSL

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:inm="http://www.inmagic.com/webpublisher/query" version="1.0">
    <xsl:output method="text" encoding="UTF-8" />

    <xsl:preserve-space elements="*" />
    <xsl:template match="text()" />

    <xsl:template match="mos">
        <xsl:apply-templates />

        <xsl:for-each select="mosObj">
          'Notes or subject' 
           <xsl:call-template
                name="rem-html">
                <xsl:with-param name="text" select="SBS_ABSTRACT" />
            </xsl:call-template>
        </xsl:for-each>
    </xsl:template>

    <xsl:template name="rem-html">
        <xsl:param name="text" />
        <xsl:variable name="text" select="replace($text, 'a', 'b')" />
    </xsl:template>
</xsl:stylesheet>

Bất cứ ai có thể cho tôi biết điều gì sai với nó?

replace không khả dụng cho XSLT 1.0.

Codesling có một mẫu để thay thế chuỗi mà bạn có thể sử dụng để thay thế cho hàm:

<xsl:template name="string-replace-all">
    <xsl:param name="text" />
    <xsl:param name="replace" />
    <xsl:param name="by" />
    <xsl:choose>
        <xsl:when test="$text = '' or $replace = ''or not($replace)" >
            <!-- Prevent this routine from hanging -->
            <xsl:value-of select="$text" />
        </xsl:when>
        <xsl:when test="contains($text, $replace)">
            <xsl:value-of select="substring-before($text,$replace)" />
            <xsl:value-of select="$by" />
            <xsl:call-template name="string-replace-all">
                <xsl:with-param name="text" select="substring-after($text,$replace)" />
                <xsl:with-param name="replace" select="$replace" />
                <xsl:with-param name="by" select="$by" />
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

được gọi là:

<xsl:variable name="newtext">
    <xsl:call-template name="string-replace-all">
        <xsl:with-param name="text" select="$text" />
        <xsl:with-param name="replace" select="a" />
        <xsl:with-param name="by" select="b" />
    </xsl:call-template>
</xsl:variable>

Mặt khác, nếu bạn thực sự chỉ cần thay thế một ký tự này bằng một ký tự khác, bạn có thể gọi translateký tự có chữ ký tương tự. Một cái gì đó như thế này sẽ hoạt động tốt:

<xsl:variable name="newtext" select="translate($text,'a','b')"/>

Ngoài ra, lưu ý, trong ví dụ này, tôi đã thay đổi tên biến thành "newtext", trong XSLT các biến là bất biến, vì vậy bạn không thể làm tương $foo = $footự như bạn đã làm trong mã gốc của mình.

Đây là hàm XSLT sẽ hoạt động tương tự như hàm String.Replace () của C #.

Mẫu này có 3 Tham số như bên dưới

text : - chuỗi chính của bạn

thay thế : - chuỗi mà bạn muốn thay thế

bởi : - chuỗi sẽ trả lời bằng chuỗi mới

Dưới đây là các mẫu

<xsl:template name="string-replace-all">
  <xsl:param name="text" />
  <xsl:param name="replace" />
  <xsl:param name="by" />
  <xsl:choose>
    <xsl:when test="contains($text, $replace)">
      <xsl:value-of select="substring-before($text,$replace)" />
      <xsl:value-of select="$by" />
      <xsl:call-template name="string-replace-all">
        <xsl:with-param name="text" select="substring-after($text,$replace)" />
        <xsl:with-param name="replace" select="$replace" />
        <xsl:with-param name="by" select="$by" />
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$text" />
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

Mẫu dưới đây cho thấy cách gọi nó

<xsl:variable name="myVariable ">
  <xsl:call-template name="string-replace-all">
    <xsl:with-param name="text" select="'This is a {old} text'" />
    <xsl:with-param name="replace" select="'{old}'" />
    <xsl:with-param name="by" select="'New'" />
  </xsl:call-template>
</xsl:variable>

Bạn cũng có thể tham khảo URL bên dưới để biết chi tiết.

Lưu ý: Trong trường hợp bạn muốn sử dụng thuật ngữ đã được đề cập cho các trường hợp bạn cần thay thế một số lượng lớn các trường hợp trong chuỗi nguồn (ví dụ: các dòng mới trong văn bản dài) thì khả năng cao là bạn sẽ gặp phải StackOverflowExceptionvì đệ quy gọi.

Tôi đã giải quyết vấn đề này nhờ vào kiểu nhúng Java tích hợp sẵn của Xalan (không có vẻ như thế nào trong Saxon ):

<xsl:stylesheet version="1.0" exclude-result-prefixes="xalan str"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xalan="http://xml.apache.org/xalan"
                xmlns:str="xalan://java.lang.String"
        >
...
<xsl:value-of select="str:replaceAll(
    str:new(text()),
    $search_string,
    $replace_string)"/>
...
</xsl:stylesheet>

Bạn có thể sử dụng mã sau khi bộ xử lý của bạn chạy trên .NET hoặc sử dụng MSXML (trái ngược với bộ xử lý dựa trên Java hoặc gốc khác). Nó sử dụng msxsl:script.

Đảm bảo thêm không gian tên xmlns:msxsl="urn:schemas-microsoft-com:xslt"vào gốc xsl:stylesheethoặc xsl:transformphần tử của bạn .

Ngoài ra, liên kết outletvới bất kỳ không gian tên nào bạn thích, chẳng hạn xmlns:outlet = "http://my.functions".

<msxsl:script implements-prefix="outlet" language="javascript">
function replace_str(str_text,str_replace,str_by)
{
     return str_text.replace(str_replace,str_by);
}
</msxsl:script>


<xsl:variable name="newtext" select="outlet:replace_str(string(@oldstring),'me','you')" />

Tôi tiếp tục đánh câu trả lời này. Nhưng không ai trong số họ liệt kê giải pháp dễ dàng nhất cho xsltproc (và có lẽ là hầu hết các bộ xử lý XSLT 1.0):

1. Thêm tên chuỗi exslt vào biểu định kiểu, tức là:

<xsl:stylesheet
  version="1.0"
  xmlns:str="http://exslt.org/strings"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

2. Sau đó sử dụng nó như:

<xsl:value-of select="str:replace(., ' ', '')"/>

Rouine khá tốt, tuy nhiên nó khiến ứng dụng của tôi bị treo, vì vậy tôi cần thêm trường hợp:

  <xsl:when test="$text = '' or $replace = ''or not($replace)" >
    <xsl:value-of select="$text" />
    <!-- Prevent thsi routine from hanging -->
  </xsl:when>

trước khi hàm được gọi đệ quy.

Tôi đã nhận được câu trả lời từ đây: Khi thử nghiệm treo trong một vòng lặp vô hạn

Cảm ơn bạn!