Kiểm tra xem một chuỗi là null hoặc trống trong XSLT

Làm cách nào để kiểm tra xem giá trị là null hay rỗng với XSL ?

Chẳng hạn, nếu categoryNametrống? Tôi đang sử dụng khi chọn cấu trúc.

Ví dụ:

<xsl:choose>
    <xsl:when test="categoryName !=null">
        <xsl:value-of select="categoryName " />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>

test="categoryName != ''"

Chỉnh sửa : Điều này bao gồm cách giải thích có khả năng nhất, theo ý kiến ​​của tôi, về "[không] rỗng hoặc trống rỗng" như được suy ra từ câu hỏi, bao gồm mã giả và trải nghiệm ban đầu của tôi với XSLT. Tức là, "Tương đương với Java sau đây là gì?":

!(categoryName == null || categoryName.equals(""))

Để biết thêm chi tiết, ví dụ, xác định rõ ràng null so với trống, hãy xem câu trả lời của johnvey bên dưới và / hoặc 'fiddle' XSLT mà tôi đã điều chỉnh từ câu trả lời đó, bao gồm tùy chọn trong nhận xét của Michael Kay cũng như cách giải thích thứ sáu có thể.

Không có bất kỳ thông tin nào khác, tôi sẽ giả sử XML sau:

<group>
    <item>
        <id>item 1</id>
        <CategoryName>blue</CategoryName>
    </item>
    <item>
        <id>item 2</id>
        <CategoryName></CategoryName>
    </item>
    <item>
        <id>item 3</id>
    </item>
    ...
</group>

Một trường hợp sử dụng mẫu sẽ trông như sau:

<xsl:for-each select="/group/item">
    <xsl:if test="CategoryName">
        <!-- will be instantiated for item #1 and item #2 -->
    </xsl:if>
    <xsl:if test="not(CategoryName)">
        <!-- will be instantiated for item #3 -->
    </xsl:if>
    <xsl:if test="CategoryName != ''">
        <!-- will be instantiated for item #1 -->
    </xsl:if>
    <xsl:if test="CategoryName = ''">
        <!-- will be instantiated for item #2 -->
    </xsl:if>
</xsl:for-each>

Từ phần tử rỗng :

Để kiểm tra xem giá trị của một nút nào đó có trống không

Nó phụ thuộc vào những gì bạn có nghĩa là trống rỗng.

• Không chứa các nút con: not(node())
• Không chứa nội dung văn bản: not(string(.))
• Không chứa văn bản nào ngoài khoảng trắng: not(normalize-space(.))
• Không chứa gì ngoại trừ ý kiến: not(node()[not(self::comment())])

Thế còn?

test="not(normalize-space(categoryName)='')"

Hai giao dịch đầu tiên với giá trị null và hai giao dịch thứ hai với chuỗi rỗng.

<xsl:if test="USER/FIRSTNAME">
    USERNAME is not null
</xsl:if>
<xsl:if test="not(USER/FIRSTNAME)">
    USERNAME is null
 </xsl:if>
 <xsl:if test="USER/FIRSTNAME=''">
     USERNAME is empty string
 </xsl:if>
 <xsl:if test="USER/FIRSTNAME!=''">
     USERNAME is not empty string
 </xsl:if>

Trong một số trường hợp, bạn có thể muốn biết khi nào giá trị cụ thể là null, điều này đặc biệt cần thiết khi sử dụng XML đã được tuần tự hóa từ các đối tượng .NET. Mặc dù câu trả lời được chấp nhận hoạt động cho điều này, nó cũng trả về kết quả tương tự khi chuỗi trống hoặc trống, tức là '', vì vậy bạn không thể phân biệt được.

<group>
    <item>
        <id>item 1</id>
        <CategoryName xsi:nil="true" />
    </item>
</group>

Vì vậy, bạn có thể chỉ cần kiểm tra thuộc tính.

<xsl:if test="CategoryName/@xsi:nil='true'">
   Hello World.
</xsl:if>

Đôi khi, cần phải biết chính xác trạng thái và bạn không thể kiểm tra xem CategoryName có được khởi tạo hay không, vì không giống như Javascript.

