Làm cách nào để thay đổi con trỏ Vim trong chế độ Chèn / Thường?

Tôi muốn biết, nếu có thể, cách thay đổi con trỏ trong Vim (về màu sắc, hình dạng, v.v.) tùy thuộc vào chế độ bạn đang ở.

Tôi liên tục quên rằng tôi không ở chế độ chèn và bắt đầu nhập mã, điều này dẫn đến tất cả những điều điên rồ xảy ra. Sẽ rất hữu ích nếu có một số loại chỉ dẫn trực quan trên con trỏ.

Một tùy chọn phổ biến để chỉ ra việc chuyển sang và chuyển từ chế độ Chèn là bật / tắt cursorlinetùy chọn, tùy chọn này chịu trách nhiệm về việc dòng màn hình hiện tại có được đánh dấu hay không (xem :help cursorline):

:autocmd InsertEnter,InsertLeave * set cul!

Hay cách khác,

:autocmd InsertEnter * set cul
:autocmd InsertLeave * set nocul

Sửa đổi CursorLinenhóm tô sáng để thay đổi kiểu của dòng con trỏ theo ý thích của bạn (xem :help :highlightvà :help highlight-groups).

Phần sau hoạt động trong xterm, urxvt và các trình giả lập đầu cuối khác trên Linux; iTerm2 trên macOS; Git Bash với ConEmu trên Windows; và hơn thế nữa (xem bình luận):

let &t_SI = "\e[6 q"
let &t_EI = "\e[2 q"

" Optionally reset the cursor on start:
augroup myCmds
au!
autocmd VimEnter * silent !echo -ne "\e[2 q"
augroup END

