Vim: Tạo thư mục mẹ khi lưu

Nếu tôi gọi vim foo/bar/somefilenhưng foo/barchưa tồn tại, Vim sẽ từ chối lưu.

Tôi biết tôi có thể chuyển sang trình bao hoặc làm :!mkdir foo/bartừ Vim nhưng tôi lười :) Có cách nào để Vim làm điều đó tự động khi nó lưu bộ đệm không?

augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * if expand("<afile>")!~#'^\w\+:/' && !isdirectory(expand("%:h")) | execute "silent! !mkdir -p ".shellescape(expand('%:h'), 1) | redraw! | endif
augroup END

Lưu ý các điều kiện: expand("<afile>")!~#'^\w\+:/'sẽ ngăn vim tạo thư mục cho các tệp như ftp://*và !isdirectorysẽ ngăn cuộc gọi mkdir tốn kém.

Cập nhật : giải pháp sắp xếp tốt hơn cũng kiểm tra buftype không trống và sử dụng mkdir():

function s:MkNonExDir(file, buf)
    if empty(getbufvar(a:buf, '&buftype')) && a:file!~#'\v^\w+\:\/'
        let dir=fnamemodify(a:file, ':h')
        if !isdirectory(dir)
            call mkdir(dir, 'p')
        endif
    endif
endfunction
augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * :call s:MkNonExDir(expand('<afile>'), +expand('<abuf>'))
augroup END

Dựa trên các gợi ý cho câu hỏi của tôi, đây là những gì tôi đã kết thúc:

function WriteCreatingDirs()
    execute ':silent !mkdir -p %:h'
    write
endfunction
command W call WriteCreatingDirs()

Điều này xác định :Wlệnh. Lý tưởng nhất, tôi muốn có tất cả :w!, :wq, :wq!, :wallvv làm việc như nhau, nhưng tôi không chắc chắn nếu nó có thể không có cơ bản reimplementing tất cả chúng với chức năng tùy chỉnh.

Tôi đã thêm cái này vào ~ / .vimrc của tôi

cnoremap mk. !mkdir -p <c-r>=expand("%:h")<cr>/

Nếu tôi cần tạo thư mục mà tôi đang ở, tôi nhập :mk.và nó thay thế thư mục đó bằng "! Mkdir -p / path / to / my / file /" và cho phép tôi xem lại lệnh trước khi gọi nó.

Tôi đã :saveas!tạo thư mục nếu thiếu: https://github.com/henrik/dotfiles/commit/54cc9474b345332cf54cf25b51ddb8a9bd00a0bb

Mã này sẽ nhắc bạn tạo thư mục bằng :whoặc chỉ thực hiện với :w!:

augroup vimrc-auto-mkdir
  autocmd!
  autocmd BufWritePre * call s:auto_mkdir(expand('<afile>:p:h'), v:cmdbang)
  function! s:auto_mkdir(dir, force)
    if !isdirectory(a:dir)
          \   && (a:force
          \       || input("'" . a:dir . "' does not exist. Create? [y/N]") =~? '^y\%[es]$')
      call mkdir(iconv(a:dir, &encoding, &termencoding), 'p')
    endif
  endfunction
augroup END

Tôi nghĩ rằng tôi đã quản lý để làm điều này trong ba dòng, kết hợp những gì người khác đang nói về câu trả lời này.

Điều này dường như thực hiện thủ thuật:

if has("autocmd")
  autocmd BufWritePre * :silent !mkdir -p %:p:h
end

Nó cố gắng tạo thư mục tự động khi lưu bộ đệm. Nếu bất kỳ điều gì xấu xảy ra (tức là các vấn đề về quyền), nó sẽ chỉ đóng cửa và để tệp ghi không thành công.

Nếu bất kỳ ai nhìn thấy bất kỳ sai sót rõ ràng, xin vui lòng gửi một bình luận. Tôi không thành thạo vimscript.

CHỈNH SỬA: Ghi chú nhờ ZyX

• Điều này sẽ không hoạt động nếu các thư mục của bạn có khoảng trống trên chúng (dường như chúng không được thoát đúng cách hoặc một cái gì đó)
• Hoặc nếu bạn đang làm các tệp giả.
• Hoặc nếu bạn đang tìm nguồn vimrc của mình.
• Nhưng con trai, nó ngắn.