Hiển thị đầu ra lệnh Windows và chuyển hướng nó đến một tệp

Làm cách nào tôi có thể chạy ứng dụng dòng lệnh trong dấu nhắc lệnh của Windows và có đầu ra được hiển thị và chuyển hướng đến một tệp cùng một lúc?

Ví dụ, nếu tôi chạy lệnh dir > test.txt, điều này sẽ chuyển hướng đầu ra đến một tệp được gọi test.txtmà không hiển thị kết quả.

Làm thế nào tôi có thể viết một lệnh để hiển thị đầu ra và chuyển hướng đầu ra sang một tệp trong dấu nhắc lệnh của Windows, tương tự như teelệnh trên Unix?

Để mở rộng câu trả lời của davor , bạn có thể sử dụng PowerShell như thế này:

powershell "dir | tee test.txt"

Nếu bạn đang cố chuyển hướng đầu ra của một exe trong thư mục hiện tại, bạn cần sử dụng .\tên tệp, ví dụ:

powershell ".\something.exe | tee test.txt"

Tôi đã có thể tìm một giải pháp / cách giải quyết chuyển hướng đầu ra sang một tệp và sau đó đến bàn điều khiển:

dir > a.txt | type a.txt

Trong đó dir là lệnh mà đầu ra cần được chuyển hướng, a.txt một tệp nơi lưu trữ đầu ra.

Có một cổng Win32 của teelệnh Unix , thực hiện chính xác điều đó. Xem http://unxutils.sourceforge.net/ hoặc http://getgnuwin32.sourceforge.net/

Kiểm tra này: wintee

Không cần cygwin.

Tôi đã gặp và báo cáo một số vấn đề mặc dù.

Ngoài ra, bạn có thể kiểm tra unxutils vì nó có chứa tee (và không cần cygwin), nhưng hãy cẩn thận khi xuất EOL giống như UNIX ở đây.

Cuối cùng, nhưng không kém phần quan trọng, là nếu bạn có PowerShell, bạn có thể thử Tee-Object. Nhập get-help tee-objectvào bảng điều khiển PowerShell để biết thêm.

@ tori3852

Tôi thấy rằng

dir > a.txt | type a.txt

không hoạt động (chỉ một vài dòng đầu tiên của danh sách dir - nghi ngờ một số loại quy trình giả mạo và phần thứ hai, lệnh 'loại' đã chấm dứt trước khi danh sách thảm khốc hoàn thành?), vì vậy thay vào đó tôi đã sử dụng:

dir > z.txt && type z.txt

đã làm - các lệnh tuần tự, một lệnh hoàn thành trước khi bắt đầu thứ hai.

Thật không may, không có điều đó.

Các ứng dụng giao diện điều khiển Windows chỉ có một tay cầm đầu ra duy nhất. (Chà, có hai cái STDOUT, STDERRnhưng nó không thành vấn đề ở đây) >Chuyển hướng đầu ra thường được ghi vào tay cầm bàn điều khiển để xử lý tệp.

Nếu bạn muốn có một số loại ghép kênh, bạn phải sử dụng một ứng dụng bên ngoài mà bạn có thể chuyển hướng đầu ra. Ứng dụng này sau đó có thể ghi vào một tệp và vào bàn điều khiển một lần nữa.

Một ứng dụng bảng điều khiển C # đơn giản sẽ thực hiện thủ thuật:

using System;
using System.Collections.Generic;
using System.IO;

namespace CopyToFiles
{
    class Program
    {
        static void Main(string[] args)
        {
            var buffer = new char[100];
            var outputs = new List<TextWriter>();

            foreach (var file in args)
                outputs.Add(new StreamWriter(file));

            outputs.Add(Console.Out);

            int bytesRead;
            do
            {
                bytesRead = Console.In.ReadBlock(buffer, 0, buffer.Length);
                outputs.ForEach(o => o.Write(buffer, 0, bytesRead));
            } while (bytesRead == buffer.Length);

            outputs.ForEach(o => o.Close());
        }
    }
}

