Làm cách nào để tạo một tệp bó chấm dứt khi gặp lỗi?

Tôi có một tệp bó gọi các tệp thực thi giống nhau với các tham số khác nhau. Làm cách nào để khiến nó chấm dứt ngay lập tức nếu một trong các cuộc gọi trả về mã lỗi ở bất kỳ cấp độ nào?

Về cơ bản, tôi muốn tương đương với MSBuild ContinueOnError=false.

Kiểm tra errorleveltrong một ifcâu lệnh và sau đó exit /b(chỉ thoát tệp b atch, không phải toàn bộ quá trình cmd.exe) cho các giá trị khác 0.

same-executable-over-and-over.exe /with different "parameters"
if %errorlevel% neq 0 exit /b %errorlevel%

Nếu bạn muốn giá trị của errorlevel lan truyền bên ngoài tệp bó của bạn

if %errorlevel% neq 0 exit /b %errorlevel%

nhưng nếu điều này là bên trong fornó sẽ có một chút khó khăn. Bạn sẽ cần một cái gì đó giống như:

setlocal enabledelayedexpansion
for %%f in (C:\Windows\*) do (
    same-executable-over-and-over.exe /with different "parameters"
    if !errorlevel! neq 0 exit /b !errorlevel!
)

Chỉnh sửa: Bạn phải kiểm tra lỗi sau mỗi lệnh. Không có kiểu cấu trúc "on error goto" toàn cầu trong lô cmd.exe / lệnh.com. Tôi cũng đã cập nhật mã của mình cho mỗi CodeMonkey , mặc dù tôi chưa bao giờ gặp phải lỗi âm bản trong bất kỳ vụ hack hàng loạt nào trên XP hoặc Vista.

Thêm || goto :labelvào mỗi dòng, và sau đó xác định a :label.

Ví dụ: tạo tệp .cmd này:

@echo off

echo Starting very complicated batch file...
ping -invalid-arg || goto :error
echo OH noes, this shouldn't have succeeded.
goto :EOF

:error
echo Failed with error #%errorlevel%.
exit /b %errorlevel%

Xem thêm câu hỏi về việc thoát khỏi chương trình con tập tin hàng loạt .

Ngắn nhất:

command || exit /b

Nếu bạn cần, bạn có thể đặt mã thoát:

command || exit /b 666

Và bạn cũng có thể đăng nhập:

command || echo ERROR && exit /b

Một bản cập nhật nhỏ, bạn nên thay đổi các kiểm tra cho "if errorlevel 1" thành ...

IF %ERRORLEVEL% NEQ 0 

Điều này là do trên XP, bạn có thể nhận được các số âm là lỗi. 0 = không có vấn đề, bất cứ điều gì khác là một vấn đề.

Và hãy ghi nhớ cách DOS xử lý các bài kiểm tra "IF ERRORLEVEL". Nó sẽ trả về true nếu số bạn đang kiểm tra là số đó hoặc cao hơn, vì vậy nếu bạn đang tìm kiếm các số lỗi cụ thể, bạn cần bắt đầu với 255 và làm việc xuống.

Đây là một chương trình polyglot cho BASH và Windows CMD chạy một loạt các lệnh và thoát ra nếu bất kỳ lỗi nào trong số chúng bị lỗi:

#!/bin/bash 2> nul

:; set -o errexit
:; function goto() { return $?; }

command 1 || goto :error

command 2 || goto :error

command 3 || goto :error

:; exit 0
exit /b 0

:error
exit /b %errorlevel%

Tôi đã sử dụng loại điều này trong quá khứ cho một kịch bản tích hợp liên tục nhiều nền tảng .

Tôi thích hình thức lệnh OR, vì tôi thấy chúng dễ đọc nhất (trái ngược với việc có if sau mỗi lệnh). Tuy nhiên, cách làm ngây thơ này, command || exit /b %ERRORLEVEL%là sai .

