Làm cách nào tôi có thể thực hiện tìm kiếm chuỗi ngược trong Excel mà không cần sử dụng VBA?

Tôi có một bảng tính Excel chứa danh sách các chuỗi. Mỗi chuỗi được tạo thành từ nhiều từ, nhưng số lượng từ trong mỗi chuỗi là khác nhau.

Sử dụng các hàm Excel tích hợp (không có VBA), có cách nào để tách từ cuối cùng trong mỗi chuỗi không?

Ví dụ:

  Bạn được phân loại là con người? -> con người?
Tiêu cực, tôi là một popsicle thịt -> popsicle
                  Aziz! Ánh sáng! -> Ánh sáng!

Cái này đã được thử nghiệm và hoạt động (dựa trên bài viết gốc của Brad):

=RIGHT(A1,LEN(A1)-FIND("|",SUBSTITUTE(A1," ","|",
     LEN(A1)-LEN(SUBSTITUTE(A1," ","")))))

Nếu chuỗi ban đầu của bạn có thể chứa một đường ống "|" ký tự, sau đó thay thế cả hai ở trên bằng một số ký tự khác sẽ không xuất hiện trong nguồn của bạn. (Tôi nghi ngờ bản gốc của Brad đã bị hỏng vì một ký tự không thể in được đã bị xóa trong bản dịch).

Phần thưởng: Cách thức hoạt động (từ phải sang trái):

LEN(A1)-LEN(SUBSTITUTE(A1," ",""))- Đếm số khoảng trắng trong chuỗi gốc
SUBSTITUTE(A1," ","|", ... )- Thay thế chỉ khoảng trắng cuối cùng bằng a |
FIND("|", ... )- Tìm vị trí tuyệt đối của vị trí được thay thế |(đó là khoảng trắng cuối cùng)
Right(A1,LEN(A1) - ... ))- Trả về tất cả các ký tự sau đó|

EDIT: để giải thích cho trường hợp văn bản nguồn không có khoảng trắng, hãy thêm phần sau vào đầu công thức:

=IF(ISERROR(FIND(" ",A1)),A1, ... )

làm toàn bộ công thức bây giờ:

=IF(ISERROR(FIND(" ",A1)),A1, RIGHT(A1,LEN(A1) - FIND("|",
    SUBSTITUTE(A1," ","|",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))))

Hoặc bạn có thể sử dụng =IF(COUNTIF(A1,"* *")cú pháp của phiên bản khác.

Khi chuỗi gốc có thể chứa một khoảng trắng ở vị trí cuối cùng, hãy thêm hàm trim trong khi đếm tất cả các khoảng trắng: Tạo hàm như sau:

=IF(ISERROR(FIND(" ",B2)),B2, RIGHT(B2,LEN(B2) - FIND("|",
    SUBSTITUTE(B2," ","|",LEN(TRIM(B2))-LEN(SUBSTITUTE(B2," ",""))))))

Đây là kỹ thuật tôi đã sử dụng rất thành công:

=TRIM(RIGHT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

Để có được từ đầu tiên trong một chuỗi, chỉ cần thay đổi từ PHẢI sang TRÁI

=TRIM(LEFT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

Ngoài ra, thay thế A1 bằng ô giữ văn bản.

Một phiên bản mạnh mẽ hơn của câu trả lời của Jerry:

=TRIM(RIGHT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(TRIM(A1))))

Nó hoạt động bất kể độ dài của chuỗi, khoảng trắng ở đầu hoặc cuối hoặc bất cứ thứ gì khác và nó vẫn khá ngắn và đơn giản.

Tôi đã tìm thấy cái này trên google, đã thử nghiệm trong Excel 2003 và nó hoạt động với tôi:

=IF(COUNTIF(A1,"* *"),RIGHT(A1,LEN(A1)-LOOKUP(LEN(A1),FIND(" ",A1,ROW(INDEX($A:$A,1,1):INDEX($A:$A,LEN(A1),1))))),A1)

[sửa] Tôi không có đủ đại diện để bình luận, vì vậy đây có vẻ là nơi tốt nhất ... Câu trả lời của BradC cũng không hoạt động với dấu cách hoặc ô trống ...
[chỉnh sửa lần 2] thực sự, nó không hoạt động cho một từ duy nhất ...

=RIGHT(TRIM(A1),LEN(TRIM(A1))-FIND(CHAR(7),SUBSTITUTE(" "&TRIM(A1)," ",CHAR(7),
LEN(TRIM(A1))-LEN(SUBSTITUTE(" "&TRIM(A1)," ",""))+1))+1)

Điều này rất mạnh mẽ - nó hoạt động cho các câu không có khoảng trắng, khoảng trắng ở đầu / cuối, nhiều khoảng trắng, nhiều khoảng trắng ở đầu / cuối ... và tôi đã sử dụng char (7) cho dấu phân cách thay vì thanh dọc "|" chỉ trong trường hợp đó là một mục văn bản mong muốn.

Điều này rất sạch sẽ và nhỏ gọn, và hoạt động tốt.

{=RIGHT(A1,LEN(A1)-MAX(IF(MID(A1,ROW(1:999),1)=" ",ROW(1:999),0)))}

Nó không lỗi bẫy không có khoảng trắng hoặc một từ, nhưng thật dễ dàng để thêm.

Chỉnh sửa:
Điều này xử lý các khoảng trắng ở cuối, từ đơn và các tình huống ô trống. Tôi chưa tìm được cách phá vỡ nó.

{=RIGHT(TRIM(A1),LEN(TRIM(A1))-MAX(IF(MID(TRIM(A1),ROW($1:$999),1)=" ",ROW($1:$999),0)))}

=RIGHT(A1,LEN(A1)-FIND("`*`",SUBSTITUTE(A1," ","`*`",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))) 

Để thêm vào câu trả lời của Jerry và Joe, nếu bạn muốn tìm văn bản TRƯỚC từ cuối cùng bạn có thể sử dụng:

=TRIM(LEFT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))))-LEN(TRIM(A1))))

