Làm thế nào để viết tập lệnh mong đợi để cài đặt mariadb?

Môi trường: centos7 + mariadb5.5.64.
Hãy để tôi hiển thị thông tin cài đặt trên màn hình khi chạy mysql_secure_installation.

# mysql_secure_installation

NOTE: RUNNING ALL PARTS OF THIS SCRIPT IS RECOMMENDED FOR ALL MariaDB
      SERVERS IN PRODUCTION USE!  PLEASE READ EACH STEP CAREFULLY!

In order to log into MariaDB to secure it, we'll need the current
password for the root user.  If you've just installed MariaDB, and
you haven't set the root password yet, the password will be blank,
so you should just press enter here.

Enter current password for root (enter for none): 
OK, successfully used password, moving on...

Setting the root password ensures that nobody can log into the MariaDB
root user without the proper authorisation.

Set root password? [Y/n] y
New password: 
Re-enter new password: 
Password updated successfully!
Reloading privilege tables..
 ... Success!


By default, a MariaDB installation has an anonymous user, allowing anyone
to log into MariaDB without having to have a user account created for
them.  This is intended only for testing, and to make the installation
go a bit smoother.  You should remove them before moving into a
production environment.

Remove anonymous users? [Y/n] y
 ... Success!

Normally, root should only be allowed to connect from 'localhost'.  This
ensures that someone cannot guess at the root password from the network.

Disallow root login remotely? [Y/n] y
 ... Success!

By default, MariaDB comes with a database named 'test' that anyone can
access.  This is also intended only for testing, and should be removed
before moving into a production environment.

Remove test database and access to it? [Y/n] y
 - Dropping test database...
 ... Success!
 - Removing privileges on test database...
 ... Success!

Reloading the privilege tables will ensure that all changes made so far
will take effect immediately.

Reload privilege tables now? [Y/n] y
 ... Success!

Cleaning up...

All done!  If you've completed all of the above steps, your MariaDB
installation should now be secure.

Thanks for using MariaDB!

