Tập lệnh hủy tất cả các kết nối đến cơ sở dữ liệu (Hơn RESTRICTED_USER ROLLBACK)

Tôi có một cơ sở dữ liệu phát triển triển khai lại thường xuyên từ dự án Cơ sở dữ liệu Visual Studio (thông qua TFS Auto Build).

Đôi khi khi tôi chạy bản dựng, tôi gặp lỗi này:

ALTER DATABASE failed because a lock could not be placed on database 'MyDB'. Try again later.  
ALTER DATABASE statement failed.  
Cannot drop database "MyDB" because it is currently in use.  

Tôi đã thử điều này:

ALTER DATABASE MyDB SET RESTRICTED_USER WITH ROLLBACK IMMEDIATE

nhưng tôi vẫn không thể bỏ cơ sở dữ liệu. (Tôi đoán là hầu hết các nhà phát triển đều có dboquyền truy cập.)

Tôi có thể tự chạy SP_WHOvà bắt đầu tắt các kết nối, nhưng tôi cần một cách tự động để thực hiện việc này trong quá trình xây dựng tự động. (Mặc dù lần này kết nối của tôi là người duy nhất trên db tôi đang cố gắng thả.)

Có một kịch bản có thể bỏ cơ sở dữ liệu của tôi bất kể ai được kết nối?

Đã cập nhật

Dành cho MS SQL Server 2012 trở lên

USE [master];

DECLARE @kill varchar(8000) = '';  
SELECT @kill = @kill + 'kill ' + CONVERT(varchar(5), session_id) + ';'  
FROM sys.dm_exec_sessions
WHERE database_id  = db_id('MyDB')

EXEC(@kill);

Đối với MS SQL Server 2000, 2005, 2008

USE master;

DECLARE @kill varchar(8000); SET @kill = '';  
SELECT @kill = @kill + 'kill ' + CONVERT(varchar(5), spid) + ';'  
FROM master..sysprocesses  
WHERE dbid = db_id('MyDB')

EXEC(@kill); 

USE master
GO
ALTER DATABASE database_name
SET OFFLINE WITH ROLLBACK IMMEDIATE
GO

Tham chiếu: http://msdn.microsoft.com/en-us/l Library / bb522682% 28v = sql.105% 29.aspx

Bạn có thể lấy tập lệnh mà SSMS cung cấp bằng cách thực hiện như sau:

1. Nhấp chuột phải vào cơ sở dữ liệu trong SSMS và chọn xóa
2. Trong hộp thoại, chọn hộp kiểm cho "Đóng kết nối hiện có."
3. Nhấp vào nút Script ở đầu hộp thoại.

Kịch bản sẽ trông giống như thế này:

USE [master]
GO
ALTER DATABASE [YourDatabaseName] SET  SINGLE_USER WITH ROLLBACK IMMEDIATE
GO
USE [master]
GO
DROP DATABASE [YourDatabaseName]
GO

Ít ai biết: câu lệnh GO sql có thể lấy một số nguyên cho số lần lặp lại lệnh trước đó.

Vì vậy, nếu bạn:

ALTER DATABASE [DATABASENAME] SET SINGLE_USER
GO

Sau đó:

USE [DATABASENAME]
GO 2000

Điều này sẽ lặp lại lệnh USE 2000 lần, buộc bế tắc trên tất cả các kết nối khác và sở hữu kết nối duy nhất. (Cung cấp quyền truy cập duy nhất cho cửa sổ truy vấn của bạn để làm như bạn muốn.)

Theo kinh nghiệm của tôi, việc sử dụng SINGLE_USER hầu hết mọi lúc, tuy nhiên, người ta nên cẩn thận: Tôi đã trải qua những dịp mà trong thời gian tôi bắt đầu lệnh SINGLE_USER và khi nó kết thúc ... rõ ràng là một 'người dùng' khác đã nhận được SINGLE_USER truy cập, không phải tôi. Nếu điều đó xảy ra, bạn đang trong một công việc khó khăn khi cố gắng lấy lại quyền truy cập vào cơ sở dữ liệu (trong trường hợp của tôi, đó là một dịch vụ cụ thể chạy cho một phần mềm có cơ sở dữ liệu SQL có quyền truy cập SINGLE_USER trước khi tôi làm). Những gì tôi nghĩ nên là cách đáng tin cậy nhất (không thể xác minh cho nó, nhưng nó là những gì tôi sẽ kiểm tra trong những ngày tới), thực sự là:
- Các dịch vụ dừng có thể ảnh hưởng truy cập của bạn (nếu có)
- sử dụng tập lệnh 'kill' ở trên để đóng tất cả các kết nối
- đặt cơ sở dữ liệu thành single_user ngay sau đó
- sau đó thực hiện khôi phục

Tập lệnh cực kỳ hiệu quả của Matthew được cập nhật để sử dụng DMV dm_exec_sments, thay thế bảng hệ thống sys Processes không dùng nữa:

USE [master];
GO

DECLARE @Kill VARCHAR(8000) = '';

SELECT
    @Kill = @Kill + 'kill ' + CONVERT(VARCHAR(5), session_id) + ';'
FROM
    sys.dm_exec_sessions
WHERE
    database_id = DB_ID('<YourDB>');

EXEC sys.sp_executesql @Kill;

Thay thế bằng vòng lặp WHILE (nếu bạn muốn xử lý bất kỳ hoạt động nào khác trên mỗi lần thực hiện):

USE [master];
GO

DECLARE @DatabaseID SMALLINT = DB_ID(N'<YourDB>');    
DECLARE @SQL NVARCHAR(10);

