CMake & CTest: thực hiện thử nghiệm không tạo thử nghiệm

Tôi đang thử CTest trong CMake để tự động chạy một số thử nghiệm của mình bằng make testtarget. Vấn đề là CMake không "hiểu" rằng bài kiểm tra tôi sẵn sàng chạy phải được xây dựng vì nó là một phần của dự án.

Vì vậy, tôi đang tìm cách xác định rõ ràng sự phụ thuộc này.

Có thể cho là một lỗi trong CMake (đã được theo dõi trước đây ở đây ) khiến điều này không hoạt động tốt. Một cách giải quyết là làm như sau:

add_test(TestName ExeName)
add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND}
                  DEPENDS ExeName)

Sau đó, bạn có thể chạy make checkvà nó sẽ biên dịch và chạy thử nghiệm. Nếu bạn có một số bài kiểm tra, thì bạn sẽ phải sử dụng DEPENDS exe1 exe2 exe3 ...trong dòng trên.

Thực ra có một cách để sử dụng make test. Bạn cần phải xác định việc xây dựng tệp thực thi thử nghiệm là một trong các thử nghiệm và sau đó thêm các phụ thuộc giữa các thử nghiệm. Đó là:

ADD_TEST(ctest_build_test_code
         "${CMAKE_COMMAND}" --build ${CMAKE_BINARY_DIR} --target test_code)
ADD_TEST(ctest_run_test_code test_code)
SET_TESTS_PROPERTIES(ctest_run_test_code
                     PROPERTIES DEPENDS ctest_build_test_code)

Tôi sử dụng một biến thể của câu trả lời richq. Ở cấp cao nhất CMakeLists.txt, tôi thêm một mục tiêu tùy chỉnh build_and_test, để xây dựng và chạy tất cả các thử nghiệm:

find_package(GTest)
if (GTEST_FOUND)
    enable_testing()
    add_custom_target(build_and_test ${CMAKE_CTEST_COMMAND} -V)
    add_subdirectory(test)
endif()

Trong các CMakeLists.txttệp dự án con khác nhau bên dưới test/, tôi thêm từng tệp thực thi thử nghiệm dưới dạng phụ thuộc của build_and_test:

include_directories(${CMAKE_SOURCE_DIR}/src/proj1)
include_directories(${GTEST_INCLUDE_DIRS})
add_executable(proj1_test proj1_test.cpp)
target_link_libraries(proj1_test ${GTEST_BOTH_LIBRARIES} pthread)
add_test(proj1_test proj1_test)
add_dependencies(build_and_test proj1_test)

Với cách tiếp cận này, tôi chỉ cần make build_and_testthay vì make test(hoặc make all test) và nó có lợi ích là chỉ xây dựng mã thử nghiệm (và các phụ thuộc của nó). Thật tiếc khi tôi không thể sử dụng tên mục tiêu test. Trong trường hợp của tôi, nó không quá tệ vì tôi có một tập lệnh cấp cao nhất thực hiện gỡ lỗi và phát hành (và biên dịch chéo) các bản dựng bằng cách gọi cmakevà sau đó make, và nó được dịch testsang build_and_test.

Rõ ràng, nội dung GTest không bắt buộc. Tôi chỉ tình cờ sử dụng / thích Google Test và muốn chia sẻ một ví dụ hoàn chỉnh về việc sử dụng nó với CMake / CTest. IMHO, cách tiếp cận này cũng có lợi ích là cho phép tôi sử dụng ctest -V, hiển thị kết quả Kiểm tra của Google trong khi các bài kiểm tra chạy:

1: Running main() from gtest_main.cc
1: [==========] Running 1 test from 1 test case.
1: [----------] Global test environment set-up.
1: [----------] 1 test from proj1
1: [ RUN      ] proj1.dummy
1: [       OK ] proj1.dummy (0 ms)
1: [----------] 1 test from proj1 (1 ms total)
1:
1: [----------] Global test environment tear-down
1: [==========] 1 test from 1 test case ran. (1 ms total)
1: [  PASSED  ] 1 test.
1/2 Test #1: proj1_test .......................   Passed    0.03 sec

Nếu bạn đang cố gắng mô phỏng make check, bạn có thể thấy mục nhập wiki này hữu ích:

http://www.cmake.org/Wiki/CMakeEmulateMakeCheck

Tôi vừa kiểm tra xem nó có thành công không (CMake 2.8.10).

Tự cứu mình khỏi đau đầu:

make all test

