TSQL - Cách sử dụng GO bên trong khối BEGIN .. END?

Tôi đang tạo một tập lệnh để tự động di chuyển các thay đổi từ nhiều cơ sở dữ liệu phát triển sang dàn dựng / sản xuất. Về cơ bản, cần một loạt các kịch bản thay đổi và kết hợp chúng thành một tập lệnh duy nhất, gói mỗi tập lệnh trong một IF whatever BEGIN ... ENDcâu lệnh.

Tuy nhiên, một số tập lệnh yêu cầu một GOcâu lệnh để, chẳng hạn, trình phân tích cú pháp SQL biết về một cột mới sau khi nó được tạo.

ALTER TABLE dbo.EMPLOYEE 
ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO -- Necessary, or next line will generate "Unknown column:  EMP_IS_ADMIN"
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Tuy nhiên, khi tôi bọc nó trong một IFkhối:

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
    GO
    UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever
END

Nó không thành công vì tôi đang gửi một BEGINmà không có kết quả phù hợp END. Tuy nhiên, nếu tôi xóa GOnó, nó lại phàn nàn về một cột không xác định.

Có cách nào để tạo và cập nhật cùng một cột trong một IFkhối duy nhất không?

Tôi đã gặp vấn đề tương tự và cuối cùng đã giải quyết được nó bằng SET NOEXEC .

IF not whatever
BEGIN
    SET NOEXEC ON; 
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

SET NOEXEC OFF; 

GO không phải là SQL - nó chỉ đơn giản là một dấu phân tách hàng loạt được sử dụng trong một số công cụ MS SQL.

Nếu bạn không sử dụng điều đó, bạn cần đảm bảo các câu lệnh được thực thi riêng biệt - trong các lô khác nhau hoặc bằng cách sử dụng SQL động cho tập hợp (cảm ơn @gbn):

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL;

    EXEC ('UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever')
END

Bạn có thể thử sp_executesqltách nội dung giữa mỗi GOcâu lệnh thành một chuỗi riêng biệt để thực thi, như được minh họa trong ví dụ bên dưới. Ngoài ra, có một biến @statementNo để theo dõi câu lệnh nào đang được thực thi để dễ dàng gỡ lỗi khi xảy ra ngoại lệ. Số dòng sẽ liên quan đến phần đầu của số báo cáo có liên quan đã gây ra lỗi.

BEGIN TRAN

DECLARE @statementNo INT
BEGIN TRY
    IF 1=1
    BEGIN
        SET @statementNo = 1
        EXEC sp_executesql
            N'  ALTER TABLE dbo.EMPLOYEE
                    ADD COLUMN EMP_IS_ADMIN BIT NOT NULL'

        SET @statementNo = 2
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1'

        SET @statementNo = 3
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1x'
    END
END TRY
BEGIN CATCH
    PRINT 'Error occurred on line ' + cast(ERROR_LINE() as varchar(10)) 
       + ' of ' + 'statement # ' + cast(@statementNo as varchar(10)) 
       + ': ' + ERROR_MESSAGE()
    -- error occurred, so rollback the transaction
    ROLLBACK
END CATCH
-- if we were successful, we should still have a transaction, so commit it
IF @@TRANCOUNT > 0
    COMMIT

Bạn cũng có thể dễ dàng thực thi các câu lệnh nhiều dòng, như được minh họa trong ví dụ trên, bằng cách chỉ cần đặt chúng trong dấu ngoặc kép ( '). Đừng quên thoát khỏi bất kỳ dấu nháy đơn nào chứa bên trong chuỗi bằng dấu nháy kép ( '') khi tạo tập lệnh.

Cuối cùng, tôi đã làm cho nó hoạt động bằng cách thay thế mọi phiên bản GOtrên dòng riêng của nó bằng

END
GO

---Automatic replacement of GO keyword, need to recheck IF conditional:
IF whatever
BEGIN

Điều này rất thích hợp để gói mọi nhóm câu lệnh trong một chuỗi, nhưng vẫn còn xa lý tưởng. Nếu ai tìm thấy giải pháp tốt hơn, hãy đăng nó và tôi sẽ chấp nhận nó.

Bạn có thể đặt các câu lệnh bằng BEGIN và END thay vì GO ở giữa

IF COL_LENGTH('Employees','EMP_IS_ADMIN') IS NULL --Column does not exist
BEGIN
    BEGIN
        ALTER TABLE dbo.Employees ADD EMP_IS_ADMIN BIT
    END

    BEGIN
        UPDATE EMPLOYEES SET EMP_IS_ADMIN = 0
    END
END

(Đã thử nghiệm trên cơ sở dữ liệu Northwind)

Chỉnh sửa: (Có thể được thử nghiệm trên SQL2012)

Bạn có thể thử giải pháp này:

if exists(
SELECT...
)
BEGIN
PRINT 'NOT RUN'
RETURN
END

--if upper code not true

ALTER...
GO
UPDATE...
GO

Tôi đã sử dụng RAISERRORtrong quá khứ cho điều này

IF NOT whatever BEGIN
    RAISERROR('YOU''RE ALL SET, and sorry for the error!', 20, -1) WITH LOG
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Bạn có thể kết hợp câu lệnh a GOTOvà LABELđể bỏ qua mã, do đó giữ GOnguyên các từ khóa.