Để sử dụng điều này, bạn chỉ cần đưa lệnh nguồn vào chương trình và cung cấp đường dẫn của bất kỳ tệp nào bạn muốn sao chép đầu ra. Ví dụ:

dir | CopyToFiles files1.txt files2.txt 

Sẽ hiển thị kết quả của dir cũng như lưu trữ kết quả trong cả files1.txt và files2.txt.

Lưu ý rằng không có nhiều (bất cứ điều gì!) Trong cách xử lý lỗi ở trên và việc hỗ trợ nhiều tệp có thể không thực sự được yêu cầu.

Điều này hoạt động, mặc dù nó hơi xấu:

dir >_ && type _ && type _ > a.txt

Nó linh hoạt hơn một chút so với một số giải pháp khác, ở chỗ nó hoạt động theo từng câu lệnh để bạn cũng có thể sử dụng nó để nối thêm. Tôi sử dụng điều này khá nhiều trong các tệp bó để ghi nhật ký và hiển thị thông báo:

ECHO Print line to screen and log to file.  >_ && type _ && type _ >> logfile.txt

Có, bạn chỉ có thể lặp lại câu lệnh ECHO (một lần cho màn hình và lần thứ hai chuyển hướng đến logfile), nhưng điều đó có vẻ tệ và là một vấn đề bảo trì. Ít nhất theo cách này, bạn không phải thay đổi tin nhắn ở hai nơi.

Lưu ý rằng _ chỉ là một tên tệp ngắn, vì vậy bạn sẽ cần đảm bảo xóa nó ở cuối tệp bó của mình (nếu bạn đang sử dụng tệp bó).

mtee là một tiện ích nhỏ hoạt động rất tốt cho mục đích này. Nó miễn phí, nguồn mở và nó chỉ hoạt động.

Bạn có thể tìm thấy nó tại http://www.commandline.co.uk .

Được sử dụng trong một tệp bó để hiển thị đầu ra VÀ tạo một tệp nhật ký đồng thời, cú pháp trông như thế này:

    someprocess | mtee /+ mylogfile.txt

Trong đó / + có nghĩa là nối thêm đầu ra.

Điều này giả định rằng bạn đã sao chép mtee vào một thư mục trong PATH, tất nhiên.

Tôi muốn mở rộng một chút về câu trả lời tuyệt vời của Saxon Druce .

Như đã nêu, bạn có thể chuyển hướng đầu ra của một tệp thực thi trong thư mục hiện tại như sau:

powershell ".\something.exe | tee test.txt"

Tuy nhiên, điều này chỉ đăng nhập stdoutvào test.txt. Nó cũng không đăng nhập stderr.

Giải pháp rõ ràng là sử dụng một cái gì đó như thế này:

powershell ".\something.exe 2>&1 | tee test.txt"

Tuy nhiên, điều này sẽ không làm việc cho tất cả các something.exes. Một số something.exes sẽ giải thích 2>&1như là một đối số và thất bại. Giải pháp chính xác là thay vào đó chỉ có dấu nháy đơn xung quanh something.exevà các công tắc và đối số của nó, như vậy:

powershell ".\something.exe --switch1 --switch2 … arg1 arg2 …" 2>&1 | tee test.txt

Tôi đồng ý với Brian Rasmussen, cổng unxutils là cách dễ nhất để làm điều này. Trong phần Batch Files trong các trang Scripting của mình, Rob van der Woude cung cấp nhiều thông tin về việc sử dụng các lệnh MS-DOS và CMD. Tôi nghĩ rằng anh ta có thể có một giải pháp tự nhiên cho vấn đề của bạn và sau khi đào bới xung quanh đó, tôi đã tìm thấy TEE.BAT , có vẻ như đó là một triển khai ngôn ngữ hàng loạt MS-DOS của tee. Đây là một tệp bó trông khá phức tạp và thiên hướng của tôi vẫn là sử dụng cổng unxutils.