<xsl:if test="CategoryName">
   Hello World.
</xsl:if>

Sẽ trả về true cho phần tử null.

Tôi biết câu hỏi này đã cũ, nhưng giữa tất cả các câu trả lời, tôi bỏ lỡ một câu hỏi là cách tiếp cận phổ biến cho trường hợp sử dụng này trong phát triển XSLT.

Tôi đang tưởng tượng rằng mã bị thiếu từ OP trông giống như thế này:

<xsl:template match="category">
    <xsl:choose>
        <xsl:when test="categoryName !=null">
            <xsl:value-of select="categoryName " />
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="other" />
        </xsl:otherwise>
    </xsl:choose>
</category>

Và rằng đầu vào trông giống như thế này:

<categories>
    <category>
       <categoryName>Books</categoryName>
    </category>
    <category>
       <categoryName>Magazines</categoryName>
       <categoryName>Periodicals</categoryName>
       <categoryName>Journals</categoryName>
    </category>
    <category>
        <categoryName><!-- please fill in category --></categoryName>
    </category>
    <category>
        <categoryName />
    </category>
    <category />
</categories>

Tức là, tôi cho rằng có thể có 0, trống, đơn hoặc nhiều categoryNamephần tử. Để giải quyết tất cả các trường hợp này bằng xsl:choosecách sử dụng các cấu trúc kiểu, hay nói cách khác, bắt buộc phải nhanh chóng trở nên lộn xộn (thậm chí nhiều hơn nếu các yếu tố có thể ở các cấp độ khác nhau!). Một thành ngữ lập trình điển hình trong XSLT là sử dụng các mẫu (do đó T trong XSLT), đó là lập trình khai báo, không bắt buộc (bạn không nói cho bộ xử lý biết phải làm gì, bạn chỉ cần nói bạn muốn đầu ra nếu điều kiện nhất định được đáp ứng). Đối với trường hợp sử dụng này, có thể trông giống như sau:

<!-- positive test, any category with a valid categoryName -->
<xsl:template match="category[categoryName[text()]]">
    <xsl:apply-templates />
</xsl:template>

<!-- any other category (without categoryName, "null", with comments etc) -->
<xsl:template match="category">
    <xsl:text>Category: Other</xsl:text>
</xsl:template>

<!-- matching the categoryName itself for easy handling of multiple names -->
<xsl:template match="categoryName">
    <xsl:text>Category: </xsl:text>
    <xsl:value-of select="." />
</xsl:template>

Điều này hoạt động (với bất kỳ phiên bản XSLT nào), vì phiên bản đầu tiên ở trên có độ ưu tiên cao hơn (nó có một vị ngữ). Mẫu phù hợp "rơi qua", mẫu thứ hai, nắm bắt bất cứ điều gì không hợp lệ. Cái thứ ba sau đó đảm nhận việc xuất racategoryName giá trị một cách thích hợp.

Lưu ý rằng trong kịch bản này, không cần phải khớp cụ thể categorieshoặc categorybởi vì bộ xử lý sẽ tự động xử lý tất cả trẻ em, trừ khi chúng tôi nói khác (trong ví dụ này, mẫu thứ hai và thứ ba không xử lý thêm cho trẻ em, vì không cóxsl:apply-templates trong họ).

Cách tiếp cận này dễ dàng mở rộng hơn cách tiếp cận bắt buộc, bởi vì nó tự động xử lý nhiều danh mục và nó có thể được mở rộng cho các yếu tố hoặc ngoại lệ khác bằng cách chỉ cần thêm một mẫu phù hợp khác. Lập trình mà không có nhánh if .

Lưu ý: không có thứ như nulltrong XML. Có xsi: nil , nhưng điều đó hiếm khi được sử dụng, đặc biệt hiếm khi trong các tình huống chưa được xử lý mà không có lược đồ nào đó.

Làm cách nào để kiểm tra xem giá trị là null hay rỗng với XSL?

Chẳng hạn, nếu categoryNametrống?

Đây có lẽ là biểu thức XPath đơn giản nhất (câu trả lời được chấp nhận cung cấp một bài kiểm tra ngược lại và sẽ dài hơn, nếu bị phủ định):