Các tùy chọn khác (thay thế số sau \e[):

Ps = 0  -> blinking block.
Ps = 1  -> blinking block (default).
Ps = 2  -> steady block.
Ps = 3  -> blinking underline.
Ps = 4  -> steady underline.
Ps = 5  -> blinking bar (xterm).
Ps = 6  -> steady bar (xterm).

Khi bạn sử dụng tmux , điều quan trọng là phải sử dụng nó như vậy (không có \<Esc>Ptmux;lối thoát). tmux sẽ theo dõi hình dạng con trỏ chính xác khi bạn chuyển đổi cửa sổ / ngăn.

Nếu nó không hiệu quả với bạn, hãy thử đặt TERM=xterm-256colortrước khi bắt đầu tmux hoặc thêm cái này vào của bạn .tmux.conf( cảm ơn @Steven Lu ):

set -ga terminal-overrides ',*:Ss=\E[%p1%d q:Se=\E[2 q'

Nếu bạn đang sử dụng tmux và iTerm2 trên macOS , thao
tác sau sẽ thay đổi con trỏ từ một khối thành một con trỏ và đánh dấu dòng hiện tại

if exists('$TMUX')
  let &t_SI = "\<Esc>Ptmux;\<Esc>\<Esc>]50;CursorShape=1\x7\<Esc>\\"
  let &t_EI = "\<Esc>Ptmux;\<Esc>\<Esc>]50;CursorShape=0\x7\<Esc>\\"
else
  let &t_SI = "\<Esc>]50;CursorShape=1\x7"
  let &t_EI = "\<Esc>]50;CursorShape=0\x7"
endif
:autocmd InsertEnter * set cul
:autocmd InsertLeave * set nocul

tín dụng: https://gist.github.com/andyfowler/1195581

Để thay đổi hình dạng của con trỏ ở các chế độ khác nhau, bạn có thể thêm phần sau vào .vimrctệp của mình .

Đối với GNOME Terminal (phiên bản 2.26):

if has("autocmd")
  au InsertEnter * silent execute "!gconftool-2 --type string --set /apps/gnome-terminal/profiles/Default/cursor_shape ibeam"
  au InsertLeave * silent execute "!gconftool-2 --type string --set /apps/gnome-terminal/profiles/Default/cursor_shape block"
  au VimLeave * silent execute "!gconftool-2 --type string --set /apps/gnome-terminal/profiles/Default/cursor_shape ibeam"
endif

Nếu bạn sử dụng nhiều cấu hình trong GNOME Terminal, bạn có thể phải điều chỉnh cấu hình này cho phù hợp với cấu hình của mình.

Đối với Konsole trong KDE4:

let &t_SI = "\<Esc>]50;CursorShape=1\x7"
let &t_EI = "\<Esc>]50;CursorShape=0\x7"

Điều này hoạt động với nhiều tab và cửa sổ.

Xem thêm: “ Thay đổi hình dạng con trỏ ở các chế độ khác nhau ” trên Vim Tips Wiki .

Bạn có thể thử plugin vim ga cuối :

Trong chế độ chèn, hình dạng con trỏ thay đổi thành một thanh dọc mỏng. Trong chế độ thay thế, nó chuyển thành một gạch dưới. Khi trở về chế độ bình thường, nó sẽ trở lại hình dạng "khối" tiêu chuẩn.

Tôi thấy hữu ích khi chỉ nhấp nháy con trỏ trong chế độ Chèn và tĩnh ở các chế độ khác.

set guicursor+=n-v-c:blinkon0

Không chắc liệu có ai khác đang gặp phải sự chậm trễ sau khi nhấn Escphím để quay lại chế độ bình thường để hiển thị con trỏ khối hay không nhưng nếu vậy, đây cũng là cách tôi sửa nó.

Trên thực tế, tôi đang sử dụng iTerm2 và sử dụng Vim bên trong thiết bị đầu cuối của mình trên macOS. Và khi vào chế độ chèn, con trỏ vẫn là một khối và hơi khó hiểu khi bạn đang ở chế độ chèn hoặc chế độ bình thường.

Tôi muốn hiển thị một đường mảnh dưới dạng con trỏ khi ở chế độ chèn và quay lại chặn khi ở chế độ bình thường như MacVim. Và để làm như vậy, nó khá đơn giản, chỉ cần thêm nó vào .vimrctệp của tôi như được mô tả ở đây :

let &t_SI = "\<Esc>]50;CursorShape=1\x7"
let &t_SR = "\<Esc>]50;CursorShape=2\x7"
let &t_EI = "\<Esc>]50;CursorShape=0\x7"

Nhưng như bạn có thể thấy đã có độ trễ khi nhấn ESCđể thoát khỏi chế độ chèn trở lại chế độ bình thường và hiển thị lại khối dưới dạng con trỏ. Vì vậy, để khắc phục nó, tôi tìm thấy điều này:

set ttimeout
set ttimeoutlen=1
set listchars=tab:>-,trail:~,extends:>,precedes:<,space:.
set ttyfast

Và bây giờ nó hoạt động khá tốt như bạn có thể thấy:

Tôi hy vọng nó có thể giúp bất kỳ ai khác! 👻

Tôi không nghĩ điều này bổ sung nhiều vào câu trả lời mà những người khác đã cung cấp nhưng tôi muốn bằng cách nào đó tóm tắt mọi thứ ở một nơi và cũng có liên kết đến các tài liệu tham khảo có liên quan.

Đây là đoạn mã có liên quan từ của tôi .vimrctrông như thế nào:

    " Cursor appearance
    "
    " See also: [1]'ANSI Control Functions Summary', [2]DECSCUSR, [3]xterm+tmux
    "   entry in terminfo.src.
    " [1] https://www.vt100.net/docs/vt510-rm/chapter4.html
    " [2] https://invisible-island.net/xterm/ctlseqs/ctlseqs.html
    " [3] https://raw.githubusercontent.com/mirror/ncurses/master/misc/terminfo.src
    "
    " On:
    " - entered insert mode
    let &t_SI = "^[[5 q^[]12;Magenta\007" " blinking bar (Ss) in magenta (Cs)
    " - entered replace mode
    let &t_SR = "^[[0 q^[]12;Red\007" " blinking block (Ss) in red (Cs)
    " - leaving insert/replace mode
    let &t_EI = "^[[2 q^[]112\007" " terminal power-on style (Se) and colour (Cr)

Lưu ý: Các '^['ký tự thực sự là một ESCký tự điều khiển (trình tự thoát).

Điều này hoạt động bình thường trên xfce4-terminal:

thêm tập lệnh sau vào của bạn .vimrc

if has("autocmd")
  au InsertEnter * silent execute "!sed -i.bak -e 's/TERMINAL_CURSOR_SHAPE_BLOCK/TERMINAL_CURSOR_SHAPE_IBEAM/' ~/.config/xfce4/terminal/terminalrc"                                                                                          
  au InsertLeave * silent execute "!sed -i.bak -e 's/TERMINAL_CURSOR_SHAPE_IBEAM/TERMINAL_CURSOR_SHAPE_BLOCK/' ~/.config/xfce4/terminal/terminalrc"                                                                                          
  au VimLeave * silent execute "!sed -i.bak -e 's/TERMINAL_CURSOR_SHAPE_IBEAM/TERMINAL_CURSOR_SHAPE_BLOCK/' ~/.config/xfce4/terminal/terminalrc"  
endif

Tóm tắt: Như bạn đã biết xfce4-terminal giữ các tùy chọn trong .config/xfce4/terminal/terminalrctệp. Tập lệnh thay đổi TERMINAL_CURSOR_SHAPE_BLOCKthành TERMINAL_CURSOR_SHAPE_IBEAMkhi bạn đang ở chế độ chèn và quay lại chặn khi bạn rời khỏi chế độ chèn hoặc vim. Cảm thấy tự do để thay đổi IBEAMbất cứ điều gì bạn muốn ( BLOCK, IBEAMvà UNDERLINEcó sẵn).

Nếu bạn đang sử dụng phiên bản hiện đại của nvimvà bạn muốn đạt được điều này, bạn có thể tránh một số cách giải quyết ưa thích được liệt kê ở trên.

Các cài đặt dưới đây sẽ chuyển từ con trỏ khối ở chế độ bình thường, thay thế con trỏ gạch dưới sang con trỏ dòng trong chèn.

# ~/.tmux.conf
set -g default-terminal "screen-256color"
set -ga terminal-overrides ",*256col*:Tc"
set -ga terminal-overrides '*:Ss=\E[%p1%d q:Se=\E[ q',w

" ~/.vimrc
" Sets cursor styles
" Block in normal, line in insert, underline in replace
set guicursor=n-v-c-sm:block,i-ci-ve:ver25-Cursor,r-cr-o:hor20

Tôi đã quản lý để làm cho điều này hoạt động với các cài đặt sau được lấy từ hai nguồn này.

tui-con trỏ-hình dạng

guicursor

Tôi thường đặt chế độ vim hiện tại trên dòng trạng thái, trong số những thứ khác. Nếu bạn tìm kiếm sự đơn giản, bạn chỉ có thể đặt thông tin này vào dòng trạng thái .

Tuy nhiên, thông thường những điều thực sự điên rồ sẽ xảy ra khi bạn chán nản khóa mũ và đang ở chế độ lệnh (vì hjkl bây giờ là HJKL - chỉ cần J và K là đủ để khiến bạn sởn tóc gáy khi không hiểu chuyện gì đang xảy ra. Làm a :h Jvà :h Kđể xem ý tôi là gì). Chỉ cần cẩn thận với phím caps lock và bạn sẽ luôn ổn IMO.