Có cách nào để lặp qua một biến bảng trong TSQL mà không cần sử dụng con trỏ không?

Giả sử tôi có biến bảng đơn giản sau:

declare @databases table
(
    DatabaseID    int,
    Name        varchar(15),   
    Server      varchar(15)
)
-- insert a bunch rows into @databases

Là khai báo và sử dụng một con trỏ tùy chọn duy nhất của tôi nếu tôi muốn lặp qua các hàng? Có cách nào khác không?

Trước hết, bạn nên chắc chắn rằng bạn cần lặp lại qua từng hàng - các hoạt động dựa trên tập hợp sẽ thực hiện nhanh hơn trong mọi trường hợp tôi có thể nghĩ và thường sẽ sử dụng mã đơn giản hơn.

Tùy thuộc vào dữ liệu của bạn, có thể lặp lại bằng cách sử dụng chỉ các SELECTcâu lệnh như dưới đây:

Declare @Id int

While (Select Count(*) From ATable Where Processed = 0) > 0
Begin
    Select Top 1 @Id = Id From ATable Where Processed = 0

    --Do some processing here

    Update ATable Set Processed = 1 Where Id = @Id 

End

Một cách khác là sử dụng bảng tạm thời:

Select *
Into   #Temp
From   ATable

Declare @Id int

