Dim wkbkdestination As Workbook
Dim destsheet As Worksheet

For Each ThisWorkSheet In wkbkorigin.Worksheets 
    'this throws subscript out of range if there is not a sheet in the destination 
    'workbook that has the same name as the current sheet in the origin workbook.
    Set destsheet = wkbkdestination.Worksheets(ThisWorkSheet.Name) 
Next

Về cơ bản, tôi lặp qua tất cả các trang tính trong sổ làm việc gốc, sau đó đặt destsheettrong sổ làm việc đích thành trang tính có cùng tên với trang hiện được lặp lại trong sổ làm việc gốc.

Làm cách nào để kiểm tra xem trang tính đó có tồn tại không? Cái gì đó như:

If wkbkdestination.Worksheets(ThisWorkSheet.Name) Then 

Một số người không thích cách tiếp cận này vì sử dụng xử lý lỗi "không phù hợp", nhưng tôi nghĩ nó được coi là chấp nhận được trong VBA ... Một cách tiếp cận thay thế là lặp lại tất cả các trang tính cho đến khi bạn tìm thấy một kết quả phù hợp.

Function WorksheetExists(shtName As String, Optional wb As Workbook) As Boolean
    Dim sht As Worksheet

    If wb Is Nothing Then Set wb = ThisWorkbook
    On Error Resume Next
    Set sht = wb.Sheets(shtName)
    On Error GoTo 0
    WorksheetExists = Not sht Is Nothing
End Function

Nếu bạn đặc biệt quan tâm đến trang tính, bạn có thể sử dụng lệnh gọi Đánh giá đơn giản:

Function WorksheetExists(sName As String) As Boolean
    WorksheetExists = Evaluate("ISREF('" & sName & "'!A1)")
End Function

Bạn không cần xử lý lỗi để thực hiện điều này. Tất cả những gì bạn phải làm là lặp lại tất cả các Trang tính và kiểm tra xem tên được chỉ định có tồn tại hay không:

For i = 1 To Worksheets.Count
    If Worksheets(i).Name = "MySheet" Then
        exists = True
    End If
Next i

If Not exists Then
    Worksheets.Add.Name = "MySheet"
End If

Vì việc kiểm tra các thành viên của bộ sưu tập là một vấn đề chung, đây là phiên bản tóm tắt của câu trả lời của Tim:

Hàm chứa (objCollection dưới dạng đối tượng, strName dưới dạng chuỗi) dưới dạng Boolean
    Dim o as Object
    Khi có lỗi Tiếp tục tiếp theo
    đặt o = objCollection (strName)
    Chứa = (Err.Number = 0)
    Err.Clear
 Kết thúc chức năng

Chức năng này có thể được sử dụng với bất kỳ bộ sưu tập như đối tượng ( Shapes, Range, Names, Workbooks, vv).

Để kiểm tra sự tồn tại của một trang tính, hãy sử dụng If Contains(Sheets, "SheetName") ...

Đã sửa: Không xử lý lỗi:

Function CheckIfSheetExists(SheetName As String) As Boolean
      CheckIfSheetExists = False
      For Each WS In Worksheets
        If SheetName = WS.name Then
          CheckIfSheetExists = True
          Exit Function
        End If
      Next WS
End Function

Trong trường hợp bất kỳ ai muốn tránh VBA và kiểm tra xem một trang tính có tồn tại hoàn toàn trong một công thức ô hay không, thì có thể sử dụng hàm ISREFvà INDIRECT:

=ISREF(INDIRECT("SheetName!A1"))

Điều này sẽ trả về TRUEnếu sổ làm việc chứa một trang tính được gọi SheetNamevà FALSEnếu không.

Tôi đã viết cái này:

Function sheetExist(sSheet As String) As Boolean
On Error Resume Next
sheetExist = (ActiveWorkbook.Sheets(sSheet).Index > 0)
End Function

Giải pháp của tôi trông giống Tims nhưng cũng hoạt động trong trường hợp không phải trang tính - biểu đồ