not(string(categoryName))

Giải thích :

Đối số cho not()hàm trên là false()chính xác khi không có categoryNamecon ("null") của mục ngữ cảnh hoặc con (đơn lẻ) categoryNamecó giá trị chuỗi - chuỗi rỗng.

Tôi đang sử dụng khi lựa chọn cấu trúc.

Ví dụ:

<xsl:choose>
    <xsl:when test="categoryName !=null">
        <xsl:value-of select="categoryName " />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>

Trong XSLT 2.0, sử dụng :

<xsl:copy-of select="concat(categoryName,  $vOther[not(string(current()/categoryName))])"/>

Dưới đây là một ví dụ hoàn chỉnh :

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vOther" select="'Other'"/>

 <xsl:template match="/">
  <xsl:copy-of select="concat(categoryName,$vOther[not(string(current()/categoryName))])"/>
 </xsl:template>
</xsl:stylesheet>

Khi chuyển đổi này được áp dụng trên tài liệu XML sau:

<categoryName>X</categoryName>

kết quả mong muốn, chính xác được tạo ra :

X

Khi được áp dụng trên tài liệu XML này :

<categoryName></categoryName>

hoặc về điều này:

<categoryName/>

hoặc về điều này

<somethingElse>Y</somethingElse>

kết quả chính xác được tạo ra :

Other

Tương tự, sử dụng phép chuyển đổi XSLT 1.0 này :

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vOther" select="'Other'"/>

  <xsl:template match="/">
    <xsl:copy-of select=
    "concat(categoryName,  substring($vOther, 1 div not(string(categoryName))))"/>
  </xsl:template>
</xsl:stylesheet>

Lưu ý : Không có điều kiện được sử dụng ở tất cả. Tìm hiểu thêm về tầm quan trọng của việc tránh các cấu trúc có điều kiện trong khóa học Pluralsight tuyệt vời này:

" Các mẫu thiết kế chiến thuật trong .NET: Control Flow "

Nếu có khả năng phần tử không tồn tại trong XML, tôi sẽ kiểm tra cả phần tử có mặt và độ dài chuỗi lớn hơn 0:

<xsl:choose>
    <xsl:when test="categoryName and string-length(categoryName) &gt; 0">
        <xsl:value-of select="categoryName " />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>

Nếu một nút không có giá trị khả dụng trong xml đầu vào như bên dưới xpath,

<node>
    <ErrorCode/>
</node>

Hàm chuỗi () chuyển thành giá trị trống. Vì vậy, điều này hoạt động tốt:

string(/Node/ErrorCode) =''

Một cái gì đó như thế này làm việc cho tôi:

<xsl:choose>
  <xsl:when test="string(number(categoryName)) = 'NaN'"> - </xsl:when> 
  <xsl:otherwise> 
    <xsl:number value="categoryName" />
  </xsl:otherwise>
</xsl:choose>

Hoặc cách khác xung quanh:

<xsl:choose>
  <xsl:when test="string(number(categoryName)) != 'NaN'">
    <xsl:number value="categoryName" />
  </xsl:when> 
  <xsl:otherwise> - </xsl:otherwise>
</xsl:choose>

Lưu ý: Nếu bạn không kiểm tra giá trị null hoặc xử lý giá trị null, IE7 trả về -2147483648 thay vì NaN.

Tôi thực sự thấy tốt hơn là chỉ kiểm tra độ dài chuỗi vì nhiều lần trường không rỗng, chỉ trống

<xsl: when test = "chuỗi độ dài (trường bạn muốn kiểm tra) <1">

Theo kinh nghiệm của tôi, cách tốt nhất là:

<xsl:when test="not(string(categoryName))">
    <xsl:value-of select="other" />
</xsl:when>
<otherwise>
    <xsl:value-of select="categoryName" />
</otherwise>

Sử dụng danh mục đơn giản / văn bản () Kiểm tra như vậy hoạt động tốt <categoryName/>và cũng <categoryName></categoryName>.

<xsl:choose>
    <xsl:when test="categoryName/text()">
        <xsl:value-of select="categoryName" />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>