CMake: In ra tất cả các biến có thể truy cập trong tập lệnh

Tôi tự hỏi liệu có cách nào để in ra tất cả các biến có thể truy cập trong CMake. Tôi không quan tâm đến các biến CMake - như trong --help-variablestùy chọn. Tôi đang nói về các biến của tôi mà tôi đã xác định hoặc các biến được xác định bởi các tập lệnh được bao gồm.

Tôi hiện đang bao gồm:

INCLUDE (${CMAKE_ROOT}/Modules/CMakeBackwardCompatibilityCXX.cmake)

Và tôi đã hy vọng rằng tôi có thể in ra tất cả các biến ở đây, thay vì phải xem qua tất cả các tệp và đọc những gì có sẵn - tôi có thể tìm thấy một số biến tôi không biết có thể hữu ích. Nó sẽ là tốt để hỗ trợ học tập và khám phá. Nó là nghiêm ngặt để gỡ lỗi / phát triển.

Điều này tương tự với câu hỏi trong In tất cả các biến cục bộ có thể truy cập phạm vi hiện tại trong Lua , nhưng đối với CMake!

Có ai đã làm điều này?

Sử dụng get_cmake_propertyhàm, vòng lặp sau sẽ in ra tất cả các biến CMake được xác định và các giá trị của chúng:

get_cmake_property(_variableNames VARIABLES)
list (SORT _variableNames)
foreach (_variableName ${_variableNames})
    message(STATUS "${_variableName}=${${_variableName}}")
endforeach()

Điều này cũng có thể được nhúng trong một hàm tiện lợi, có thể tùy ý sử dụng biểu thức chính quy để chỉ in một tập hợp con các biến có tên phù hợp

function(dump_cmake_variables)
    get_cmake_property(_variableNames VARIABLES)
    list (SORT _variableNames)
    foreach (_variableName ${_variableNames})
        if (ARGV0)
            unset(MATCHED)
            string(REGEX MATCH ${ARGV0} MATCHED ${_variableName})
            if (NOT MATCHED)
                continue()
            endif()
        endif()
        message(STATUS "${_variableName}=${${_variableName}}")
    endforeach()
endfunction()

Để in các biến môi trường, sử dụng chế độ lệnh của CMake :

execute_process(COMMAND "${CMAKE_COMMAND}" "-E" "environment")

Một cách khác là sử dụng đơn giản:

cmake -LAH

Từ trang hướng dẫn :

-L[A][H]

Liệt kê các biến lưu trữ không nâng cao.

Liệt kê các biến bộ đệm sẽ chạy CMake và liệt kê tất cả các biến từ bộ đệm CMake không được đánh dấu là INTERNALhoặc ADVANCED. Điều này sẽ hiển thị hiệu quả các cài đặt CMake hiện tại [...].

Nếu Ađược chỉ định, thì nó cũng sẽ hiển thị các biến nâng cao.

Nếu Hđược chỉ định, nó cũng sẽ hiển thị trợ giúp cho từng biến.

ccmakelà một tùy chọn tương tác tốt để kiểm tra tương tác các biến được lưu trong bộ nhớ cache ( option(hoặc set( CACHE:

sudo apt-get install cmake-curses-gui
mkdir build
cd build
cmake ..
ccmake ..