Mẹo và thủ thuật của Vim và Ctags [đã đóng]

Tôi vừa cài đặt Ctags (để giúp phát triển C ++) với Vim của tôi (hay đúng hơn là gVim), và muốn tìm hiểu các lệnh, macro, phím tắt, mẹo ưa thích của bạn đi cùng với nó ...

Chia sẻ kho vũ khí tốt nhất của bạn. Những tiện ích Vim nào khác mà bạn muốn giới thiệu cho C ++ khi phát triển Vim?

EDIT Những tiện ích bổ sung nào khác mà bạn sẽ sử dụng cùng với Ctags?

EDIT2 Phiên bản gVim nào bạn sử dụng với thẻ? Liệu nó có làm cho một sự khác biệt?

EDIT3 Làm thế nào để bạn nâng cao kinh nghiệm lập trình cho cả các dự án lớn và nhỏ?

Ctrl+ ]- đi đến định nghĩa
Ctrl+ T- Nhảy trở lại từ định nghĩa.
Ctrl+ W Ctrl+ ]- Mở định nghĩa theo cách chia ngang

Thêm các dòng này trong vimrc
map <C-\> :tab split<CR>:exec("tag ".expand("<cword>"))<CR>
map <A-]> :vsp <CR>:exec("tag ".expand("<cword>"))<CR>

Ctrl+ \- Mở định nghĩa trong tab mới
Alt+ ]- Mở định nghĩa theo phân chia dọc

Sau khi các thẻ được tạo ra. Bạn có thể sử dụng các phím sau để gắn thẻ và gắn thẻ ngoài chức năng:

Ctrl+ Left MouseClick- Chuyển đến định nghĩa
Ctrl+ Right MouseClick- Quay trở lại từ định nghĩa

Một dòng luôn đi trong .vimrc của tôi:

set tags=./tags;/

Điều này sẽ tìm trong thư mục hiện tại cho "thẻ", và đưa cây về phía gốc cho đến khi tìm thấy. IOW, bạn có thể ở bất cứ đâu trong cây nguồn của bạn thay vì chỉ là gốc của nó.

Một plugin hữu ích khác để phát triển C là cscope Cũng giống như Ctags cho phép bạn chuyển sang định nghĩa, Cscope nhảy vào cuộc gọi chức năng .

Nếu bạn có cscope trong thư mục ~ / bin / của bạn, hãy thêm đoạn sau vào .vimrc của bạn và sử dụng g ^] để chuyển đến chức năng gọi (xem: help cscope).

if has("cscope")
    set csprg=~/bin/cscope
    set csto=0
    set cst
    set nocsverb
    " add any database in current directory
    if filereadable("cscope.out")
        cs add cscope.out
        " else add database pointed to by environment
    elseif $CSCOPE_DB != ""
        cs add $CSCOPE_DB
    endif
endif

Hầu như quên ... Cũng giống như ctags - bạn phải tạo (và cập nhật định kỳ) cơ sở dữ liệu. Tôi sử dụng đoạn script sau

select_files > cscope.files
ctags -L cscope.files
ctags -e -L cscope.files
cscope -ub -i cscope.files

Trong đó 'select_files' là một tập lệnh khác trích xuất danh sách các tệp C và tiêu đề từ Makefile. Bằng cách này, tôi chỉ lập chỉ mục các tập tin thực sự được sử dụng bởi dự án.

Bạn có thể thêm các thư mục để tra cứu ctags của bạn. Ví dụ: tôi có một chỉ mục ctags được xây dựng cho Qt4 và có cái này trong .vimrc của tôi:

set tags+=/usr/local/share/ctags/qt4

Tất cả những điều trên và ...

code_complete: hoàn thành tham số chức năng, đoạn mã và nhiều hơn nữa.

• http://www.vim.org/scripts/script.php?script_id=1764

taglist.vim: Trình duyệt mã nguồn (hỗ trợ C / C ++, java, perl, python, tcl, sql, php, v.v.)

• http://www.vim.org/scripts/script.php?script_id=273

Tôi sử dụng ALT-left và ALT-right để bật / đẩy từ / đến ngăn xếp thẻ.

" Alt-right/left to navigate forward/backward in the tags stack
map <M-Left> <C-T>
map <M-Right> <C-]>

Nếu bạn sử dụng hjklcho phong trào, bạn có thể lập bản đồ <M-h>và <M-l>thay vào đó.