Điều này là do lô mở rộng các biến khi một dòng được đọc lần đầu, thay vì khi chúng đang được sử dụng. Điều này có nghĩa là nếu commandtrong dòng trên không thành công, tệp bó sẽ thoát đúng, nhưng nó thoát với mã trả về 0, vì đó là giá trị của %ERRORLEVEL%ở đầu dòng. Rõ ràng, điều này là không mong muốn trong kịch bản của chúng tôi, vì vậy chúng tôi phải kích hoạt mở rộng bị trì hoãn , như vậy:

SETLOCAL EnableDelayedExpansion

command-1 || exit /b !ERRORLEVEL!
command-2 || exit /b !ERRORLEVEL!
command-3 || exit /b !ERRORLEVEL!
command-4 || exit /b !ERRORLEVEL!

Đoạn mã này sẽ thực thi các lệnh 1-4 và nếu bất kỳ lỗi nào trong số chúng bị lỗi, nó sẽ thoát với cùng mã thoát như lệnh thất bại đã làm.

Chúng tôi không thể luôn phụ thuộc vào ERRORLEVEL, vì nhiều lần các chương trình bên ngoài hoặc tập lệnh bó không trả về mã thoát.

Trong trường hợp đó, chúng ta có thể sử dụng kiểm tra chung cho các lỗi như thế này:

IF EXIST %outfile% (DEL /F %outfile%)
CALL some_script.bat -o %outfile%
IF NOT EXIST %outfile%  (ECHO ERROR & EXIT /b)

Và nếu chương trình xuất ra thứ gì đó để điều khiển, chúng ta cũng có thể kiểm tra nó.

some_program.exe 2>&1 | FIND "error message here" && (ECHO ERROR & EXIT /b)
some_program.exe 2>&1 | FIND "Done processing." || (ECHO ERROR & EXIT /b)

Cho dù tôi đã cố gắng như thế nào, errorlevel luôn ở mức 0 ngay cả khi msbuild không thành công. Vì vậy, tôi đã xây dựng cách giải quyết của mình:

Xây dựng dự án và lưu nhật ký vào Build.log

SET Build_Opt=/flp:summary;logfile=Build.log;append=true

msbuild "myproj.csproj" /t:rebuild /p:Configuration=release /fl %Build_Opt%

tìm kiếm chuỗi "0 Error" trong nhật ký xây dựng, đặt kết quả thành var

FOR /F "tokens=* USEBACKQ" %%F IN (`find /c /i "0 Error" Build.log`) DO (
    SET var=%%F
)
echo %var%

lấy ký tự cuối cùng, cho biết có bao nhiêu dòng chứa chuỗi tìm kiếm

set result=%var:~-1%

echo "%result%"

nếu không tìm thấy chuỗi, thì lỗi> 0, xây dựng thất bại

if "%result%"=="0" ( echo "build failed" )

Giải pháp đó được lấy cảm hứng từ bài đăng của Mechaflash tại Cách đặt đầu ra lệnh dưới dạng một biến trong tệp bó

và https://ss64.com/nt/syntax-subopes.html

@echo off

set startbuild=%TIME%

C:\WINDOWS\Microsoft.NET\Framework\v3.5\msbuild.exe c:\link.xml /flp1:logfile=c:\link\errors.log;errorsonly /flp2:logfile=c:\link\warnings.log;warningsonly || goto :error

copy c:\app_offline.htm "\\lawpccnweb01\d$\websites\OperationsLinkWeb\app_offline.htm"

del \\lawpccnweb01\d$\websites\OperationsLinkWeb\bin\ /Q

echo Start Copy: %TIME%

set copystart=%TIME%

xcopy C:\link\_PublishedWebsites\OperationsLink \\lawpccnweb01\d$\websites\OperationsLinkWeb\ /s /y /d

del \\lawpccnweb01\d$\websites\OperationsLinkWeb\app_offline.htm

echo Started Build: %startbuild%
echo Started Copy: %copystart%
echo Finished Copy: %TIME%

c:\link\warnings.log

:error

c:\link\errors.log