Làm cách nào để kiểm tra xem tệp thực thi có tồn tại trong% PATH% từ tệp lô cửa sổ hay không?

Tôi đang tìm một cách đơn giản để kiểm tra xem tệp thực thi có tồn tại trong biến môi trường PATH từ tệp lô Windows hay không.

Không được phép sử dụng các công cụ bên ngoài không do HĐH cung cấp. Phiên bản Windows tối thiểu được yêu cầu là Windows XP.

for %%X in (myExecutable.exe) do (set FOUND=%%~$PATH:X)
if defined FOUND ...

Nếu bạn cần điều này cho các tiện ích mở rộng khác nhau, chỉ cần lặp lại PATHEXT:

set FOUND=
for %%e in (%PATHEXT%) do (
  for %%X in (myExecutable%%e) do (
    if not defined FOUND (
      set FOUND=%%~$PATH:X
    )
  )
)

Có thể điều đó wherecũng đã tồn tại trên các phiên bản Windows cũ, nhưng tôi không có quyền truy cập vào một phiên bản, vì vậy tôi không thể nói. Trên máy của tôi, tính năng sau cũng hoạt động:

where myExecutable

và trả về với mã thoát khác 0 nếu không tìm thấy mã này. Tuy nhiên, trong một lô, bạn có thể cũng muốn chuyển hướng đầu ra NUL.

Ghi nhớ

Phân tích cú pháp trong .batcác tệp batch ( ) và trên dòng lệnh khác nhau (vì các tệp batch có %0- %9), vì vậy bạn phải tăng gấp đôi số %ở đó. Trên dòng lệnh, điều này không cần thiết, vì vậy chỉ cần các biến %X.

Windows Vista và các phiên bản mới hơn đi kèm với một chương trình được gọi là where.exetìm kiếm các chương trình trong đường dẫn. Nó hoạt động như thế này:

D:\>where notepad
C:\Windows\System32\notepad.exe
C:\Windows\notepad.exe

D:\>where where
C:\Windows\System32\where.exe

Để sử dụng trong một tệp hàng loạt, bạn có thể sử dụng công /qtắc, công tắc này chỉ thiết lập ERRORLEVELvà không tạo ra bất kỳ đầu ra nào.

where /q myapplication
IF ERRORLEVEL 1 (
    ECHO The application is missing. Ensure it is installed and placed in your PATH.
    EXIT /B
) ELSE (
    ECHO Application exists. Let's go!
)

Hoặc phiên bản viết tắt đơn giản (nhưng ít đọc hơn) in thông báo và thoát khỏi ứng dụng của bạn:

where /q myapplication || ECHO Cound not find app. && EXIT /B

Đây là một giải pháp đơn giản cố gắng chạy ứng dụng và xử lý mọi lỗi sau đó .

file.exe /?  2> NUL
IF NOT %ERRORLEVEL%==9009 ECHO file.exe exists in path

Mã lỗi 9009 thường có nghĩa là không tìm thấy tệp.

Nhược điểm duy nhất là nó file.exethực sự được thực thi nếu được tìm thấy (trong một số trường hợp là không thể giải thích được).

Điều này có thể được thực hiện thông qua thay thế tham số.

%~$PATH:1

Điều này trả về đường dẫn đầy đủ của tên tệp thực thi trong% 1, nếu không là một chuỗi trống.

Điều này không hoạt động với các biến do người dùng xác định. Vì vậy, nếu tên tệp thực thi không phải là một tham số cho tập lệnh của bạn, thì bạn cần một chương trình con. Ví dụ:

call :s_which app.exe
if not "%_path%" == "" (
  "%_path%"
)

goto :eof

:s_which
  setlocal
  endlocal & set _path=%~$PATH:1
  goto :eof

Xem http://ss64.com/nt/syntax-args.html

@echo off
set found=
set prog=cmd.exe
for %%i in (%path%) do if exist %%i\%prog% set found=%%i
echo "%found%"
if "%found%"=="" ....

Đôi khi giải pháp đơn giản này hoạt động, nơi bạn kiểm tra xem đầu ra có khớp với những gì bạn mong đợi hay không. Dòng đầu tiên chạy lệnh và lấy dòng cuối cùng của đầu ra tiêu chuẩn.

FOR /F "tokens=*" %%i in (' "xcopy /? 2> nul" ') do SET xcopyoutput=%%i
if "%xcopyoutput%"=="" echo xcopy not in path.

Nếu bạn đang tìm kiếm một cái gì đó giống như tôi trên thư mục khởi động, hãy chuyển đến thư mục. Ví dụ: tôi tìm kiếm exe trên thư mục khởi động và tôi sử dụng mã này như

@echo off
cd C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp
where /q program.exe
IF ERRORLEVEL 1 (
echo F | xcopy /Y /S /I /E "\\programsetup\programsetup.exe" 
"C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp\program.exe"
) ELSE (
ECHO Application exists. Let's go!
)

Sử dụng lệnh: powershell Test-Path "exe mà bạn đang tìm kiếm"

Nó sẽ trả về True nếu hiện tại của nó, ngược lại là False.

Đối với những người đang tìm kiếm một tùy chọn PowerShell. Bạn có thể sử dụng Get-Commandlệnh ghép ngắn để chuyển hai mục. Đầu tiên cung cấp vị trí dir hiện tại với .\tiền tố, sau đó chỉ cung cấp tên exe.

(Get-Command ".\notepad", "notepad" -ErrorAction Ignore -CommandType Application) -ne $null

Điều đó sẽ trả về true nếu được tìm thấy cục bộ hoặc trong các đường dẫn rộng của hệ thống.