Hoạt động hiệu quả đối với tôi và sẽ xây dựng các phụ thuộc trước khi chạy thử nghiệm. Với mức độ đơn giản của điều này, nó gần như làm cho make testchức năng gốc trở nên thuận tiện vì nó cung cấp cho bạn tùy chọn chạy các thử nghiệm biên dịch cuối cùng ngay cả khi mã của bạn bị hỏng.

Nếu bạn đang sử dụng CMake> = 3.7, thì cách tiếp cận được khuyến nghị là sử dụng đồ đạc :

add_executable(test test.cpp)
add_test(test_build
  "${CMAKE_COMMAND}"
  --build "${CMAKE_BINARY_DIR}"
  --config "$<CONFIG>"
  --target test
)
set_tests_properties(test_build PROPERTIES FIXTURES_SETUP    test_fixture)
add_test(test test)
set_tests_properties(test       PROPERTIES FIXTURES_REQUIRED test_fixture)

Điều này thực hiện như sau:

• Thêm một testmục tiêu thực thi được xây dựng từtest.cpp
• Thêm một test_build"bài kiểm tra" chạy Cmake để xây dựng mục tiêutest
• Đánh dấu test_buildbài kiểm tra là một nhiệm vụ thiết lập của vật cố địnhtest_fixture
• Thêm một testbài kiểm tra chỉ chạy testtệp thực thi
• Đánh dấu testbài kiểm tra cần cố định test_fixture.

Vì vậy, mỗi khi testchạy thử nghiệm test_build, trước tiên nó sẽ chạy thử nghiệm , điều này sẽ xây dựng tệp thực thi cần thiết.

Đây là những gì tôi đã đúc kết ra và đã được sử dụng:

set(${PROJECT_NAME}_TESTS a b c)

enable_testing()
add_custom_target(all_tests)
foreach(test ${${PROJECT_NAME}_TESTS})
        add_executable(${test} EXCLUDE_FROM_ALL ${test}.cc)
        add_test(NAME ${test} COMMAND $<TARGET_FILE:${test}>)
        add_dependencies(all_tests ${test})
endforeach(test)

build_command(CTEST_CUSTOM_PRE_TEST TARGET all_tests)
string(CONFIGURE \"@CTEST_CUSTOM_PRE_TEST@\" CTEST_CUSTOM_PRE_TEST_QUOTED ESCAPE_QUOTES)
file(WRITE "${CMAKE_BINARY_DIR}/CTestCustom.cmake" "set(CTEST_CUSTOM_PRE_TEST ${CTEST_CUSTOM_PRE_TEST_QUOTED})" "\n")

YMMV

Câu trả lời của Derrick, được đơn giản hóa và nhận xét:

# It is impossible to make target "test" depend on "all":
# https://gitlab.kitware.com/cmake/cmake/-/issues/8774
# Set a magic variable in a magic file that tells ctest
# to invoke the generator once before running the tests:
file(WRITE "${CMAKE_BINARY_DIR}/CTestCustom.cmake"
    "set(CTEST_CUSTOM_PRE_TEST ${CMAKE_MAKE_PROGRAM})\n"
)

Nó không hoàn toàn chính xác, vì nó không giải quyết được vấn đề đồng thời khi chạy ninja all test, trong trường hợp bất kỳ ai làm điều đó. Ngược lại, bởi vì bây giờ, bạn có hai quy trình ninja.

(Ftr, tôi cũng đã chia sẻ giải pháp này ở đây .)

Tất cả các câu trả lời trên đều hoàn hảo. Nhưng thực ra CMake sử dụng CTest làm công cụ kiểm tra, vì vậy phương pháp tiêu chuẩn (tôi nghĩ là như vậy) để thực hiện sứ mệnh là:

enable_testing ()
add_test (TestName TestCommand)
add_test (TestName2 AnotherTestCommand)

Sau đó chạy cmake và thực hiện để xây dựng các mục tiêu. Sau đó, bạn có thể chạy thử nghiệm hoặc chỉ chạy

ctest

bạn sẽ nhận được kết quả. Điều này được thử nghiệm theo CMake 2.8.

Kiểm tra chi tiết tại: http://cmake.org/Wiki/CMake/Testing_With_CTest#Simple_Testing

Tất cả các câu trả lời đều tốt, nhưng chúng ngụ ý vi phạm truyền thống chạy kiểm tra bằng lệnh make test. Tôi đã thực hiện thủ thuật này:

add_test(NAME <mytest>
WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
COMMAND sh -c "make <mytarget>; $<TARGET_FILE:<mytarget>>")

Điều này có nghĩa là kiểm tra bao gồm xây dựng (tùy chọn) và chạy mục tiêu thực thi.