WHILE EXISTS ( SELECT
                1
               FROM
                sys.dm_exec_sessions
               WHERE
                database_id = @DatabaseID )    
    BEGIN;
        SET @SQL = (
                    SELECT TOP 1
                        N'kill ' + CAST(session_id AS NVARCHAR(5)) + ';'
                    FROM
                        sys.dm_exec_sessions
                    WHERE
                        database_id = @DatabaseID
                   );
        EXEC sys.sp_executesql @SQL;
    END;

Câu trả lời được chấp nhận có một nhược điểm là nó không xem xét rằng cơ sở dữ liệu có thể bị khóa bởi một kết nối đang thực hiện một truy vấn liên quan đến các bảng trong cơ sở dữ liệu khác với cơ sở dữ liệu được kết nối.

Đây có thể là trường hợp nếu phiên bản máy chủ có nhiều cơ sở dữ liệu và truy vấn trực tiếp hoặc gián tiếp (ví dụ: thông qua từ đồng nghĩa) sử dụng các bảng trong nhiều hơn một cơ sở dữ liệu, v.v.

Do đó, tôi thấy rằng đôi khi tốt hơn là sử dụng syslockinfo để tìm các kết nối để hủy.

Do đó, đề xuất của tôi sẽ là sử dụng biến thể dưới đây của câu trả lời được chấp nhận từ AlexK:

USE [master];

DECLARE @kill varchar(8000) = '';  
SELECT @kill = @kill + 'kill ' + CONVERT(varchar(5), req_spid) + ';'  
FROM master.dbo.syslockinfo
WHERE rsc_type = 2
AND rsc_dbid  = db_id('MyDB')

EXEC(@kill);

Bạn nên cẩn thận về các ngoại lệ trong quá trình tiêu diệt. Vì vậy, bạn có thể sử dụng tập lệnh này:

USE master;
GO
 DECLARE @kill varchar(max) = '';
 SELECT @kill = @kill + 'BEGIN TRY KILL ' + CONVERT(varchar(5), spid) + ';' + ' END TRY BEGIN CATCH END CATCH ;' FROM master..sysprocesses 
EXEC (@kill)

@AlexK đã viết một câu trả lời tuyệt vời . Tôi chỉ muốn thêm hai xu của tôi. Mã dưới đây hoàn toàn dựa trên câu trả lời của @ AlexK, điểm khác biệt là bạn có thể chỉ định người dùng và thời gian kể từ đợt cuối cùng được thực thi (lưu ý rằng mã sử dụng sys.dm_exec_simes thay vì master..sys process):

DECLARE @kill varchar(8000);
set @kill =''
select @kill = @kill + 'kill ' +  CONVERT(varchar(5), session_id) + ';' from sys.dm_exec_sessions 
where login_name = 'usrDBTest'
and datediff(hh,login_time,getdate()) > 1
--and session_id in (311,266)    
exec(@kill)

Trong ví dụ này, chỉ có quá trình người dùng usrDBTest mà đợt cuối cùng được thực hiện hơn 1 giờ trước sẽ bị giết.

Bạn có thể sử dụng Con trỏ như thế:

USE master
GO

DECLARE @SQL AS VARCHAR(255)
DECLARE @SPID AS SMALLINT
DECLARE @Database AS VARCHAR(500)
SET @Database = 'AdventureWorks2016CTP3'

DECLARE Murderer CURSOR FOR
SELECT spid FROM sys.sysprocesses WHERE DB_NAME(dbid) = @Database

OPEN Murderer

FETCH NEXT FROM Murderer INTO @SPID
WHILE @@FETCH_STATUS = 0

    BEGIN
    SET @SQL = 'Kill ' + CAST(@SPID AS VARCHAR(10)) + ';'
    EXEC (@SQL)
    PRINT  ' Process ' + CAST(@SPID AS VARCHAR(10)) +' has been killed'
    FETCH NEXT FROM Murderer INTO @SPID
    END 

CLOSE Murderer
DEALLOCATE Murderer

Tôi đã viết về điều đó trong blog của tôi ở đây: http://www.pigeonsql.com/single-post/2016/12/13/Kill-all-connections-on-DB-by-Coder

SELECT
    spid,
    sp.[status],
    loginame [Login],
    hostname, 
    blocked BlkBy,
    sd.name DBName, 
    cmd Command,
    cpu CPUTime,
    memusage Memory,
    physical_io DiskIO,
    lastwaittype LastWaitType,
    [program_name] ProgramName,
    last_batch LastBatch,
    login_time LoginTime,
    'kill ' + CAST(spid as varchar(10)) as 'Kill Command'
FROM master.dbo.sysprocesses sp 
JOIN master.dbo.sysdatabases sd ON sp.dbid = sd.dbid
WHERE sd.name NOT IN ('master', 'model', 'msdb') 
--AND sd.name = 'db_name' 
--AND hostname like 'hostname1%' 
--AND loginame like 'username1%'
ORDER BY spid

/* If a service connects continously. You can automatically execute kill process then run your script:
DECLARE @sqlcommand nvarchar (500)
SELECT @sqlcommand = 'kill ' + CAST(spid as varchar(10))
FROM master.dbo.sysprocesses sp 
JOIN master.dbo.sysdatabases sd ON sp.dbid = sd.dbid
WHERE sd.name NOT IN ('master', 'model', 'msdb') 
--AND sd.name = 'db_name' 
--AND hostname like 'hostname1%' 
--AND loginame like 'username1%'
--SELECT @sqlcommand
EXEC sp_executesql @sqlcommand
*/

Tôi đã thử nghiệm thành công với mã đơn giản dưới đây

USE [master]
GO
ALTER DATABASE [YourDatabaseName] SET SINGLE_USER WITH ROLLBACK IMMEDIATE
GO