Một số định nghĩa cùng tên

<C-w>g<C-]>mở định nghĩa trong một tách, nhưng cũng làm :tjumptheo định nghĩa hoặc, nếu có một số định nghĩa, trình bày cho bạn một danh sách các định nghĩa để lựa chọn.

Lệnh tôi đang sử dụng nhiều nhất là C-] nhảy đến định nghĩa của hàm dưới con trỏ. Bạn có thể sử dụng nó thường xuyên hơn để theo dõi nhiều cuộc gọi hơn. Sau đó, Co sẽ đưa bạn trở lại một cấp, Ci lại tiến sâu hơn.

Tôi đã tìm thấy taglist plug-in một cuốn sách phải có. Nó liệt kê tất cả các thẻ mà nó biết về (các tệp mà bạn đã mở) trong một cửa sổ riêng biệt và làm cho nó rất dễ dàng điều hướng các tệp lớn hơn.

Tôi sử dụng nó chủ yếu để phát triển Python, nhưng nó chỉ có thể tốt hơn cho C / C ++.

Tôi đã đóng gói các thao tác thẻ trong một plugin thử nghiệm của tôi.

Về phát triển C ++ trong vim, tôi đã trả lời ở đó : Tôi sử dụng bộ riêng của mình và một vài plugin khác.

Tôi đã điều chỉnh các plugin vim của mình trong hai năm để hỗ trợ dự án c ++ đủ lớn. Bạn có thể xem chúng.

Họ sử dụng ctags và cscsope.

http://www.vim.org/scripts/script.php?script_id=1638
http://www.vim.org/scripts/script.php?script_id=2507

Tôi đặt phần sau vào tệp .gvimrc của mình, tìm kiếm cây từ bất kỳ điểm nào cho tệp thẻ khi gvim bắt đầu:

function SetTags()
    let curdir = getcwd()

    while !filereadable("tags") && getcwd() != "/"
        cd ..
    endwhile

    if filereadable("tags")
        execute "set tags=" . getcwd() . "/tags"
    endif

    execute "cd " . curdir
endfunction

call SetTags()

Sau đó, tôi định kỳ tạo lại một tệp thẻ ở đầu cây nguồn của mình với một tập lệnh trông giống như:

#!/bin/bash

find . -regex ".*\.\(c\|h\|hpp\|cc\|cpp\)" -print | ctags --totals --recurse --extra="+qf" --fields="+i" -L -

Tôi sử dụng vim trong macos và các ctags ban đầu không hoạt động tốt, vì vậy tôi tải xuống mới nhất và cấu hình thực hiện cài đặt. Tôi cài đặt ctgas trong / usr / local / bin / ctags (để giữ bản gốc)

"taglist
let Tlist_Ctags_Cmd = "/usr/local/bin/ctags"
let Tlist_WinWidth = 50
map <leader>ta :TlistToggle<cr>
map <leader>bta :!/usr/local/bin/ctags -R .<CR>
set tags=tags;/
map <M-j> <C-]>
map <M-k> <C-T>

Tôi đã điều chỉnh chức năng tìm kiếm SetTags () ở trên (cần được thay thế bằng tương đương set tags+=./tags;/) để hoạt động cho cscope. Có vẻ để làm việc!

"cscope file-searching alternative
function SetCscope()
    let curdir = getcwd()

    while !filereadable("cscope.out") && getcwd() != "/"
            cd ..
                endwhile

    if filereadable("cscope.out")
            execute "cs add " . getcwd() . "/cscope.out"
                endif

    execute "cd " . curdir
    endfunction

call SetCscope()

Một lần lặp khác trên hàm SetCscope () ở trên. Điều đó đặt đường dẫn trước của cscope để có được các trận đấu mà không nằm trên đường dẫn trong đó "cscope.out" là:

function s:FindFile(file)
    let curdir = getcwd()
    let found = curdir
    while !filereadable(a:file) && found != "/"
        cd ..
        let found = getcwd()
    endwhile
    execute "cd " . curdir
    return found
endfunction

if has('cscope')    
    let $CSCOPE_DIR=s:FindFile("cscope.out")
    let $CSCOPE_DB=$CSCOPE_DIR."/cscope.out"
    if filereadable($CSCOPE_DB)
        cscope add $CSCOPE_DB $CSCOPE_DIR
    endif

    command -nargs=0 Cscope !cscope -ub -R &
endif