While (Select Count(*) From #Temp) > 0
Begin

    Select Top 1 @Id = Id From #Temp

    --Do some processing here

    Delete #Temp Where Id = @Id

End

Tùy chọn bạn nên chọn thực sự phụ thuộc vào cấu trúc và khối lượng dữ liệu của bạn.

Lưu ý: Nếu bạn đang sử dụng SQL Server, bạn sẽ được phục vụ tốt hơn bằng cách sử dụng:

WHILE EXISTS(SELECT * FROM #Temp)

Sử dụng COUNTsẽ phải chạm vào từng hàng trong bảng, EXISTSchỉ cần chạm vào hàng đầu tiên (xem câu trả lời của Josef bên dưới).

Xin lưu ý, nếu bạn đang sử dụng SQL Server (2008 trở lên), các ví dụ có:

While (Select Count(*) From #Temp) > 0

Sẽ được phục vụ tốt hơn với

While EXISTS(SELECT * From #Temp)

Bá tước sẽ phải chạm vào từng hàng trong bảng, EXISTSchỉ cần chạm vào hàng đầu tiên.

Đây là cách tôi làm điều đó:

declare @RowNum int, @CustId nchar(5), @Name1 nchar(25)

select @CustId=MAX(USERID) FROM UserIDs     --start with the highest ID
Select @RowNum = Count(*) From UserIDs      --get total number of records
WHILE @RowNum > 0                          --loop until no more records
BEGIN   
    select @Name1 = username1 from UserIDs where USERID= @CustID    --get other info from that row
    print cast(@RowNum as char(12)) + ' ' + @CustId + ' ' + @Name1  --do whatever

    select top 1 @CustId=USERID from UserIDs where USERID < @CustID order by USERID desc--get the next one
    set @RowNum = @RowNum - 1                               --decrease count
END

Không có con trỏ, không có bảng tạm thời, không có cột thêm. Cột USERID phải là một số nguyên duy nhất, vì hầu hết các Khóa chính là.

Xác định bảng tạm thời của bạn như thế này -

declare @databases table
(
    RowID int not null identity(1,1) primary key,
    DatabaseID    int,
    Name        varchar(15),   
    Server      varchar(15)
)

-- insert a bunch rows into @databases

Sau đó làm điều này -

declare @i int
select @i = min(RowID) from @databases
declare @max int
select @max = max(RowID) from @databases

while @i <= @max begin
    select DatabaseID, Name, Server from @database where RowID = @i --do some stuff
    set @i = @i + 1
end

Đây là cách tôi sẽ làm điều đó:

Select Identity(int, 1,1) AS PK, DatabaseID
Into   #T
From   @databases

Declare @maxPK int;Select @maxPK = MAX(PK) From #T
Declare @pk int;Set @pk = 1

While @pk <= @maxPK
Begin

    -- Get one record
    Select DatabaseID, Name, Server
    From @databases
    Where DatabaseID = (Select DatabaseID From #T Where PK = @pk)

    --Do some processing here
    -- 

    Select @pk = @pk + 1
End

[Chỉnh sửa] Bởi vì tôi có thể bỏ qua từ "biến" khi lần đầu tiên đọc câu hỏi, đây là câu trả lời được cập nhật ...

declare @databases table
(
    PK            int IDENTITY(1,1), 
    DatabaseID    int,
    Name        varchar(15),   
    Server      varchar(15)
)
-- insert a bunch rows into @databases
--/*
INSERT INTO @databases (DatabaseID, Name, Server) SELECT 1,'MainDB', 'MyServer'
INSERT INTO @databases (DatabaseID, Name, Server) SELECT 1,'MyDB',   'MyServer2'
--*/

Declare @maxPK int;Select @maxPK = MAX(PK) From @databases
Declare @pk int;Set @pk = 1

While @pk <= @maxPK
Begin

    /* Get one record (you can read the values into some variables) */
    Select DatabaseID, Name, Server
    From @databases
    Where PK = @pk

    /* Do some processing here */
    /* ... */ 

    Select @pk = @pk + 1
End

Nếu bạn không có lựa chọn nào khác ngoài việc đi từng hàng, tạo một con trỏ FAST_FORWARD. Nó sẽ nhanh như việc xây dựng một vòng lặp while và dễ dàng hơn nhiều để duy trì trong một quãng đường dài.

FAST_FORWARD Chỉ định con trỏ FORWARD_ONLY, READ_ONLY với tối ưu hóa hiệu suất được bật. FAST_FORWARD không thể được chỉ định nếu SCROLL hoặc FOR_UPDATE cũng được chỉ định.

Một cách tiếp cận khác mà không phải thay đổi lược đồ của bạn hoặc sử dụng bảng tạm thời:

DECLARE @rowCount int = 0
  ,@currentRow int = 1
  ,@databaseID int
  ,@name varchar(15)
  ,@server varchar(15);

SELECT @rowCount = COUNT(*)
FROM @databases;

WHILE (@currentRow <= @rowCount)
BEGIN
  SELECT TOP 1
     @databaseID = rt.[DatabaseID]
    ,@name = rt.[Name]
    ,@server = rt.[Server]
  FROM (
    SELECT ROW_NUMBER() OVER (
        ORDER BY t.[DatabaseID], t.[Name], t.[Server]
       ) AS [RowNumber]
      ,t.[DatabaseID]
      ,t.[Name]
      ,t.[Server]
    FROM @databases t
  ) rt
  WHERE rt.[RowNumber] = @currentRow;

  EXEC [your_stored_procedure] @databaseID, @name, @server;

  SET @currentRow = @currentRow + 1;
END

Bạn có thể sử dụng một vòng lặp while:

While (Select Count(*) From #TempTable) > 0
Begin
    Insert Into @Databases...

    Delete From #TempTable Where x = x
End

Điều này sẽ hoạt động trong phiên bản SQL SERVER 2012.

declare @Rowcount int 
select @Rowcount=count(*) from AddressTable;

while( @Rowcount>0)
  begin 
 select @Rowcount=@Rowcount-1;
 SELECT * FROM AddressTable order by AddressId desc OFFSET @Rowcount ROWS FETCH NEXT 1 ROWS ONLY;
end 

Nhẹ, không phải tạo thêm bảng, nếu bạn có số nguyên IDtrên bảng

Declare @id int = 0, @anything nvarchar(max)
WHILE(1=1) BEGIN
  Select Top 1 @anything=[Anything],@id=@id+1 FROM Table WHERE ID>@id
  if(@@ROWCOUNT=0) break;

  --Process @anything

END

-- [PO_RollBackOnReject]  'FININV10532'
alter procedure PO_RollBackOnReject
@CaseID nvarchar(100)

AS
Begin
SELECT  *
INTO    #tmpTable
FROM   PO_InvoiceItems where CaseID = @CaseID

Declare @Id int
Declare @PO_No int
Declare @Current_Balance Money


While (Select ROW_NUMBER() OVER(ORDER BY PO_LineNo DESC) From #tmpTable) > 0
Begin
        Select Top 1 @Id = PO_LineNo, @Current_Balance = Current_Balance,
        @PO_No = PO_No
        From #Temp
        update PO_Details
        Set  Current_Balance = Current_Balance + @Current_Balance,
            Previous_App_Amount= Previous_App_Amount + @Current_Balance,
            Is_Processed = 0
        Where PO_LineNumber = @Id
        AND PO_No = @PO_No
        update PO_InvoiceItems
        Set IsVisible = 0,
        Is_Processed= 0
        ,Is_InProgress = 0 , 
        Is_Active = 0
        Where PO_LineNo = @Id
        AND PO_No = @PO_No
End
End

Tôi thực sự không thấy được lý do tại sao bạn cần phải sử dụng sự sợ hãi cursor. Nhưng đây là một tùy chọn khác nếu bạn đang sử dụng SQL Server phiên bản 2005/2008
Sử dụng đệ quy

declare @databases table
(
    DatabaseID    int,
    Name        varchar(15),   
    Server      varchar(15)
)

--; Insert records into @databases...

--; Recurse through @databases
;with DBs as (
    select * from @databases where DatabaseID = 1
    union all
    select A.* from @databases A 
        inner join DBs B on A.DatabaseID = B.DatabaseID + 1
)
select * from DBs

Tôi sẽ cung cấp giải pháp dựa trên tập hợp.

insert  @databases (DatabaseID, Name, Server)
select DatabaseID, Name, Server 
From ... (Use whatever query you would have used in the loop or cursor)

Điều này nhanh hơn nhiều so với bất kỳ kỹ thuật lặp và dễ viết và bảo trì hơn.

Tôi thích sử dụng Offset Fetch nếu bạn có một ID duy nhất, bạn có thể sắp xếp bảng của mình theo:

DECLARE @TableVariable (ID int, Name varchar(50));
DECLARE @RecordCount int;
SELECT @RecordCount = COUNT(*) FROM @TableVariable;

WHILE @RecordCount > 0
BEGIN
SELECT ID, Name FROM @TableVariable ORDER BY ID OFFSET @RecordCount - 1 FETCH NEXT 1 ROW;
SET @RecordCount = @RecordCount - 1;
END

Bằng cách này, tôi không cần thêm các trường vào bảng hoặc sử dụng chức năng cửa sổ.

Có thể sử dụng một con trỏ để làm điều này:

tạo hàm [dbo] .f_teste_loop trả về bảng @tabela (cod int, nome varchar (10)) khi bắt đầu

insert into @tabela values (1, 'verde');
insert into @tabela values (2, 'amarelo');
insert into @tabela values (3, 'azul');
insert into @tabela values (4, 'branco');

return;

kết thúc

tạo thủ tục [dbo]. [sp_teste_loop] khi bắt đầu

DECLARE @cod int, @nome varchar(10);

DECLARE curLoop CURSOR STATIC LOCAL 
FOR
SELECT  
    cod
   ,nome
FROM 
    dbo.f_teste_loop();

OPEN curLoop;

FETCH NEXT FROM curLoop
           INTO @cod, @nome;

WHILE (@@FETCH_STATUS = 0)
BEGIN
    PRINT @nome;

    FETCH NEXT FROM curLoop
           INTO @cod, @nome;
END

CLOSE curLoop;
DEALLOCATE curLoop;

kết thúc

Tôi đồng ý với bài viết trước rằng các hoạt động dựa trên tập hợp thường sẽ hoạt động tốt hơn, nhưng nếu bạn cần lặp lại các hàng ở đây thì cách tiếp cận tôi sẽ thực hiện:

1. Thêm một trường mới vào biến bảng của bạn (Bit loại dữ liệu, mặc định 0)
2. Chèn dữ liệu của bạn
3. Chọn Hàng 1 trên cùng trong đó fUsed = 0 (Lưu ý: fUsed là tên của trường trong bước 1)
4. Thực hiện bất kỳ xử lý nào bạn cần làm
5. Cập nhật bản ghi trong biến bảng của bạn bằng cách đặt fUsed = 1 cho bản ghi

6. Chọn bản ghi không sử dụng tiếp theo từ bảng và lặp lại quy trình

   DECLARE @databases TABLE  
   (  
       DatabaseID  int,  
       Name        varchar(15),     
       Server      varchar(15),   
       fUsed       BIT DEFAULT 0  
   ) 
   
   -- insert a bunch rows into @databases
   
   DECLARE @DBID INT
   
   SELECT TOP 1 @DBID = DatabaseID from @databases where fUsed = 0 
   
   WHILE @@ROWCOUNT <> 0 and @DBID IS NOT NULL  
   BEGIN  
       -- Perform your processing here  
   
       --Update the record to "used" 
   
       UPDATE @databases SET fUsed = 1 WHERE DatabaseID = @DBID  
   
       --Get the next record  
       SELECT TOP 1 @DBID = DatabaseID from @databases where fUsed = 0   
   END

Bước 1: Dưới đây chọn câu lệnh tạo một bảng tạm thời với số hàng duy nhất cho mỗi bản ghi.

select eno,ename,eaddress,mobno int,row_number() over(order by eno desc) as rno into #tmp_sri from emp 

Bước2: Khai báo các biến cần thiết

DECLARE @ROWNUMBER INT
DECLARE @ename varchar(100)

Bước 3: Lấy tổng số hàng từ bảng tạm thời

SELECT @ROWNUMBER = COUNT(*) FROM #tmp_sri
declare @rno int

Bước 4: Lặp lại bảng tạm thời dựa trên số hàng duy nhất tạo trong temp

while @rownumber>0
begin
  set @rno=@rownumber
  select @ename=ename from #tmp_sri where rno=@rno  **// You can take columns data from here as many as you want**
  set @rownumber=@rownumber-1
  print @ename **// instead of printing, you can write insert, update, delete statements**
end

Cách tiếp cận này chỉ yêu cầu một biến và không xóa bất kỳ hàng nào khỏi @database. Tôi biết có rất nhiều câu trả lời ở đây, nhưng tôi không thấy câu trả lời nào sử dụng MIN để lấy ID tiếp theo của bạn như thế này.

DECLARE @databases TABLE
(
    DatabaseID    int,
    Name        varchar(15),   
    Server      varchar(15)
)

-- insert a bunch rows into @databases

DECLARE @CurrID INT

SELECT @CurrID = MIN(DatabaseID)
FROM @databases

WHILE @CurrID IS NOT NULL
BEGIN

    -- Do stuff for @CurrID

    SELECT @CurrID = MIN(DatabaseID)
    FROM @databases
    WHERE DatabaseID > @CurrID

END

Đây là giải pháp của tôi, sử dụng một vòng lặp vô hạn, BREAKcâu lệnh và @@ROWCOUNThàm. Không có con trỏ hoặc bảng tạm thời là cần thiết và tôi chỉ cần viết một truy vấn để có được hàng tiếp theo trong @databasesbảng:

declare @databases table
(
    DatabaseID    int,
    [Name]        varchar(15),   
    [Server]      varchar(15)
);


-- Populate the [@databases] table with test data.
insert into @databases (DatabaseID, [Name], [Server])
select X.DatabaseID, X.[Name], X.[Server]
from (values 
    (1, 'Roger', 'ServerA'),
    (5, 'Suzy', 'ServerB'),
    (8675309, 'Jenny', 'TommyTutone')
) X (DatabaseID, [Name], [Server])


-- Create an infinite loop & ensure that a break condition is reached in the loop code.
declare @databaseId int;

while (1=1)
begin
    -- Get the next database ID.
    select top(1) @databaseId = DatabaseId 
    from @databases 
    where DatabaseId > isnull(@databaseId, 0);

    -- If no rows were found by the preceding SQL query, you're done; exit the WHILE loop.
    if (@@ROWCOUNT = 0) break;

    -- Otherwise, do whatever you need to do with the current [@databases] table row here.
    print 'Processing @databaseId #' + cast(@databaseId as varchar(50));
end

Đây là mã mà tôi đang sử dụng 2008 R2. Mã này tôi đang sử dụng là để xây dựng các chỉ mục trên các trường chính (SSNO & EMPR_NO) n tất cả các câu chuyện

if object_ID('tempdb..#a')is not NULL drop table #a

select 'IF EXISTS (SELECT name FROM sysindexes WHERE name ='+CHAR(39)+''+'IDX_'+COLUMN_NAME+'_'+SUBSTRING(table_name,5,len(table_name)-3)+char(39)+')' 
+' begin DROP INDEX [IDX_'+COLUMN_NAME+'_'+SUBSTRING(table_name,5,len(table_name)-3)+'] ON '+table_schema+'.'+table_name+' END Create index IDX_'+COLUMN_NAME+'_'+SUBSTRING(table_name,5,len(table_name)-3)+ ' on '+ table_schema+'.'+table_name+' ('+COLUMN_NAME+') '   'Field'
,ROW_NUMBER() over (order by table_NAMe) as  'ROWNMBR'
into #a
from INFORMATION_SCHEMA.COLUMNS
where (COLUMN_NAME like '%_SSNO_%' or COLUMN_NAME like'%_EMPR_NO_')
    and TABLE_SCHEMA='dbo'

declare @loopcntr int
declare @ROW int
declare @String nvarchar(1000)
set @loopcntr=(select count(*)  from #a)
set @ROW=1  

while (@ROW <= @loopcntr)
    begin
        select top 1 @String=a.Field 
        from #A a
        where a.ROWNMBR = @ROW
        execute sp_executesql @String
        set @ROW = @ROW + 1
    end 

SELECT @pk = @pk + 1

sẽ tốt hơn:

SET @pk += @pk

Tránh sử dụng CHỌN nếu bạn không tham chiếu các bảng chỉ là gán giá trị.