Với 'Con mèo nhỏ của tôi' trong A1 sẽ dẫn đến 'Con nhỏ của tôi' (nơi Joe và Jerry sẽ tặng 'con mèo'

Theo cùng một cách mà Jerry và Joe cô lập từ cuối cùng, điều này sau đó chỉ cần đưa mọi thứ về bên trái của từ đó (sau đó cắt lại)

Hãy tưởng tượng chuỗi có thể được đảo ngược. Sau đó, nó thực sự dễ dàng. Thay vì làm việc trên chuỗi:

"My little cat" (1)

bạn làm việc với

"tac elttil yM" (2)

Với =LEFT(A1;FIND(" ";A1)-1)A2, bạn nhận được "My"với (1) và "tac"với (2), được đảo ngược "cat", từ cuối cùng trong (1).

Có một vài VBA xung quanh để đảo ngược một chuỗi. Tôi thích chức năng VBA công cộng ReverseString.

Cài đặt ở trên như mô tả. Sau đó, với chuỗi của bạn trong A1, ví dụ, "My little cat"và hàm này trong A2:

=ReverseString(LEFT(ReverseString(A1);IF(ISERROR(FIND(" ";A1));
  LEN(A1);(FIND(" ";ReverseString(A1))-1))))

bạn sẽ thấy "cat"trong A2.

Phương pháp trên giả định rằng các từ được phân tách bằng khoảng trắng. Các IFkhoản là dành cho các tế bào có chứa những từ đơn lẻ = không có khoảng trống trong phòng giam. Lưu ý: TRIMvà CLEANchuỗi gốc cũng hữu ích. Về nguyên tắc, nó đảo ngược toàn bộ chuỗi từ A1 và chỉ cần tìm khoảng trống đầu tiên trong chuỗi đảo ngược bên cạnh từ (đảo ngược) cuối cùng (nghĩa là "tac "). LEFTchọn từ này và một chuỗi đảo ngược khác hoàn nguyên thứ tự ban đầu của từ ( " cat"). Các -1vào cuối củaFIND câu lệnh xóa khoảng trống.

Ý tưởng là dễ dàng trích xuất từ ​​đầu tiên (!) Trong một chuỗi với LEFTvà FINDing khoảng trống đầu tiên. Tuy nhiên, đối với từ (!) Cuối cùng, RIGHThàm là lựa chọn sai khi bạn cố gắng làm điều đó vì không may TÌM không có cờ cho hướng bạn muốn phân tích chuỗi của mình.

Do đó, toàn bộ chuỗi chỉ đơn giản là đảo ngược. LEFTvà FINDhoạt động như bình thường nhưng chuỗi trích xuất bị đảo ngược. Nhưng anh ta không phải là vấn đề lớn khi bạn biết cách đảo ngược một chuỗi. Các ReverseStringtuyên bố đầu tiên trong công thức làm công việc này.

=LEFT(A1,FIND(IF(
 ISERROR(
  FIND("_",A1)
 ),A1,RIGHT(A1,
  LEN(A1)-FIND("~",
   SUBSTITUTE(A1,"_","~",
    LEN(A1)-LEN(SUBSTITUTE(A1,"_",""))
   )
  )
 )
),A1,1)-2)

Sao chép vào một cột, chọn cột đó và TRANG CHỦ> Chỉnh sửa> Tìm & Chọn, Thay thế:

Replace All.

Có một khoảng trống sau dấu hoa thị.

Tôi đã dịch sang PT-BR, vì tôi cũng cần điều này.

(Xin lưu ý rằng tôi đã thay đổi không gian thành \vì tôi chỉ cần tên tệp của chuỗi đường dẫn.)

=SE(ÉERRO(PROCURAR("\",A1)),A1,DIREITA(A1,NÚM.CARACT(A1)-PROCURAR("|", SUBSTITUIR(A1,"\","|",NÚM.CARACT(A1)-NÚM.CARACT(SUBSTITUIR(A1,"\",""))))))

Một cách khác để đạt được điều này là như dưới đây

=IF(ISERROR(TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14))))),TRIM(D14),TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14)))))

Tôi cũng có một nhiệm vụ như thế này và khi tôi hoàn thành, sử dụng phương pháp trên, một phương pháp mới đã xảy ra với tôi: Tại sao bạn không làm điều này:

1. Đảo ngược chuỗi ("chuỗi một" trở thành "eno gnumps").
2. Sử dụng Tìm cũ tốt (được mã hóa cứng từ trái sang phải).
3. Đảo ngược nó thành chuỗi có thể đọc được một lần nữa.

Làm thế nào để âm thanh này?