Di chuyển toàn bộ dòng lên và xuống trong Vim

Trong Notepad ++, tôi có thể sử dụng Ctrl+ Shift+ Up/ Downđể di chuyển dòng hiện tại lên và xuống. Có một lệnh tương tự như thế này trong Vim? Tôi đã xem qua các hướng dẫn vô tận, nhưng không tìm thấy gì.

Nếu không có, làm thế nào tôi có thể liên kết hành động với tổ hợp phím đó?

Chỉnh sửa: Câu trả lời của Mykola hoạt động cho tất cả các dòng, ngoài những câu ở đầu và cuối bộ đệm. Di chuyển dòng đầu tiên lên hoặc dòng dưới cùng xóa dòng, và khi di chuyển dòng dưới lên, nó nhảy hai khoảng trống ban đầu, giống như một con tốt! Bất cứ ai có thể cung cấp bất kỳ tinh chỉnh?

Đặt phần sau vào .vimrc của bạn để thực hiện công việc

noremap <c-s-up> :call feedkeys( line('.')==1 ? '' : 'ddkP' )<CR>
noremap <c-s-down> ddp

Biến mất của dòng trông giống như một lỗi Vim. Tôi đặt một hack để tránh nó. Có lẽ có một số giải pháp chính xác hơn.

Cập nhật

Có rất nhiều khó khăn không giải thích được khi chỉ sử dụng kết hợp Vim. Đây là dòng thiếu và nhảy dòng bổ sung.

Vì vậy, đây là giải pháp kịch bản có thể được đặt bên trong .vimrc hoặc ~ / .vim / plugin / exchange_lines.vim

function! s:swap_lines(n1, n2)
    let line1 = getline(a:n1)
    let line2 = getline(a:n2)
    call setline(a:n1, line2)
    call setline(a:n2, line1)
endfunction

function! s:swap_up()
    let n = line('.')
    if n == 1
        return
    endif

    call s:swap_lines(n, n - 1)
    exec n - 1
endfunction

function! s:swap_down()
    let n = line('.')
    if n == line('$')
        return
    endif

    call s:swap_lines(n, n + 1)
    exec n + 1
endfunction

noremap <silent> <c-s-up> :call <SID>swap_up()<CR>
noremap <silent> <c-s-down> :call <SID>swap_down()<CR>

Nếu tôi muốn hoán đổi một dòng với dòng trên, tôi thường làm như sau

ddkP

Giải trình

• dd sẽ xóa dòng và thêm nó vào thanh ghi mặc định.
• k sẽ di chuyển lên một dòng (j sẽ di chuyển xuống một dòng)
• P sẽ dán phía trên dòng hiện tại

Giả sử con trỏ nằm trên dòng bạn muốn di chuyển.

Di chuyển lên và xuống: :mđể di chuyển

:m +1 - di chuyển xuống 1 dòng

:m -2 - di chuyển lên 1 dòng

(Lưu ý bạn có thể thay thế +1 bằng bất kỳ số nào tùy thuộc vào số lượng dòng bạn muốn di chuyển lên hoặc xuống, tức là +2 sẽ di chuyển xuống 2 dòng, -3 sẽ di chuyển lên 2 dòng)

Để di chuyển đến dòng cụ thể

:set number - hiển thị các dòng số (dễ dàng hơn để xem nơi bạn đang di chuyển đến)

:m 3 - di chuyển dòng sau dòng thứ 3 (thay thế 3 thành bất kỳ dòng nào bạn muốn)

Di chuyển nhiều dòng:

V(tức là Shift- V) và di chuyển courser lên và xuống để chọn nhiều dòng trong VIM

một khi được chọn nhấn :và chạy các lệnh trên, m +1vv

Di chuyển một dòng lên: ddkP

Di chuyển một dòng xuống: ddp

Điều này làm việc cho tôi:

http://vim.wikia.com/wiki/Moving_lines_up_or_down_in_a_file

BTW, nếu bạn muốn sử dụng ALT + some_key và thiết bị đầu cuối của bạn (urxvt làm điều này) từ chối tuân thủ, bạn nên nhập một cái gì đó như thế này trong .vimrc của bạn:

" For moving lines (^] is a special character; use <M-k> and <M-j> if it works)
nnoremap ^]k mz:m-2<CR>`z==
inoremap ^]j <Esc>:m+<CR>==gi
inoremap ^]k <Esc>:m-2<CR>==gi
vnoremap ^]j :m'>+<CR>gv=`<my`>mzgv`yo`z
nnoremap ^]j mz:m+<CR>`z==
vnoremap ^]k :m'<-2<CR>gv=`>my`<mzgv`yo`z

trong đó ^] là một ký tự đại diện cho phím ALT. Để nhập ký tự đó, sử dụng C+v, Esctrong Vim ( C+q, Esctrên Windows).

thêm tệp sau vào tệp ~ / .vimrc (đảm bảo bạn không có ánh xạ cho n, m)

nmap n :m +1<CR>
nmap m :m -2<CR>

bây giờ nhấn nphím sẽ di chuyển một dòng xuống và msẽ di chuyển một dòng lên.

Trong chế độ lệnh, vị trí con trỏ trên dòng bạn muốn di chuyển xuống, và sau đó

ddp

Giải thích: dd xóa dòng hiện tại vào bộ đệm chung p đặt nó trở lại SAU vị trí con trỏ hoặc trong trường hợp toàn bộ dòng, một dòng bên dưới.

Có một số nhầm lẫn liên quan đến lệnh p và P trong nhiều tài liệu. Trong thực tế, p dán con trỏ SAU và con trỏ P AT.

Chỉ cần thêm mã này vào .vimrc (hoặc .gvimrc)

nnoremap <A-j> :m+<CR>==
nnoremap <A-k> :m-2<CR>==
inoremap <A-j> <Esc>:m+<CR>==gi
inoremap <A-k> <Esc>:m-2<CR>==gi
vnoremap <A-j> :m'>+<CR>gv=gv
vnoremap <A-k> :m-2<CR>gv=gv

Chính xác những gì bạn đang tìm kiếm trong plugin tuyệt vời này: https://github.com/vim-scripts/upAndDown

Một giải pháp đơn giản là đưa vào .vimrcnhững dòng này của bạn :

nmap <C-UP> :m-2<CR>  
nmap <C-DOWN> :m+1<CR>

Tôi đặt phần sau vào cuối tệp .vimrc của mình:

noremap H ddkkp
noremap N ddp

Vì vậy, bây giờ 'H' và 'N' di chuyển dòng hiện tại lên và xuống tương ứng.

Đây là phiên bản đơn giản hóa, dành cho MacVim, sử dụng các ví dụ về bài viết Wikia (xem liên kết từ nhận xét của súng ).

" Move selection up/down (add =gv to reindent after move)
:vmap <D-S-Up> :m-2<CR>gv
:vmap <D-S-Down> :m'>+<CR>gv

Tôi chỉ sử dụng biến thể chọn khối, vì tất cả chỉ cần Shift-V để chọn dòng hiện tại và tùy chọn con trỏ lên / xuống để chọn thêm một số dòng.

Theo các phím tắt ở trên, nhấn Cmd-Shift-Up / Down sẽ thay đổi lựa chọn khối lên / xuống. "D" là phím Lệnh trong MacVim, đối với Windows, hãy thử "C" (Điều khiển) hoặc "A" (Alt) (ví dụ: <CAf> sẽ là Control Alt f).

Bài viết Wikia thêm "= gv" vào những điều này, có tác dụng điều chỉnh độ thụt của khối sau khi di chuyển, dựa trên văn bản xung quanh. Điều này gây nhầm lẫn vì vậy tôi đã xóa nó và thêm các phím tắt để nhanh chóng thụt vào lựa chọn.

" Indent selection left/right (Cmd Shift Left/Right is used for Tab switching)
:vmap <D-A-Left> <gv
:vmap <D-A-Right> >gv

Lưu ý, điều tương tự cũng có thể được thực hiện với << và >> nhưng lựa chọn sẽ bị mất, vì vậy các phím tắt ở trên cho phép thụt lề nhiều lần và vẫn di chuyển khối xung quanh vì lựa chọn được duy trì.