Nếu bạn có cygwin trong đường dẫn môi trường windows, bạn có thể sử dụng:

 dir > a.txt | tail -f a.txt

dir 1>a.txt 2>&1 | type a.txt

Điều này sẽ giúp chuyển hướng cả STDOUT và STDERR

Tôi biết đây là một chủ đề rất cũ, nhưng trong các câu trả lời trước đây không có triển khai đầy đủ về một Tee thời gian thực được viết bằng Batch. Giải pháp của tôi dưới đây là tập lệnh lai Batch-JScript sử dụng phần JScript chỉ để lấy đầu ra từ lệnh piped, nhưng việc xử lý dữ liệu được thực hiện trong phần Batch. Cách tiếp cận này có lợi thế là bất kỳ lập trình viên Batch nào cũng có thể sửa đổi chương trình này để phù hợp với nhu cầu cụ thể. Chương trình này cũng xử lý chính xác đầu ra của lệnh CLS được tạo bởi các tệp Batch khác, nghĩa là, nó sẽ xóa màn hình khi phát hiện ra lệnh CLS.

@if (@CodeSection == @Batch) @then


@echo off
setlocal EnableDelayedExpansion

rem APATee.bat: Asynchronous (real time) Tee program, Batch-JScript hybrid version
rem Antonio Perez Ayala

rem The advantage of this program is that the data management is written in Batch code,
rem so any Batch programmer may modify it to fit their own needs.
rem As an example of this feature, CLS command is correctly managed

if "%~1" equ "" (
   echo Duplicate the Stdout output of a command in the screen and a disk file
   echo/
   echo anyCommand ^| APATee teeFile.txt [/A]
   echo/
   echo If /A switch is given, anyCommand output is *appended* to teeFile.txt
   goto :EOF
)

if "%2" equ ":TeeProcess" goto TeeProcess

rem Get the output of CLS command
for /F %%a in ('cls') do set "cls=%%a"

rem If /A switch is not provided, delete the file that receives Tee output
if /I "%~2" neq "/A" if exist %1 del %1

rem Create the semaphore-signal file and start the asynchronous Tee process
echo X > Flag.out
if exist Flag.in del Flag.in
Cscript //nologo //E:JScript "%~F0" | "%~F0" %1 :TeeProcess
del Flag.out
goto :EOF