Tôi viết một kịch bản tự động mong đợi để cài đặt mariadb.

  vim secure.exp
  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? [Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? [Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? [Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? [Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? [Y/n]" {send "y\r";exp_continue}
  }

Để thực hiện /usr/bin/expect secure.exp, tôi gặp lỗi:

spawn mysql_secure_installation
invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
          "Enter current password for root (enter for none): " {send "\r";exp_continue}
          "Set root password? [Y/n] " {send "y\r";exp..."
    (file "secure.exp" line 3)

Không có ích để viết như dưới đây:

  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? \\[Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? \\[Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? \\[Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? \\[Y/n]" {send "y\r";exp_continue}
  }

Lỗi tương tự:

invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_conti..."
    (file "secure.exp" line 3)

Làm thế nào để sửa tập lệnh exp của tôi?

Các tập lệnh này chờ để nhận đầu ra tùy chọn ( timeout -1có nghĩa là "không có thời gian chờ") và chúng có thể phân biệt các phản hồi khác nhau, vì nó được yêu cầu bởi yum installvà mysql_secure_installation. Với #!/bin/expect -fnhư shebang, các tập lệnh có thể được thực thi, khi chúng được đặt thành chmod +x.

A) Để bắt đầu, mariadb_yum.exp(yêu cầu suhoặc sudo):

#!/bin/expect -f
set timeout 30
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_yum.exp \[linux sudo password\]\n"
    exit 1
}
set USERNAME "[exec whoami]"
set PASSWORD [lindex $argv 0];

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/$USERNAME/mariadb_install.log"

spawn sudo yum -y install MariaDB-server
set yum_spawn_id $spawn_id

# On GCE it will never ask for a sudo password:
expect -ex "\[sudo\] password for $USERNAME: " {
   exp_send "$PASSWORD\r"
}

expect {
    # when the package was already installed
    -ex "Nothing to do" {
        send_user "package was already installed\n"
    }
    # when the package had been installed
    -ex "Complete!" {
        send_user "package had been installed\n"
    }
}

expect eof
close $yum_spawn_id
exit 0

B) Và sau đó mariadb_sec.exp(không yêu cầu sudo):

#!/bin/expect -f
set timeout 1
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_sec.exp \[mysql root password\]\n"
    exit 1
}
set PASSWORD [lindex $argv 0];

spawn mysql_secure_installation
set mysql_spawn_id $spawn_id

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/[exec whoami]/mariadb_install.log"

# when there is no password set, this probably should be "\r"
expect -ex "Enter current password for root (enter for none): "
exp_send "$PASSWORD\r"

expect {
    # await an eventual error message
    -ex "ERROR 1045" {
        send_user "\nMariaDB > An invalid root password had been provided.\n"
        close $mysql_spawn_id
        exit 1
    }
    # when there is a root password set
    -ex "Change the root password? \[Y/n\] " {
        exp_send "n\r"
    }
    # when there is no root password set (could not test this branch).
    -ex "Set root password? \[Y/n\] " {
        exp_send "Y\r"
        expect -ex "New password: "
        exp_send "$PASSWORD\r"
        expect -ex "Re-enter new password: "
        exp_send "$PASSWORD\r"
    }
}
expect -ex "Remove anonymous users? \[Y/n\] "
exp_send "Y\r"
expect -ex "Disallow root login remotely? \[Y/n\] "
exp_send "Y\r"
expect -ex "Remove test database and access to it? \[Y/n\] "
exp_send "Y\r"
expect -ex "Reload privilege tables now? \[Y/n\] "
exp_send "Y\r"

expect eof
close $mysql_spawn_id
exit 0

Đối với mục đích gỡ lỗi - hoặc để xác thực câu trả lời, người ta có thể chạy expectvới cấp độ nhật ký strace 4. Điều này có thể có uy tín như một nguồn có thể nhận được, khi nói đến việc viết expectcác kịch bản, vì nó hiển thị độc đáo những gì đang diễn ra và quan trọng nhất là theo thứ tự các sự việc xảy ra:

expect -c "strace 4" ./mariadb_yum.exp [linux sudo password]
expect -c "strace 4" ./mariadb_sec.exp [mysql root password]

Hướng dẫn set exp_internal 1có thể được sử dụng để có được đầu ra cho kết hợp regex.

Một nguồn có thể gây nhầm lẫn có thể là, nơi một người sinh ra các quy trình - vì người ta có thể sinh ra một số quy trình trên các máy chủ khác nhau, ví dụ. sshcục bộ và sau đó yumvà mysql_secure_installationtừ xa. Đã thêm vào $spawn_idkịch bản; closecuộc gọi dưới cùng có thể là dư thừa, vì nó đã có sẵn EOF(chỉ để hiển thị cách spawn& closequy trình):

Thanks for using MariaDB!
 1  close $mysql_spawn_id
 1  exit 0
 2  rename _close.pre_expect close

Kết luận: mariadb_sec.expKịch bản có thể có thể được cải thiện hơn nữa, ví dụ. lúc đầu không gửi mật khẩu và xem điều gì xảy ra - sau đó gửi mật khẩu ERROR 1045(khi mật khẩu đã được đặt trước đó). Có thể lưu lại giả định rằng người ta phải đặt mật khẩu khi máy chủ vừa được cài đặt (ngoại trừ việc yum reinstallmang lại kết quả tương tự). Chỉ không có thùng chứa CentOS trống để kiểm tra tất cả các trường hợp. Trừ khi chạy trong trình rootbao, việc chuyển cả hai loại mật khẩu vào một tập lệnh sẽ được yêu cầu để tự động hóa việc này từ khi cài đặt cho đến khi cài đặt sau.

Có lẽ đáng chú ý là trên GCE, sudosẽ không yêu cầu mật khẩu; thực sự có những khác biệt nhỏ dựa trên môi trường, vì những hình ảnh chứa CentOS này hoạt động khác nhau. Trong trường hợp như vậy (vì không có suhoặc phát hiện hình ảnh container tại chỗ), mariadb_yum.exptập lệnh có thể bị kẹt trong 30vài giây và sau đó tiếp tục.

Các nguồn có uy tín nhất mà tôi có thể cung cấp là expecthướng dẫn sử dụng, được viết bởi Don Libes @ NIST và hướng dẫn TCL / TK cho expect, cùng với đó là dự án SourceForge được gọi một cách tình cờ expect.

Không chỉ là dấu ngoặc vuông được sử dụng để thay thế lệnh, mà chúng còn đặc biệt cho các mẫu hình cầu .

Bạn có thể sử dụng công -exacttắc trong khi thoát dấu ngoặc vuông trong dấu ngoặc kép:

spawn mysql_secure_installation
expect {
    ...
    -exact "Set root password? \[Y/n\] " {send "y\r";exp_continue}
    ...
}

Hoặc sử dụng dấu ngoặc nhọn thay cho dấu ngoặc kép:

spawn mysql_secure_installation
expect {
    ...
    {Set root password? \[Y/n\] } {send "y\r";exp_continue}
    ...
}

FYI bạn có thể có tập lệnh mong đợi được tạo cho bạn bằng cách sử dụng autoexpect:

autoexpect ./mysql_secure_installation

Điều này sẽ tạo ra một kịch bản mong đợi được gọi script.exptrong thư mục làm việc hiện tại của bạn.