Làm thế nào để xóa nhiều bộ đệm trong Vim?

Giả sử tôi có nhiều tệp được mở dưới dạng bộ đệm trong Vim. Các tập tin có *.cpp, *.hvà một số *.xml. Tôi muốn đóng tất cả các tệp XML bằng :bd *.xml. Tuy nhiên, Vim không cho phép điều này (E93: Nhiều hơn một trận đấu ...).

Có cách nào để làm điều này?

Tái bút tôi biết điều đó :bd file1 file2 file3hoạt động. Vì vậy, bằng cách nào đó tôi có thể đánh giá *.xmlđể file1.xml file2.xml file3.xml?

Bạn có thể sử dụng <C-a>để hoàn thành tất cả các trận đấu. Vì vậy, nếu bạn gõ :bd *.xmlvà sau đó nhấn <C-a>, vim sẽ hoàn thành lệnh :bd file1.xml file2.xml file3.xml.

:3,5bd[elete]   

Sẽ xóa phạm vi bộ đệm từ 3 đến 5.

Bạn cũng có thể sử dụng cách sử dụng khác:

    :.,$-bd[elete]    " to delete buffers from the current one to last but one
    :%bd[elete]       " to delete all buffers

Bạn có thể sử dụng cái này.

:exe 'bd '. join(filter(map(copy(range(1, bufnr('$'))), 'bufname(v:val)'), 'v:val =~ "\.xml$"'), ' ')

Sẽ khá dễ dàng để thêm nó vào một lệnh.

function! s:BDExt(ext)
  let buffers = filter(range(1, bufnr('$')), 'buflisted(v:val) && bufname(v:val) =~ "\.'.a:ext.'$"')
  if empty(buffers) |throw "no *.".a:ext." buffer" | endif
  exe 'bd '.join(buffers, ' ')
endfunction

command! -nargs=1 BDExt :call s:BDExt(<f-args>)

Hãy thử tập lệnh bên dưới. Ví dụ là cho "txt", hãy thay đổi nó khi cần thiết, ví dụ: thành "xml". Bộ đệm đã sửa đổi không bị xóa. Nhấn \ bd để xóa bộ đệm.

map <Leader>bd :bufdo call <SID>DeleteBufferByExtension("txt")

function!  <SID>DeleteBufferByExtension(strExt)
   if (matchstr(bufname("%"), ".".a:strExt."$") == ".".a:strExt )
      if (! &modified)
         bd
      endif
   endif
endfunction

[Chỉnh sửa] Tương tự mà không có: bufdo (theo yêu cầu của Luc Hermitte, xem bình luận bên dưới)

map <Leader>bd :call <SID>DeleteBufferByExtension("txt")

function!  <SID>DeleteBufferByExtension(strExt)
   let s:bufNr = bufnr("$")
   while s:bufNr > 0
       if buflisted(s:bufNr)
           if (matchstr(bufname(s:bufNr), ".".a:strExt."$") == ".".a:strExt )
              if getbufvar(s:bufNr, '&modified') == 0
                 execute "bd ".s:bufNr
              endif
           endif
       endif
       let s:bufNr = s:bufNr-1
   endwhile
endfunction

Tôi cũng đã từng có nhu cầu về chức năng này. Đây là giải pháp tôi có trong vimrc của mình.

function! GetBufferList()
    return filter(range(1,bufnr('$')), 'buflisted(v:val)')
endfunction

function! GetMatchingBuffers(pattern)
    return filter(GetBufferList(), 'bufname(v:val) =~ a:pattern')
endfunction

function! WipeMatchingBuffers(pattern)
    let l:matchList = GetMatchingBuffers(a:pattern)

    let l:count = len(l:matchList)
    if l:count < 1
        echo 'No buffers found matching pattern ' . a:pattern
        return
    endif

    if l:count == 1
        let l:suffix = ''
    else
        let l:suffix = 's'
    endif

    exec 'bw ' . join(l:matchList, ' ')

    echo 'Wiped ' . l:count . ' buffer' . l:suffix . '.'
endfunction

command! -nargs=1 BW call WipeMatchingBuffers('<args>')

Bây giờ, tôi chỉ có thể làm :BW regex(ví dụ: :BW \.cpp$và xóa tất cả các bộ đệm phù hợp khớp với mẫu đó trong tên đường dẫn của chúng.

Nếu bạn muốn xóa thay vì xóa, tất nhiên bạn có thể thay thế exec 'bw ' . join(l:matchList, ' ')bằngexec 'bd ' . join(l:matchList, ' ')

Rất đơn giản: sử dụng :bd[elete]lệnh. Ví dụ: :bd[elete] buf#1 buf#5 buf#3sẽ xóa các bộ đệm 1, 3 và 5.

TABsẽ chỉ tự động hoàn thành một tệp cho bạn kể từ Vim 7.4.282
sử dụng <c-a>để tự động hoàn tất tất cả các tệp.

Bạn chỉ có thể sử dụng:

bd filetype

thì chỉ cần sử dụng <c-a>để tạo điều kiện hoàn thành tất cả các tệp đang mở của loại tệp được chỉ định.

ví dụ: bạn có 1.xml, 2.xml, 3.xml và 4.xml, bạn có thể làm:

bd xml

sau đó nhấn <c-a>

vim sẽ tự động hoàn thành cho bạn như sau:

bd 1.xml 2.xml 3.xml 4.xml

bạn chỉ cần nhấn enter để hoàn tất lệnh.

nếu bạn đã thực hiện các thay đổi đối với một trong các tệp được đề cập ở trên, hãy nhớ thực hiện:

bd! xml