:TeeProcess
   rem Wait for "Data Available" signal
   if not exist Flag.in goto TeeProcess
   rem Read the line sent by JScript section
   set line=
   set /P line=
   rem Set "Data Read" acknowledgement
   ren Flag.in Flag.out
   rem Check for the standard "End Of piped File" mark
   if "!line!" equ ":_EOF_:" exit /B
   rem Correctly manage CLS command
   if "!line:~0,1!" equ "!cls!" (
      cls
      set "line=!line:~1!"
   )
   rem Duplicate the line in Stdout and the Tee output file
   echo(!line!
   echo(!line!>> %1
goto TeeProcess


@end


// JScript section

var fso = new ActiveXObject("Scripting.FileSystemObject");
// Process all lines of Stdin
while ( ! WScript.Stdin.AtEndOfStream ) {
   // Read the next line from Stdin
   var line = WScript.Stdin.ReadLine();
   // Wait for "Data Read" acknowledgement
   while ( ! fso.FileExists("Flag.out") ) {
      WScript.Sleep(10);
   }
   // Send the line to Batch section
   WScript.Stdout.WriteLine(line);
   // Set "Data Available" signal
   fso.MoveFile("Flag.out", "Flag.in");
}
// Wait for last "Data Read" acknowledgement
while ( ! fso.FileExists("Flag.out") ) {
      WScript.Sleep(10);
}
// Send the standard "End Of piped File" mark
WScript.Stdout.WriteLine(":_EOF_:");
fso.MoveFile("Flag.out", "Flag.in");

Tôi cũng đang tìm kiếm giải pháp tương tự, sau một chút cố gắng, tôi đã thành công có thể đạt được điều đó trong Command Prompt. Đây là giải pháp của tôi:

@Echo off
for /f "Delims=" %%a IN (xyz.bat) do (
%%a > _ && type _ && type _ >> log.txt
)
@Echo on

Nó thậm chí còn nắm bắt bất kỳ lệnh PAUSE nào.

Đây là một ví dụ về những gì tôi đã sử dụng dựa trên một trong những câu trả lời khác

@echo off
REM SOME CODE
set __ERROR_LOG=c:\errors.txt
REM set __IPADDRESS=x.x.x.x

REM Test a variable
if not defined __IPADDRESS (
     REM Call function with some data and terminate
     call :TEE %DATE%,%TIME%,IP ADDRESS IS NOT DEFINED
     goto :EOF
)

REM If test happens to be successful, TEE out a message and end script.
call :TEE Script Ended Successful
goto :EOF


REM THE TEE FUNCTION
:TEE
for /f "tokens=*" %%Z in ("%*") do (
     >  CON ECHO.%%Z
     >> "%__ERROR_LOG%" ECHO.%%Z
     goto :EOF
)

Một cái gì đó như thế này nên làm những gì bạn cần?

%DATE%_%TIME% > c:\a.txt & type c:\a.txt
ipconfig >> c:\a.txt & type c:\a.txt
ping localhost >> c:\a.txt & type c:\a.txt
pause

gửi đầu ra đến bàn điều khiển, nối vào nhật ký bàn điều khiển, xóa đầu ra khỏi lệnh hiện tại

dir  >> usb-create.1 && type usb-create.1 >> usb-create.log | type usb-create.1 && del usb-create.1

Đây là một biến thể của câu trả lời trước của MTS, tuy nhiên, nó bổ sung một số chức năng có thể hữu ích cho những người khác. Đây là phương pháp mà tôi đã sử dụng:

• Một lệnh được đặt dưới dạng một biến, có thể được sử dụng sau này trong toàn bộ mã, để xuất ra cửa sổ lệnh và nối vào tệp nhật ký, sử dụng set _Temp_Msg_Cmd=
  • lệnh đã thoát khỏi chuyển hướng bằng cách sử dụng ^ký tự cà rốt để các lệnh không được đánh giá ban đầu
• Một tệp tạm thời được tạo với tên tệp tương tự như tệp bó đang được gọi %~n0_temp.txtcó sử dụng cú pháp mở rộng tham số dòng lệnh %~n0 để lấy tên của tệp bó.
• Đầu ra được nối vào một tệp nhật ký riêng %~n0_log.txt

Đây là chuỗi các lệnh:

1. Các thông báo đầu ra và lỗi được gửi đến tệp tạm thời ^> %~n0_temp.txt 2^>^&1
2. Nội dung của tệp tạm thời là cả hai:
   • gắn vào logfile ^& type %~n0_temp.txt ^>^> %~n0_log.txt
   • xuất ra cửa sổ lệnh ^& type %~n0_temp.txt
3. Các tập tin tạm thời với tin nhắn sẽ bị xóa ^& del /Q /F %~n0_temp.txt

Dưới đây là ví dụ:

set _Temp_Msg_Cmd= ^> %~n0_temp.txt 2^>^&1 ^& type %~n0_temp.txt ^>^> %~n0_log.txt ^& type %~n0_temp.txt ^& del /Q /F %~n0_temp.txt

Bằng cách này, lệnh đơn giản có thể được thêm vào sau các lệnh sau trong tệp bó trông sạch hơn rất nhiều:

echo test message %_Temp_Msg_Cmd%

Điều này có thể được thêm vào cuối các lệnh khác. Theo như tôi có thể nói nó sẽ hoạt động khi tin nhắn có nhiều dòng. Ví dụ: lệnh sau xuất ra hai dòng nếu có thông báo lỗi:

net use M: /D /Y %_Temp_Msg_Cmd%

@echo on

set startDate=%date%
set startTime=%time%

set /a sth=%startTime:~0,2%
set /a stm=1%startTime:~3,2% - 100
set /a sts=1%startTime:~6,2% - 100


fullprocess.bat > C:\LOGS\%startDate%_%sth%.%stm%.%sts%.LOG | fullprocess.bat

Điều này sẽ tạo một tệp nhật ký với datetime hiện tại và bạn có thể các dòng bàn điều khiển trong quá trình

Tôi sử dụng một chương trình con hàng loạt với câu lệnh "for" để nhận lệnh xuất một dòng tại một thời điểm và cả hai ghi dòng đó vào một tệp và xuất nó ra bàn điều khiển.

@echo off
set logfile=test.log

call :ExecuteAndTee dir C:\Program Files

Exit /B 0

:ExecuteAndTee
setlocal enabledelayedexpansion
echo Executing '%*'
  for /f "delims=" %%a in ('%* 2^>^&1') do (echo.%%a & echo.%%a>>%logfile%)
endlocal
Exit /B 0

Nếu bạn đang sử dụng CLI, tại sao không sử dụng vòng lặp FOR để "LÀM" bất cứ điều gì bạn muốn:

for /F "delims=" %a in ('dir') do @echo %a && echo %a >> output.txt

Tài nguyên tuyệt vời trên Windows CMD cho các vòng lặp: https://ss64.com/nt/for_cmd.html Chìa khóa ở đây là thiết lập các vạch đo (độ trễ), sẽ chia nhỏ từng dòng đầu ra, thành không có gì. Bằng cách này, nó sẽ không phá vỡ mặc định của khoảng trắng. % A là một chữ cái tùy ý, nhưng nó được sử dụng trong phần "làm" để ... làm gì đó với các ký tự được phân tích cú pháp ở mỗi dòng. Trong trường hợp này, chúng ta có thể sử dụng ký hiệu (&&) để thực thi lệnh echo thứ 2 để tạo hoặc nối thêm (>>) vào một tệp mà chúng ta chọn. An toàn hơn để giữ thứ tự các lệnh DO này trong trường hợp có vấn đề khi ghi tệp, ít nhất chúng ta sẽ nhận được tiếng vang đến bàn điều khiển trước. Dấu hiệu (@) phía trước tiếng vang đầu tiên ngăn không cho bảng điều khiển hiển thị lệnh echo và thay vào đó chỉ hiển thị kết quả của lệnh hiển thị các ký tự theo% a. Nếu không, bạn sẽ thấy:

echo Volume trong ổ đĩa [x] là Windows
Volume trong ổ đĩa [x] là Windows

CẬP NHẬT: / F bỏ qua các dòng trống và chỉ khắc phục là lọc trước đầu ra thêm một ký tự cho mỗi dòng (có thể với các số dòng thông qua lệnh tìm). Giải quyết vấn đề này trong CLI không nhanh hay đẹp. Ngoài ra, tôi cũng không bao gồm STDERR, vì vậy, đây cũng là lỗi bắt lỗi:

for /F "delims=" %a in ('dir 2^>^&1') do @echo %a & echo %a >> output.txt

Chuyển hướng thông báo lỗi

Các dấu mũ (^) ở đó để thoát khỏi các ký hiệu sau chúng, bởi vì lệnh là một chuỗi đang được giải thích, trái ngược với việc nói, nhập trực tiếp vào dòng lệnh.

Cũng giống như unix.

dir | tee a.txt

Không hoạt động Trên windows XP, nó yêu cầu mksntcài đặt.

Nó hiển thị trên dấu nhắc cũng như nối vào tệp.

Theo dõi giúp nếu bạn muốn một cái gì đó thực sự nhìn thấy trên màn hình - ngay cả khi tệp bó được chuyển hướng đến một tệp. Thiết bị CON cũng có thể được sử dụng nếu được chuyển hướng đến một tệp

Thí dụ:

ECHO first line on normal stdout. maybe redirected
ECHO second line on normal stdout again. maybe redirected
ECHO third line is to ask the user. not redirected  >CON
ECHO fourth line on normal stdout again. maybe redirected

Đồng thời xem mô tả chuyển hướng tốt: http://www.p-dd.com/ch CHƯƠNG7-page14.html

Làm cách nào để hiển thị và chuyển hướng đầu ra thành một tệp. Giả sử nếu tôi sử dụng lệnh dos, dir> test.txt, lệnh này sẽ chuyển hướng đầu ra sang tệp test.txt mà không hiển thị kết quả. Cách viết lệnh để hiển thị đầu ra và chuyển hướng đầu ra sang tệp bằng DOS, tức là dấu nhắc lệnh windows, không phải trong UNIX / LINUX.

Bạn có thể thấy các lệnh này trong biterscripting ( http://www.biterscripting.com ) hữu ích.

var str output
lf > $output
echo $output                            # Will show output on screen.
echo $output > "test.txt"               # Will write output to file test.txt.
system start "test.txt"                 # Will open file test.txt for viewing/editing.

Điều này hoạt động trong thời gian thực nhưng cũng là một loại xấu xí và hiệu suất chậm. Cũng không được kiểm tra tốt:

@echo off
cls
SET MYCOMMAND=dir /B
ECHO File called 'test.bat' > out.txt
for /f "usebackq delims=" %%I in (`%MYCOMMAND%`) do (
  ECHO %%I
  ECHO %%I >> out.txt
) 
pause

Một cách khác là để stdout tee stderr trong chương trình của bạn:

trong java:

System.setOut(new PrintStream(new TeeOutputStream(System.out, System.err)));

Sau đó, trong batchfile dos của bạn: java program > log.txt

Thiết bị xuất chuẩn sẽ đi đến logfile và thiết bị xuất chuẩn (cùng dữ liệu) sẽ hiển thị trên bảng điều khiển.

Tôi cài đặt perl trên hầu hết các máy của mình để có câu trả lời bằng perl: tee.pl

my $file = shift || "tee.dat";
open $output, ">", $file or die "unable to open $file as output: $!";
while(<STDIN>)
{
    print $_;
    print $output $_;
}
close $output;

thư mục | perl tee.pl hoặc dir | perl tee.pl dir.bat

thô và chưa được kiểm tra.

Một biến thể khác là tách đường ống, sau đó chuyển hướng đầu ra theo ý muốn.

    @echo off
    for /f "tokens=1,* delims=:" %%P in ('findstr /n "^"') do (
      echo(%%Q
      echo(%%Q>&3
    )
    @exit/b %errorlevel%

Lưu ở trên vào một tập tin .bat. Nó cũng phân tách đầu ra văn bản trên filestream 1 thành filestream 3, mà bạn có thể chuyển hướng khi cần. Trong các ví dụ của tôi dưới đây, tôi đã gọi đoạn script trên là splitPipe.bat ...

    dir | splitPipe.bat  1>con  2>&1  3>my_stdout.log

    splitPipe.bat 2>nul < somefile.txt

1. https://cygwin.com/install
2. Nhấp vào liên kết cho "setup-x86_.exe"
3. Chạy trình cài đặt
4. Trên trang ~ 2, chọn "nhân bản" để tải xuống (Tôi đã tìm tên miền .edu)
5. Tôi nói ok với các tùy chọn tiêu chuẩn
6. Cygwin nhanh chóng hoàn tất cài đặt
7. Mở cmd
8. Nhập c:\cygwin64\bin\script.exevà nhập
9. Nhập cmdvà nhập
10. Chạy chương trình của bạn
11. Kiểu exit và nhập (thoát cmd.exe của Cygwin)
12. Nhập exitvà nhập (thoát khỏi script.exe của Cygwin)
13. Xem đầu ra màn hình của chương trình của bạn trong tệp văn bản có tên là "typecript"