Public Function SheetExists(strSheetName As String, Optional wbWorkbook As Workbook) As Boolean
    If wbWorkbook Is Nothing Then Set wbWorkbook = ActiveWorkbook 'or ThisWorkbook - whichever appropriate
    Dim obj As Object
    On Error GoTo HandleError
    Set obj = wbWorkbook.Sheets(strSheetName)
    SheetExists = True
    Exit Function
HandleError:
    SheetExists = False
End Function

.

Đặt thử nghiệm vào một chức năng và bạn sẽ có thể sử dụng lại nó và bạn có khả năng đọc mã tốt hơn.

KHÔNG sử dụng "Khi Lỗi Tiếp tục Tiếp theo" vì nó có thể xung đột với phần khác của mã của bạn.

Sub DoesTheSheetExists()
    If SheetExist("SheetName") Then
        Debug.Print "The Sheet Exists"
    Else
        Debug.Print "The Sheet Does NOT Exists"
    End If
End Sub

Function SheetExist(strSheetName As String) As Boolean
    Dim i As Integer

    For i = 1 To Worksheets.Count
        If Worksheets(i).Name = strSheetName Then
            SheetExist = True
            Exit Function
        End If
    Next i
End Function

Đã trễ nhiều năm, nhưng tôi chỉ cần làm điều này và không thích bất kỳ giải pháp nào được đăng ... Vì vậy, tôi đã tạo ra một giải pháp, tất cả là nhờ phép thuật của (cử chỉ tay cầu vồng SpongeBob) "Đánh giá ()"!

Evaluate("IsError(" & vSheetName & "!1:1)")