MacVim của tôi được cấu hình để chuyển Tab bằng Cmd-Shift-Left / Right vì vậy tôi đã sử dụng Cmd-Alt-Left / Right.

Đây là Tab chuyển đổi cho MacVim (đặt .gvimrc với phần còn lại ở trên):

:macm Window.Select\ Previous\ Tab key=<D-S-Left>
:macm Window.Select\ Next\ Tab key=<D-S-Right>

vim plugin unimpaired.vim [e và] e

Khi bạn nhấn lệnh :help movein vim, đây là kết quả:

:[range]m[ove] {address} *:m* *:mo* *:move* *E134* Move the lines given by [range] to below the line given by {address}.

Ví dụ: Di chuyển dòng hiện tại xuống một dòng => :m+1 .

Ví dụ: Di chuyển dòng có số 100 bên dưới dòng có số 80 => :100 m 80 .

Ví dụ: Di chuyển dòng có số 100 bên dưới dòng có số 200 => :100 m 200 .

Ví dụ: Di chuyển các dòng có số trong [100, 120] bên dưới dòng có số 200 => :100,120 m 200 .

Đây là một giải pháp hoạt động trên máy của tôi : MacBook Pro chạy VIM 8.1

Các lệnh này sẽ không xóa các dòng của bạn ở đầu hoặc cuối bộ đệm của bạn.

Sử dụng các ký hiệu thực tế mà đầu ra Alt-J và Alt-K là một cách giải quyết cho các mã khóa của chúng không ánh xạ đúng trong môi trường của tôi.

Ném cái này vào .vimrc cũ và xem nếu nó hoạt động cho bạn.

" Maps Alt-J and Alt-K to macros for moving lines up and down
" Works for modes: Normal, Insert and Visual
nnoremap ∆ :m .+1<CR>==
nnoremap ˚ :m .-2<CR>==
inoremap ∆ <Esc>:m .+1<CR>==gi
inoremap ˚ <Esc>:m .-2<CR>==gi
vnoremap ∆ :m '>+1<CR>gv=gv
vnoremap ˚ :m '<-2<CR>gv=gv

Đối với tôi, ddkkpđã làm điều đó (thay vì ddkPvới chữ P viết hoa, nó cũng sẽ hoạt động).

: m. + 1 hoặc: m.-2 sẽ làm gì nếu bạn di chuyển một dòng. Đây là kịch bản của tôi để di chuyển nhiều dòng. Trong chế độ trực quan, Alt-up / Alt-down sẽ di chuyển các dòng chứa lựa chọn trực quan lên / xuống theo một dòng. Trong chế độ chèn hoặc chế độ bình thường, Alt-up / Alt-down sẽ di chuyển dòng hiện tại nếu không có tiền tố đếm được đưa ra. Nếu có tiền tố đếm, Alt-up / Alt-down sẽ di chuyển nhiều dòng bắt đầu từ dòng hiện tại lên / xuống theo một dòng.

function! MoveLines(offset) range
    let l:col = virtcol('.')
    let l:offset = str2nr(a:offset)
    exe 'silent! :' . a:firstline . ',' . a:lastline . 'm'
        \ . (l:offset > 0 ? a:lastline + l:offset : a:firstline + l:offset)
    exe 'normal ' . l:col . '|'
endf

imap <silent> <M-up> <C-O>:call MoveLines('-2')<CR>
imap <silent> <M-down> <C-O>:call MoveLines('+1')<CR>
nmap <silent> <M-up> :call MoveLines('-2')<CR>
nmap <silent> <M-down> :call MoveLines('+1')<CR>
vmap <silent> <M-up> :call MoveLines('-2')<CR>gv
vmap <silent> <M-down> :call MoveLines('+1')<CR>gv

Trong trường hợp bạn muốn làm điều này trên nhiều dòng khớp với một tìm kiếm cụ thể:

• Lên: :g/Your query/ normal ddphoặc:g/Your query/ m -1
• Xuống :g/Your query/ normal ddphoặc:g/Your query/ m +1