Trả về TRUE nếu Trang tính KHÔNG tồn tại; FALSE nếu trang tính KHÔNG tồn tại. Bạn có thể thay thế bất kỳ phạm vi nào bạn muốn cho "1: 1", nhưng tôi khuyên bạn không nên sử dụng một ô duy nhất, vì nếu nó chứa lỗi (ví dụ: # N / A), nó sẽ trả về True.

wsExistsChức năng nhỏ gọn _{^{( không phụ thuộc vào Xử lý lỗi!)}}

Đây là một hàm ngắn và đơn giản không dựa vào xử lý lỗi để xác định xem trang tính có tồn tại hay không ( và được khai báo đúng cách để hoạt động trong mọi tình huống!)

Function wsExists(wsName As String) As Boolean
    Dim ws: For Each ws In Sheets
    wsExists = (wsName = ws.Name): If wsExists Then Exit Function
    Next ws
End Function

Cách sử dụng ví dụ:

Ví dụ sau thêm một trang tính mới có tên myNewSheet, nếu nó chưa tồn tại:

If Not wsExists("myNewSheet") Then Sheets.Add.Name = "myNewSheet"

Thêm thông tin:

• MSDN: For Each… NextTuyên bố (VBA)
• MSDN: ExitTuyên bố (VBA)
• MSDN: Toán tử so sánh (VBA)

Tại sao không chỉ sử dụng một vòng lặp nhỏ để xác định xem trang tính được đặt tên có tồn tại hay không? Giả sử bạn đang tìm kiếm một Trang tính có tên "Sheet1" trong sổ làm việc hiện đang mở.

Dim wb as Workbook
Dim ws as Worksheet

Set wb = ActiveWorkbook

For Each ws in wb.Worksheets

    if ws.Name = "Sheet1" then
        'Do something here
    End if

Next

Nếu bạn là người yêu thích WorksheetFunction.hoặc bạn làm việc từ một quốc gia không sử dụng tiếng Anh với Excel không phải tiếng Anh, đây là một giải pháp tốt, hoạt động:

WorksheetFunction.IsErr(Evaluate("'" & wsName & "'!A1"))

Hoặc trong một chức năng như thế này:

Function WorksheetExists(sName As String) As Boolean
    WorksheetExists = Not WorksheetFunction.IsErr(Evaluate("'" & sName & "'!A1"))
End Function

Public Function WorkSheetExists(ByVal strName As String) As Boolean
   On Error Resume Next
   WorkSheetExists = Not Worksheets(strName) Is Nothing
End Function

sub test_sheet()

 If Not WorkSheetExists("SheetName") Then
 MsgBox "Not available"
Else MsgBox "Available"
End If

End Sub

    For Each Sheet In Worksheets
    If UCase(Sheet.Name) = "TEMP" Then
    'Your Code when the match is True
        Application.DisplayAlerts = False
        Sheet.Delete
        Application.DisplayAlerts = True
    '-----------------------------------
    End If
Next Sheet

Thay đổi "Dữ liệu" thành bất kỳ tên trang tính nào bạn đang kiểm tra ...

On Error Resume Next 

Set DataSheet = Sheets("Data")

If DataSheet Is Nothing Then

     Sheets.Add(after:=ActiveSheet).Name = "Data"
     ''or whatever alternate code you want to execute''
End If

On Error GoTo 0

Không nghi ngờ gì rằng chức năng trên có thể hoạt động, tôi vừa kết thúc với đoạn mã sau hoạt động khá tốt:

Sub Sheet_exist ()
On Error Resume Next
If Sheets("" & Range("Sheet_Name") & "") Is Nothing Then
    MsgBox "doesnt exist"
Else
    MsgBox "exist"
End if
End sub

Lưu ý: Sheets_Namelà nơi tôi yêu cầu người dùng nhập tên, vì vậy tên này có thể không giống với bạn.

Tôi đã làm một điều khác: xóa một trang tính chỉ khi nó tồn tại - không gặp lỗi nếu nó không:

Excel.DisplayAlerts = False 
Dim WS
For Each WS In Excel.Worksheets
    If WS.name = "Sheet2" Then
        Excel.sheets("Sheet2").Delete
        Exit For
    End If
Next
Excel.DisplayAlerts = True

Tôi đã nghĩ ra một cách dễ dàng để làm điều đó, nhưng tôi không tạo phụ đề mới cho nó. Thay vào đó, tôi chỉ "chạy kiểm tra" trong sub mà tôi đang làm việc. Giả sử tên trang tính mà chúng tôi đang tìm là "Sheet_Exist" và chúng tôi chỉ muốn kích hoạt nó nếu tìm thấy:

Dim SheetCounter As Integer

SheetCounter = 1

Do Until Sheets(SheetCounter).Name = "Sheet_Exist" Or SheetCounter = Sheets.Count + 1
 SheetCounter = SheetCounter +1
Loop
If SheetCounter < Sheets.Count + 1 Then
 Sheets("Sheet_Exist").Activate
Else
 MsgBox("Worksheet ""Sheet_Exist"" was NOT found")
End If

Tôi cũng đã thêm một cửa sổ bật lên khi trang tính không tồn tại.

Tôi biết đó là một bài viết cũ, nhưng đây là một giải pháp đơn giản khác nhanh chóng.

Public Function worksheetExists(ByVal wb As Workbook, ByVal sheetNameStr As String) As Boolean

On Error Resume Next
worksheetExists = (wb.Worksheets(sheetNameStr).Name <> "")
Err.Clear: On Error GoTo 0

End Function

Ngắn gọn và sạch sẽ:

Function IsSheet(n$) As Boolean
    IsSheet = Not IsError(Evaluate(n & "!a1"))
End Function

Tôi thực sự có một cách đơn giản để kiểm tra xem trang tính có tồn tại hay không và sau đó thực hiện một số hướng dẫn:

Trong trường hợp của tôi, tôi muốn xóa trang tính và sau đó tạo lại cùng một trang tính có cùng tên nhưng mã bị gián đoạn nếu chương trình không thể xóa trang tính vì nó đã bị xóa

Sub Foo ()

    Application.DisplayAlerts = False

    On Error GoTo instructions
    Sheets("NAME OF THE SHEET").Delete

    instructions:

    Sheets.Add After:=Sheets(Sheets.Count)
    ActiveSheet.Name = "NAME OF THE SHEET"

End Sub